Question

对于XSLT 2甚至3，How to find all numbers in a string有一些很好的解决方案。如何在XSLT 1的范围内完成同样的事情（在EXSLT的帮助下）？

以下是一个例子：

<data>
  <sig>NL Mellin 1-1 36</sig>
  <sig>NL Mellin 1-1 38</sig>
  <sig>NL Mellin 1-10 02</sig>
  <sig>NL Mellin 1-10 04</sig>
  <sig>NL Mellin 1-10 09</sig>
</data>

所需的输出是：

Answer 1

以这种方式尝试：

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="utf-8" />

<xsl:template match="/">
    <xsl:for-each select="data/sig">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="translate(., '-', ' ')"/>
        </xsl:call-template>
        <xsl:if test="position()!=last()">
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="' '"/>
        <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" />
        <xsl:if test="$token = translate($token, translate($token, '0123456789', ''), '')">
                <xsl:value-of select="$token"/>
                <xsl:text> </xsl:text>
        </xsl:if>
        <xsl:if test="contains($text, $delimiter)">
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            </xsl:call-template>
        </xsl:if>
</xsl:template>

</xsl:stylesheet>

注意：

如果您有多个分隔符，则需要将它们转换为公共字符（我的示例中为空格）;

我没有费心去掉每一行的尾随空格;

如果您的处理器支持EXSLT str：tokenize（）函数，则可能更简单。

如何使用XSLT 1查找字符串中的所有数字

1 个答案: