Question

我有一个GADT，如下所示

data MyTypes
    = MyInt
    | MyDouble

data Test (t :: MyTypes) where
    A :: Int -> Test 'MyInt
    B :: Double -> Test 'MyDouble

这允许我跟踪类型级别Test值中包含的值，这样我也可以执行类似

的操作

data Test2 (t :: MyTypes) where
    A2 :: Test 'MyInt -> Test2 'MyInt
    B2 :: Test 'MyDouble -> Test2 'MyDouble

并传递信息。

但是，如果我想要一个Test值列表与MyTypes不同的列表，例如

myData :: [Test (t :: MyTypes)]
myData =
    [ A (3 :: Int)
    , B (5.0 :: Double)
    ]

我得到了预期的‘t’ is a rigid type variable bound错误消息。

我尝试使用存在类型来克服刚性类型变量的问题，但后来我失去了传递关于MyType的类型级别信息的能力。

我该如何解决这个问题？

Answer 1

这里的解决方案是存在主义的：

data Test a where
  A :: Int -> Test Int
  B :: Double -> Test Double

data SomeTest where
  SomeTest :: Test a -> SomeTest

myData :: [SomeTest]
myData =
  [ SomeTest (A (3 :: Int))
  , SomeTest (B (5.0 :: Double))
  ]

这只会改变使用此类型的方式。您可以通过模式匹配来恢复类型信息：

consume :: Test a -> Int
consume (A a) = a + 1
consume (B b) = truncate b

map (\ (SomeTest x) -> consume x) myData :: [Int]

使用RankNType s你可以用一个恢复类型的延续来解开它：

test :: (forall a. Test a -> r) -> SomeTest -> r
test k (SomeTest x) = k x

test (\ x -> case x of
  A a -> a + 1 {- ‘a’ is known to be ‘Int’ here -}
  B b -> truncate b {- ‘b’ is known to be ‘Double’ here -})
  :: SomeTest -> Int

当你使用它来将多个事物一起打包在一个“模块”中时，没有任何类型类约束的存在主义是非常有用的，它们都必须在类型上达成一致，但是这种类型是从外面看不透明。这限制了消费者可以执行的操作 - 例如，考虑一对请求和变量来存储该请求的结果：

data SomeRequest where
  SomeRequest :: IO a -> IORef a -> SomeRequest

fetchRequests :: [SomeRequest] -> IO ()
fetchRequests = traverse_ fetchRequest
  where

    -- ‘fetchRequest’ controls the fetching strategy (sync/async)
    -- but can’t do anything with the fetched value
    -- other than store it in the ‘IORef’.
    fetchRequest :: SomeRequest -> IO ()
    fetchRequest (SomeRequest request result) = do
      value <- request
      writeIORef result value

如果您有完全多态的类型，例如：

data Test a where
  Test :: a -> Test a

然后，您可以通过添加类型类约束来恢复有关该类型的更多有趣信息。例如，如果您想要完整的动态信息，可以使用Typeable：

获取

data SomeTest where
  SomeTest :: Typeable a => Test a -> SomeTest

test :: (forall a. Typeable a => Test a -> r) -> SomeTest -> r
test k (SomeTest x) = k x

test (\ (Test a) -> case cast a of
  Just a' -> (a' :: Int) + 1
  Nothing -> case cast a of
    Just a' -> length (a' :: String)
    Nothing -> 0)

大多数情况下，您可以使用功耗低于此值的类型类，具体取决于您实际需要的操作。

异构GADT列表

1 个答案: