Question

以下是尝试解析以提取与节点公司对应的属性值的示例数据：公司节点下所有公司节点的CID，名称，符号，值

<?xml version="1.0" encoding="UTF-8"?>
<StockRecords xmlns="http://url1"
              xmlns:ref="http://url2"
              xmlns:xsi="http://url3">
  <Companies>
    <Company>
      <CID>123</CID>
      <Name>Google</Name>
      <Symbol>GOOG</Symbol> 
      <Value>1234</Value>
    </Company>
  </Companies>
</StockRecords>

以下是我尝试的两种变体。 变体1

use XML::LibXML;

my $filename = "test.xml";
my $dom = XML::LibXML->load_xml(location => $filename);

foreach my $sample ($dom->findnodes( '/Companies/Company' )) {

    print Dumper($sample);
    last;
}

变体2：由于其中涉及名称空间，因此需要指定XPathContext。

use XML::LibXML;

my $filename = "test.xml";
my $parser = XML::LibXML->new();
my $xmldoc = $parser->parse_file($filename);

my $root = $xmldoc->getDocumentElement;

my @l = $root->getElementsByTagName('StockRecords');

my $xc = XML::LibXML::XPathContext->new($root);

$xc->registerNs("ns1", "http://url1");
$xc->registerNs("ref", "http://url2");
$xc->registerNs("xsi", "http://url3");

无法提取节点的任何属性的数据。我确实看了一下其他答案，LibXML文档仍有一些遗漏。请帮我一些指示。感谢

Answer 1

use strict;
use warnings;
use feature qw( say );

use XML::LibXML               qw( );
use XML::LibXML::XPathContext qw( );

my $doc = XML::LibXML->load_xml( location => $ARGV[0] );

my $xpc = XML::LibXML::XPathContext->new();
$xpc->registerNs( ns1 => "http://url1" );

for my $company_node ($xpc->findnodes("/ns1:StockRecords/ns1:Companies/ns1:Company", $doc)) {
   say $xpc->findvalue("ns1:CID", $company_node);
   say $xpc->findvalue("ns1:Name", $company_node);
}

使用XML :: LibXML

1 个答案: