Question

我有一个XSL需要过滤掉XML中的特定数据。

在我的XML中某处会有一个节点，如：

<id root="2.16.840.1.113883.3.51.1.1.6.1" extension="9494949494949" />

我在下面的XSL删除扩展名节点，并向节点添加 nullFlavor =“MSK”。

我现在需要做的是从扩展节点获取值，并在整个XML文档中搜索该值，并将其替换为 * *。

但是我不确定如何使用扩展属性，并在XML中查找该值的所有实例（它们可以隐藏在文本和内部属性中）并将它们转换为 * *（4 *）。

以下示例只是一个示例。我不能硬编码XSL来查看特定节点，它需要查看xml中的所有文本/属性文本（原因是这将有5个不同版本的XML将应用于此）。

我需要在节点中找到Extension，然后从XML的其余部分替换（真正删除）该值。我正在寻找适合所有消息的1解决方案，因此全局搜索＆gt;擦除扩展值。

示例：

        <identifiedPerson classCode="IDENT">
                <id root="2.16.840.1.113883.3.51.1.1.6.1" extension="9494949494949" displayable="true" />
                <addr use="PHYS">
                    <city>KAMLOOPS</city>
                    <country>CA</country>
                    <postalCode>V1B3C1</postalCode>
                    <state>BC</state>
                    <streetAddressLine>1A</streetAddressLine>
                    <streetAddressLine>2A</streetAddressLine>
                    <streetAddressLine>9494949494949</streetAddressLine>
                    <streetAddressLine>4A</streetAddressLine>                        
                </addr>
                <note text="9494949494949 should be stars"/>

应该是（以下XSLT已经屏蔽了具有匹配OID的节点中的扩展名）。

            <identifiedPerson classCode="IDENT">
                <id root="2.16.840.1.113883.3.51.1.1.6.1" nullFlavor="MSK" displayable="true" />
                <addr use="PHYS">
                    <city>KAMLOOPS</city>
                    <country>CA</country>
                    <postalCode>V1B3C1</postalCode>
                    <state>BC</state>
                    <streetAddressLine>1A</streetAddressLine>
                    <streetAddressLine>2A</streetAddressLine>
                    <streetAddressLine>****</streetAddressLine>
                    <streetAddressLine>4A</streetAddressLine>                        
                </addr>
                <note text="**** should be stars"/>

任何帮助都将不胜感激。

我可以使用XSL 2.0

我有当前的XSL.IT工作正常。它匹配根为“2.16.840.1.113883.3.51.1.1.6.1”的任何标记，杀死所有属性并添加nullFlavor =“MSK”。但是，这不会在整个XML中搜索相同的＃。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:param name="attrToKeep" select="'root'" />

    <xsl:template match="* | node()">
      <xsl:copy>
        <xsl:apply-templates select="node()|@*" />
      </xsl:copy>
    </xsl:template>

    <xsl:template match="@*">
      <xsl:choose>
        <xsl:when test="../@root = '2.16.840.1.113883.3.51.1.1.6.1'">
          <xsl:copy-of select=".[contains($attrToKeep, name())]" />     
          <xsl:attribute name="nullFlavor">MSK</xsl:attribute>
          <!-- Need some way to use the value found in this node and hide the extension -->
        </xsl:when>
        <xsl:otherwise>
          <xsl:copy-of select="." />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

任何帮助都将不胜感激。

谢谢，

Answer 1

尝试使用变量来保存要替换的文本的值。像这样：

<xsl:variable
    name="rootVar"
    select="//*[@root = '2.16.840.1.113883.3.51.1.1.6.1']/@extension" />

然后您应该能够使用replace函数替换它们。

<xsl:template match="'//@*' | text()">
    <xsl:sequence select="replace(., $rootVar, '****')"/>
</xsl:template>

Answer 2

