Question

我正在开发一个程序，它向列表的元素添加'+'或' - '，具体取决于该元素的索引是奇数还是偶数（即交替的和列表）。

但是，我无法确定每个元素的索引是什么。我使用if statements和mod

代码我认为应该附加正确的符号

fun alternating([]) = 0
  | alternating(l) = 
        if List.nth(l,hd(l)) mod 2 == 0 then '+'@hd(l)@alternating(tl(l))
        else '-'@hd(l)@alternating(tl(l))

但是，List.nth(l,hd(l))始终返回第二个索引处的元素，而不是第一个索引。

Answer 1

如果你真的只是想要否定它们的整数，那么你可以将它们传递给某种求和，如果它是奇数，我就会否定论证。使用相互递归可以在没有任何明确的索引簿记的情况下完成：

fun alternate l =
   let
       fun alternate1 []      = []
         | alternate1 (x::xs) = (~x) :: alternate2 xs
       and alternate2 []      = []
         | alternate2 (x::xs) =   x  :: alternate1 xs
   in
       alternate1 l
   end

它的工作原理如下：

- alternate [1,2,3,4];
val it = [~1,2,~3,4] : int list

我强烈建议您使用模式匹配而不是hd。

修改讨论hd

根据经验，如果您需要hd，您可能还需要tl。 hd是部分函数 - 如果列表为空，它将抛出Empty。如果你模式匹配，你可以方便地获得列表的头部和尾部的变量，并且你得到一个视觉提示，你需要处理空列表。 IMO，在美学上更令人愉悦：

fun foo []      = ...
  | foo (x::xs) = ...

比同等的

fun foo l = 
  if null l 
    then ... 
    else (hd l) ... (tl l)

换句话说，您可以使用自动提醒功能获得更短，更清晰的代码，以使其正确无误。赢/赢。据我所知，以另一种方式做这件事没有明显的优势。当然，您可能会发现自己处于这样一种情况，即您知道该列表至少包含一个元素，而您不需要执行任何其他操作。你仍然需要考虑你给出的案例，但这是一个很好的经验法则。

Answer 2

如果您想用索引装饰您的列表，可以尝试类似以下内容

fun add_index l =
  let 
    fun add_index_helper (nil,  _) = nil
      | add_index_helper (h::tl,i) = (h,i) :: add_index_helper (tl,1+i)
  in
     add_index_helper (l,0)
  end

val x = add_index [0,1,4,9,16,25]

但您也可以使用相同的方法直接计算奇偶校验

fun add_sign l =
  let 
    fun add_sign_helper (nil,  _) = nil
      | add_sign_helper (h::tl,i) = (h,i) :: add_sign_helper (tl,1-i)
  in
     add_sign_helper (l,0)
  end

val y = add_sign [0,1,4,9,16,25]

然后您可以将奇偶校验映射到字符串

fun sign_to_char (x,0) = (x,"+")
  | sign_to_char (x,_) = (x,"-")

val z = List.map sign_to_char y

或者您可以直接添加标志

fun add_char l =
  let 
    fun add_char_helper (nil,  _) = nil
      | add_char_helper (h::tl,0) = (h,"+") :: add_char_helper (tl,1)
      | add_char_helper (h::tl,_) = (h,"-") :: add_char_helper (tl,0)
  in
     add_char_helper (l,0)
  end

val zz = add_char [0,1,4,9,16,25]

或者，如果您有一个字符串列表并且想要添加字符，则可以尝试这样的

fun signs L =
  let
    datatype parity = even | odd
    fun signs_helper ( nil ,_) = nil
      | signs_helper (x::xs,even) = ("+" ^ x) :: signs_helper(xs,odd)
      | signs_helper (x::xs,odd)  = ("-" ^ x) :: signs_helper(xs,even)
  in
    signs_helper (L,even)
  end

val z = signs ["x","2y","3z","4"]
(* this gives you val z = ["+x","-2y","+3z","-4"] : string list *)

SML - 获取列表索引

2 个答案: