使用多色时，图表被翻转

Question

我想使用多色图绘制两个图表（读取相同的数据点）。目的是将第二个（较小的）图表放在第一个（较大）图表的右侧。

代码是

set term post eps enhanced color blacktext size 4,4 solid "Times-Roman" 14
set output 'cla.ps'

set multiplot

# draw bottom and left lines
unset border
unset xtics
unset ytics
set border 3


# increasing the canvas size
set rmargin 50
set tmargin 2

# put the big chart, it will not use the whole space
set origin 0,0
set size 1.2,0.5

plot 'test.txt' u 1 with points lc rgb "black" 

# put the small char in the right
set origin 0.6,0.2
set size 0.2,0.2
plot 'test.txt' u 1 with points lc rgb "black" 

# always unset multiplot
unset multiplot

问题是，第二个图表以镜像方式显示（水平翻转）。但我没有这样的选择。我该如何解决这个问题？

Answer 1

这应该给你一个很好的警告，解释：warning: Terminal canvas area too small to hold plot. Check plot boundary and font sizes.

使用set rmargin 50将右边距设置为50个字符宽度。这也适用于第二个图，除非你使用例如set rmargin -1将其重置为自动计算。

但我认为设置大小和rmargin没有任何意义。设置rmargin 不会增加画布大小，就像您在评论中建议的那样。

这是一个有效的例子：

set term post eps enhanced color blacktext size 4,2 solid "Times-Roman" 14
set output 'cla.ps'

set multiplot

# draw bottom and left lines
unset tics
set border 3

# put the big chart, it will not use the whole space
set origin 0,0
set size 0.8,1

plot x**2

# put the small char in the right
set origin 0.75,0.2
set size 0.25,0.3
plot x

# always unset multiplot
unset multiplot

它为您提供输出（使用4.6.5测试）：