XSLT 2.0样式表

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

  <xsl:param name="replacement" select="'****'"/>

  <xsl:param name="new" select="'MKS'"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="identifiedPerson">
    <xsl:copy>
      <xsl:apply-templates select="@* , node()">
        <xsl:with-param name="to-be-replaced" select="id/@extension" tunnel="yes"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="identifiedPerson//text()">
    <xsl:param name="to-be-replaced" tunnel="yes"/>
    <xsl:sequence select="replace(., $to-be-replaced, $replacement)"/>
  </xsl:template>

  <xsl:template match="identifiedPerson//@*">
    <xsl:param name="to-be-replaced" tunnel="yes"/>
    <xsl:attribute name="{name()}" namespace="{namespace-uri()}" select="replace(., $to-be-replaced, $replacement)"/>
  </xsl:template>

  <xsl:template match="identifiedPerson/id">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:attribute name="nullFlavor" select="$new"/>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="identifiedPerson/id/@extension"/>

</xsl:stylesheet>

变换

<identifiedPerson classCode="IDENT">
        <id root="2.16.840.1.113883.3.51.1.1.6.1" extension="9494949494949" displayable="true" />
        <addr use="PHYS">
            <city>KAMLOOPS</city>
            <country>CA</country>
            <postalCode>V1B3C1</postalCode>
            <state>BC</state>
            <streetAddressLine>1A</streetAddressLine>
            <streetAddressLine>2A</streetAddressLine>
            <streetAddressLine>9494949494949</streetAddressLine>
            <streetAddressLine>4A</streetAddressLine>                        
        </addr>
        <note text="9494949494949 should be stars"/>
</identifiedPerson>

与Saxon 9.4合作

<?xml version="1.0" encoding="UTF-8"?><identifiedPerson classCode="IDENT">
                <id root="2.16.840.1.113883.3.51.1.1.6.1" displayable="true" nullFlavor="MKS"/>
                <addr use="PHYS">
                    <city>KAMLOOPS</city>
                    <country>CA</country>
                    <postalCode>V1B3C1</postalCode>
                    <state>BC</state>
                    <streetAddressLine>1A</streetAddressLine>
                    <streetAddressLine>2A</streetAddressLine>
                    <streetAddressLine>****</streetAddressLine>
                    <streetAddressLine>4A</streetAddressLine>
                </addr>
                <note text="**** should be stars"/>
        </identifiedPerson>

因此，对于样本，我认为它解决了这个问题。我不确定是否可以有更多关于该样本的上下文，以及是否要更改identifiedPerson元素之外的值或者不想更改它们（上面的样式表也是如此）。如果还需要更改其他元素，请考虑发布更长的输入和想要的结果样本来说明，并解释什么决定了要替换的值的节点。

[编辑] 根据你的评论我调整了样式表，它现在有一个传递id的参数（例如2.16.840.1.113883.3.51.1.1.6.1），然后它查找任何名称的元素，其中root属性具有传入的id value并替换在文档中找到的所有属性和所有文本节点中找到的extension属性值。此外，nullFlavor属性会添加到具有ID的元素中，并删除其extension属性。

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

  <xsl:param name="root-id" select="'2.16.840.1.113883.3.51.1.1.6.1'"/>
  <xsl:variable name="to-be-replaced" select="//*[@root = $root-id]/@extension"/>

  <xsl:param name="replacement" select="'****'"/>

  <xsl:param name="new" select="'MKS'"/>

  <xsl:template match="comment() | processing-instruction()">
    <xsl:copy/>
  </xsl:template>

  <xsl:template match="*">
    <xsl:copy>
      <xsl:apply-templates select="@* , node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="text()">
    <xsl:sequence select="replace(., $to-be-replaced, $replacement)"/>
  </xsl:template>

  <xsl:template match="@*">
    <xsl:attribute name="{name()}" namespace="{namespace-uri()}" select="replace(., $to-be-replaced, $replacement)"/>
  </xsl:template>

  <xsl:template match="*[@root = $root-id]">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:attribute name="nullFlavor" select="$new"/>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*[@root = $root-id]/@extension"/>

</xsl:stylesheet>

用****替换XML中的所有字符串实例

2 个答案: