Question

这是我的xml文件：

<?xml version="1.0" encoding="UTF-8"?>
<CONTACTS>

<CONTACT>
<FirstName>Arun</FirstName>
<LastName>Arun_Neelam</LastName>
<Email>nuraaa_iceee@yahoo.co.in</Email>
</CONTACT>

<CONTACT>
<FirstName>Arun</FirstName>
<LastName>Arun_Neelam</LastName>
<Email>nuraaa_iceee@gmail.com</Email>

</CONTACT>
</CONTACTS>

1.如何将上述2个联系人合并为属于同一个人的单个联系人

我想有这样的输出：

<?xml version="1.0" encoding="windows-1250"?>
<CONTACTS>
    <CONTACT>
        <FirstName>Arun</FirstName>
        <LastName>Arun_Neelam</LastName>
        <Email>nuraaa_iceee@gmail.com</Email>
        <Email>nuraaa_iceee@yahoo.co.in</Email>
</CONTACT>
</CONTACTS>

我不确定我能用current-group() and current-grouping-key()做到这一点。非常感谢您的支持。

user639175，他帮助解决了这个问题，他的解决方案正在运行，但没有给出我想要的输出。所以我以一种简单的方式改变了这个问题。

注意：我已经完全格式化了问题，以避免在同一个帖子中出现混淆。

Answer 1

使用标准分组技术，您只需要两个模板（无循环，没有参数）：

使用复合键通过 FirstName 和 SecondName 收集 CONTACT 。
然后将模板应用于每个组的一个 CONTACT 。
最后，从密钥中检索电子邮件节点。

你最后的转变：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:key name="k_Contacts" 
        match="CONTACTS/CONTACT" 
        use="concat(FirstName,LastName)"/>

    <xsl:template match="CONTACTS">
        <xsl:copy>
            <xsl:apply-templates select="CONTACT[generate-id()=
                generate-id(key('k_Contacts',concat(FirstName,LastName))[1])]"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="CONTACT">
        <xsl:copy>
            <xsl:copy-of select="FirstName | LastName"/>
            <xsl:copy-of select="key('k_Contacts',concat(FirstName,LastName))
              /Email"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

在XSLT 2.0中，您可以使用xsl:for-each-group;只需替换

<xsl:apply-templates select="CONTACT[generate-id()=
                generate-id(key('k_Contacts',concat(FirstName,LastName))[1])]"/>

使用：

    <xsl:for-each-group select="CONTACT" group-by="concat(FirstName,LastName)">
        <xsl:apply-templates select="current-group()[1]"/>
    </xsl:for-each-group>

Answer 2

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"  encoding="windows-1250" indent="yes" />

<xsl:key name="groupName" match="//CONTACTS/CONTACT" use="concat(FirstName, LastName)" />

<xsl:template match="CONTACTS">

  <CONTACTS>
  <xsl:for-each select="//CONTACTS/CONTACT[generate-id() = generate-id( key('groupName', concat(FirstName, LastName))   [1] ) ]" >
    <xsl:sort select="CONTACT/EMail"  />

      <xsl:call-template name="group">
        <xsl:with-param name="k1" select="FirstName" />
        <xsl:with-param name="k2" select="LastName" />
      </xsl:call-template>

  </xsl:for-each>
  </CONTACTS>
</xsl:template> 

<xsl:template name="group">
<xsl:param name="k1" /> 
<xsl:param name="k2" /> 


  <xsl:for-each select="//CONTACTS/CONTACT[FirstName = $k1][LastName = $k2][1]">

    <xsl:copy-of select="." />       

  </xsl:for-each>

</xsl:template> 
</xsl:stylesheet>

我没有排除Arun - 因为你的exmaple有缺陷？否则它有效：）

Answer 3

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"  encoding="windows-1250" indent="yes" />

<xsl:key name="groupName" match="//CONTACTS/CONTACT" use="concat(FirstName, LastName)" />

<xsl:template match="CONTACTS">

  <CONTACTS>
  <xsl:for-each select="//CONTACTS/CONTACT[generate-id() = generate-id( key('groupName', concat(FirstName, LastName))   [1] ) ]" >
    <xsl:sort select="CONTACT/EMail"  />

      <xsl:call-template name="group">
        <xsl:with-param name="k1" select="FirstName" />
        <xsl:with-param name="k2" select="LastName" />
      </xsl:call-template>

  </xsl:for-each>
  </CONTACTS>
</xsl:template> 

<xsl:template name="group">
<xsl:param name="k1" /> 
<xsl:param name="k2" /> 

  <CONTACT>
  <xsl:for-each select="//CONTACTS/CONTACT[FirstName = $k1][LastName = $k2][1]">

    <xsl:copy-of select="FirstName" />       
    <xsl:copy-of select="LastName" />       
    <!-- here we have the first Email -->
    <xsl:copy-of select="EMail" />       

  </xsl:for-each>
  <xsl:for-each select="//CONTACTS/CONTACT[FirstName = $k1][LastName = $k2][position() &gt; 1]">
    <!-- here we have the next Email -->

    <xsl:copy-of select="EMail" />       

  </xsl:for-each>
  </CONTACT>

</xsl:template> 
</xsl:stylesheet>

它应该工作：）

在XSLT 1.0中对两个联系人进行分组和合并

3 个答案: