我不确定标题是否正确。我有一个XML文件，如下所示：
<main>
<mainelement attribute="on">
<basic>23</basic>
random
<stuff id="10"/>
<a>sometext</a>
<b_1>1</b_1>
<b_2>0.300000</b_2>
<d att="one"/>
<e>value</e>
</mainelement>
<otherlement>
...
</otherlement>
</main>
我格式化文件以符合某种规范。标签a-e都是已知的和想要的。但也有可能其他的东西也在那里，不符合标准。 （即基本的，随机的和东西）。我写了以下
<xsl:template match="main/mainelement">
<mainelement>
<xsl:copy-of select="a">
<xsl:variable name="b1" select="b_1"/>
<xsl:variable name="b2" select="b_2"/>
<b item1="{b1}" item2="{b2}">
<xsl:variable name="c" select="c"/>
<xsl:if test="$c">
<xsl:copy-of select="c">
</xsl:if>
<xsl:if test="not(c)">
<c>default</c>
</xsl:if>
<xsl:copy-of select="d">
<xsl:variable name="e" select="e"/>
<xsl:element name="e">
<xsl:attribute name="att">
<xsl:value-of select="$e">
</xsl:attribute>
</xsl:element>
</mainelement>
<!-- surrounds every element or text() that is unknown with the undefined-tag -->
<xsl:for-each select="* | text()">
<xsl:choose>
<xsl:when test="name()='a'"/>
<xsl:when test="name()='b_1'"/>
<xsl:when test="name()='b_2'"/>
<xsl:when test="name()='c'"/>
<xsl:when test="name()='d'"/>
<xsl:otherwise>
<undefined>
<xsl:copy-of select="current()"/>
</undefined>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each>
</xsl:template>
几乎完成了我想要实现的目标。问题是，我不知道标准旁边是否有任何东西，如果上面没有基本的，随机的或东西，那么应该没有＆lt;未完成的＆gt;标签。输出是
<main>
<mainelement attribute="on">
<a>sometext</a>
<b item1="1" item2="0.3">
<c>default</c>
<d att="one"/>
<e att="value"/>
</mainelement>
<undefined>
<basic>23</basic>
</undefined>
<undefined>
random
</undefined>
<undefined>
<stuff id="10"/>
</undefined>
<otherlement>
...
</otherlement>
</main>
但我想实现这个目标：
<main>
<mainelement attribute="on">
<a>sometext</a>
<b item1="1" item2="0.3">
<c>default</c>
<d att="one"/>
<e att="value"/>
</mainelement>
<undefined>
<basic>23</basic>
random
<stuff id="10"/>
</undefined>
<otherlement>
...
</otherlement>
</main>
我想我过分夸大了，所以我有点因为一个简单的解决方案而陷入困境，所以每一个完全不同的尝试也是如此。 xsl：choose方法的更好的解决方案也很酷，它的风格让我感到沮丧...... 重要的是，我想排除那些与规范不符的东西，并把它放在其他地方。但如果除了我改变a-e之外什么都没有，除了常规之外什么都不会发生 我想到在xsl中选择变量：select并且只在整个变量不为空时才创建输出，但在XSL1.0中似乎不可能
希望我能正确解释我的问题。 非常感谢！
reineke
答案 0 :(得分：3)
我大多在这里猜测，但也许这就是你正在寻找的东西：
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/main">
<xsl:copy>
<xsl:apply-templates select="mainelement"/>
<undefined>
<xsl:copy-of select="mainelement/node()[not(self::a or self::b_1 or self::b_2 or self::c or self::d or self::e)]"/>
</undefined>
<xsl:copy-of select="otherlement"/>
</xsl:copy>
</xsl:template>
<xsl:template match="mainelement">
<xsl:copy>
<xsl:copy-of select="@* | a"/>
<b item1="{b_1}" item2="{b_2}"/>
<xsl:copy-of select="c"/>
<xsl:if test="not(c)">
<c>default</c>
</xsl:if>
<xsl:copy-of select="d"/>
<e att="{e}"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
应用于您的示例输入，结果为：
<?xml version="1.0" encoding="UTF-8"?>
<main>
<mainelement attribute="on">
<a>sometext</a>
<b item1="1" item2="0.300000"/>
<c>default</c>
<d att="one"/>
<e att="value"/>
</mainelement>
<undefined>
<basic>23</basic>
random
<stuff id="10"/>
</undefined>
<otherlement>
...
</otherlement>
</main>
或者，您可以做得更优雅：
<xsl:template match="/main">
<xsl:copy>
<xsl:apply-templates select="mainelement"/>
<xsl:variable name="whitelist" select="mainelement/a | mainelement/b_1 | mainelement/b_2 | mainelement/c | mainelement/d | mainelement/e " />
<undefined>
<xsl:copy-of select="mainelement/node()[not(count(.|$whitelist) = count($whitelist))]"/>
</undefined>
<xsl:copy-of select="otherlement"/>
</xsl:copy>
</xsl:template>
或者，如果您的处理器支持EXSLT集：difference（）扩展函数：
<xsl:template match="/main">
<xsl:copy>
<xsl:apply-templates select="mainelement"/>
<xsl:variable name="whitelist" select="mainelement/a | mainelement/b_1 | mainelement/b_2 | mainelement/c | mainelement/d | mainelement/e " />
<undefined>
<xsl:copy-of select="set:difference(mainelement/node(), $whitelist)"/>
</undefined>
<xsl:copy-of select="otherlement"/>
</xsl:copy>
</xsl:template>
它几乎完成了我想要的，除了以下内容：如果有注意到的话 那里有未定义的（即没有基本的，随机的，东西） 应该是没有＃34;未定义＆＃34;标签。
好吧，那就把＆＃34; undefined＆＃34;首先是变量中的节点，然后只有在该变量中存在某些内容时才创建<undefined>元素：
<xsl:variable name="undefined" select="mainelement/node()[not(self::a or self::b_1 or self::b_2 or self::c or self::d or self::e)]"/>
<xsl:if test="$undefined">
<undefined>
<xsl:copy-of select="$undefined"/>
</undefined>
</xsl:if>