Question

我正在使用XML::LibXML来解析带有命名空间的XML文档。因此，我使用XPath findnodes将XML::LibXML::XPathContext用于//u:model。这正确地返回3个节点。

我现在想对3个返回的XML::LibXML::Element对象使用findvalue，但无法确定工作方法/ xpath。作为替代方案，我迭代子节点并直接与nodeName匹配，但这不太理想：

use strict;
use warnings;

use XML::LibXML;
use XML::LibXML::XPathContext;

my $dom = XML::LibXML->load_xml( IO => \*DATA );
my $context = XML::LibXML::XPathContext->new( $dom->documentElement() );
$context->registerNs( 'u' => 'http://www.ca.com/spectrum/restful/schema/response' );

for my $node ( $context->findnodes('//u:model') ) {
    #my $mh = $node->findvalue('mh');
    my ($mh)
        = map { $_->textContent() }
        grep  { $_->nodeName() eq 'mh' } $node->childNodes();

    #my $attr = $node->findvalue('attribute');
    my ($attr)
        = map { $_->textContent() }
        grep  { $_->nodeName() eq 'attribute' } $node->childNodes();

    print "mh = $mh, attr = $attr\n";
}

__DATA__
<root xmlns="http://www.ca.com/spectrum/restful/schema/response">
  <error>EndOfResults</error>
  <throttle>86</throttle>
  <total-models>86</total-models>
  <model-responses>
    <model>
      <mh>0x100540</mh>
      <attribute id="0x1006e">wltvbswfc02</attribute>
    </model>
    <model>
      <mh>0x100c80</mh>
      <attribute id="0x1006e">wltvsutm1ds02</attribute>
    </model>
    <model>
      <mh>0x100c49</mh>
      <attribute id="0x1006e">wltvsdora03</attribute>
    </model>
  </model-responses>
</root>

OUPUTS：

mh = 0x100540, attr = wltvbswfc02
mh = 0x100c80, attr = wltvsutm1ds02
mh = 0x100c49, attr = wltvsdora03

有没有办法使用注释掉的行来查找节点而不是迭代子节点的间接方法？或者是否有另一种方法来解决此问题以获得配对值？

Answer 1

由于整个默认命名空间的原因，您无法使用$node->findvalue()。但是，您可以重用XML :: LibXML :: XPathContext对象来查找所需的值：

for my $node ( $context->findnodes('//u:model') ) {
   my $mh   = $context->findvalue('u:mh', $node);
   my $attr = $context->findvalue('u:attribute', $node);
   print "mh = $mh, attr = $attr\n";
}

Answer 2

XPath允许使用函数local-name忽略命名空间：

use XML::LibXML;

my $dom = XML::LibXML->load_xml( IO => \*DATA );

for my $node ( $dom->findnodes('//*[local-name()="model"]') ) {
    my $mh   = $node->findvalue('*[local-name()="mh"]');
    my $attr = $node->findvalue('*[local-name()="attribute"]');

    print "mh = $mh, attr = $attr\n";
}

这样就无需为问题中的单个命名空间文档指定上下文。

参考：Re^2: XML::LibXML and namespaces

XML :: LibXML，名称空间和findvalue

2 个答案: