Question

在Windows批处理中，您可以在变量中设置变量吗？

说明：

所以％num％在变量中。

set num=5
set cnum=test
set h1=%c%num%%

是否有可能使百分数像括号一样工作？输出应为h1 = test

任何帮助都将不胜感激。

Answer 1

您可能正在寻找“呼叫设置”命令。这将cnum设置为字符串c1，c2，c3等。每次％num％更改时它都会更改。然后，您可以使用“调用集”将任何变量（例如h1）分配给变量cnum所代表的值。

@echo off
setlocal enabledelayedexpansion
    set c5=test
    set num=5

    :: set cnum to string "c5"
        set cnum=c%num%
    :: set h1 to to the existing variable c5 
        call set "h1=%%%cnum%%%"
        echo %h1%

Answer 2

你是否经历过这样的事情？

cls
@echo off
setlocal EnableDelayedExpansion
Set num=5
Set "c!num!=test"
Echo !c5!

有关延迟扩展的详细信息，请参阅http://ss64.com/nt/delayedexpansion.html。

cls
@echo off
setlocal EnableDelayedExpansion
set num=4
set c1=this is a demo
set c2=second example
set c3=third
set c4=this is the one I want
set c5=last
Echo !c%num%!

Answer 3

你问题中的例子很乱，但我想我明白你在找什么：

@echo off
setlocal

set C1=apple
set C2=orange
set C3=banana

set num=2


:: Inefficient way without delayed expansion
:: This will be noticeably slow if used in a tight loop with many iterations
call echo %%C%num%%%

:: The remaining methods require delayed expansion
setlocal enableDelayedExpansion

:: Efficient way 1
echo(
echo !C%num%!

:: Efficient way 2 - useful if inside parenthesized block
:: where %num% will not give current value
echo(
for %%N in (!num!) do echo !C%%N!

:: Showing all values via a loop
echo(
for /l %%N in (1 1 3) do echo !C%%N!

变量中的Windows批处理变量

3 个答案: