Question

[求助] francescalus。双精度动态数组的工作代码是：

  module DynamicalArrays

  contains

      subroutine AddToList(list, element)

          IMPLICIT NONE

          integer :: i, isize
          double precision, intent(in) :: element
          double precision, dimension(:), allocatable, intent(inout) :: list
          double precision, dimension(:), allocatable :: clist


          if(allocated(list)) then
              isize = size(list)
              allocate(clist(isize+1))
              do i=1,isize          
              clist(i) = list(i)
              end do
              clist(isize+1) = element

              deallocate(list)
              call move_alloc(clist, list)

          else
              allocate(list(1))
              list(1) = element
          end if


      end subroutine AddToList


  end module DynamicalArrays

可以填充数组的demo子例程将是：

  subroutine UserDArrayTest()

  use DynamicalArrays


  integer :: i
  double precision, dimension(:), allocatable :: list
  double precision :: temp

  temp = 0.1
  do i=1,10
    temp = temp+1
    call AddToList(list, temp)
  end do

  do i=1,10
    print *, i, list(i)
  end do


  end

请注意，最好将模块代码保存在单独的文件中，但我也发现它在模块代码高于主程序和子程序代码时有效。

---------------原始问题-----------------

我需要在Fortran 90中使用动态数组，以备最初无法预测数组精确大小的情况。所以我编写了一个代码，每次将新元素添加到数组末尾时都应该扩展可分配数组：

  subroutine DArray()

  double precision, dimension(:), allocatable :: list

  allocate(list(1))

  list(1) = 1.1

  call AddToList(list, 2.2)
  call AddToList(list, 3.2)
  call AddToList(list, 4.2)
  call AddToList(list, 5.2)

  print *, list(1)
  print *, list(2)
  print *, list(3)
  print *, list(4)
  print *, list(5)


  end



  subroutine AddToList(list, element)

  double precision :: element
  double precision, dimension(:), allocatable :: list
  double precision, dimension(:), allocatable :: clist

  if(allocated(list)) then
    isize = size(list)
    allocate(clist(isize+1))
    do i=1,isize
        clist(i) = list(i)
    end do
    clist(i+1) = element

    deallocate(list)
    allocate(list(isize+1))

    do i=1,isize+1
        list(i) = clist(i)
    end do

    deallocate(clist)

  end if


  end

所以有人看到我在这里遗漏了什么吗？ [求助 - 看下面的答案和顶部的完整代码]

Answer 1

我怀疑，看着一件文物，你注意到了这个问题 - 但很快就开始了。

可疑的一句话，对我来说是：

    allocate(clist(isize+2))

为什么不是新尺寸isize+1？我想你试过了，但程序失败了。

了解程序失败的原因（可能已崩溃）是您无法获得正确结果的关键。仔细观察循环（为清晰起见，删除了打印语句）。

do i=1,isize
    clist(i) = list(i)
end do
clist(i+1) = element

你想说“将列表中的所有元素复制到clist，然后追加元素”。哪个是对的。然而

do i=1,isize
    clist(i) = list(i)
end do
! Here, i=isize+1
clist(i+1) = element
! Which means
! clist(isize+2) = element.

总之，在循环之后，循环索引变量没有它在最后一次迭代中所具有的值。

Answer 2

我知道这个问题很老了，但是最近我不得不构建这样的子例程，我发现从Fortran2003开始，有一个漂亮的衬里：

    SUBROUTINE append_int(vec, val)
    !***********************************************************************
    !> \brief Appends val in vec if not already present
    !> \date 05 2020
    !***********************************************************************
    INTEGER, DIMENSION(:), ALLOCATABLE, INTENT(INOUT)    :: vec
    INTEGER, INTENT(IN)                                  :: val

    ! Remove this test if you don't mind not having unique values
    IF (.NOT. ANY(vec .EQ. val)) THEN
        vec = [vec, val]
    END IF

    END SUBROUTINE

您的数组将自动以适当的大小重新分配。另外，您可以为Reals生成等效的例程，以将一个数组附加到另一个...，然后将它们全部包装在一个接口中，以便无论数据类型如何，您始终可以调用同一子例程。

如何在Fortran 90中向动态数组中添加新元素

2 个答案: