Question

我试图弄清楚是否有一种方法可以在Groovy中使用OpenCSV访问CSV中的列标题？这就是我所拥有的：

@GrabConfig( systemClassLoader=true )
@Grab( 'mysql:mysql-connector-java:5.1.27' )
@Grab(group = 'net.sf.opencsv', module = 'opencsv', version = '2.3')
import groovy.sql.Sql
import au.com.bytecode.opencsv.CSVReader
import au.com.bytecode.opencsv.CSVParser
def sql = Sql.newInstance("jdbc:mysql://localhost:3306/nid", "developer","whatever", "com.mysql.jdbc.Driver")
def notes = sql.dataSet("vdc_notifications")
def TEST_FILE_NAME = 'C:\\Users\\me\\Desktop\\test.csv'

List<String[]> rows = new CSVReader(new FileReader(new File(TEST_FILE_NAME)), CSVParser.DEFAULT_SEPARATOR, CSVParser.DEFAULT_ESCAPE_CHARACTER, CSVParser.DEFAULT_QUOTE_CHARACTER).readAll()

我想要做的是：

rows.each() { row -> println row.some_column_name }

Answer 1

通常，CSV文件的第一行包含列的名称。所以你可以使用一种简单的解析方法，并为标题取第一行：

@Grab('net.sf.opencsv:opencsv:2.3')
import au.com.bytecode.opencsv.CSVReader
import au.com.bytecode.opencsv.bean.CsvToBean;
import au.com.bytecode.opencsv.bean.HeaderColumnNameMappingStrategy;

def csv = """\
name,age
Charlie,23
Billy,64"""

// read the files and keep the first one as the header
def csvr = new CSVReader(new StringReader(csv))
def header
while ((line=csvr.readNext())) {
    if (!header) {
        header = line
    } else {
        // create a map from the header and the line
        println([header,line].transpose().collectEntries())
    }
}

或者您可以使用CsvToBean和HeaderColumnNameMappingStrategy来创建bean：

class Person {
    String name
    Integer age
}

// use the mapper
def ctb = new CsvToBean<Person>()
def hcnms = new HeaderColumnNameMappingStrategy<Person>()
hcnms.type = Person
println ctb.parse(hcnms, new StringReader(csv))

请参阅列标题csv Groovy

1 个答案: