父：

Question

我正在尝试使用管道和Node的node.js模块让两个长时间运行的child-process进程进行通信 - 一个父进程和一个子进程。我希望孩子能够异步地将数据发送回父级，我希望使用pipe这样做。

这是我的代码的简化版本：

父：

cp = require('child_process')
es = require('event-stream')

child = cp.spawn('coffee', ['child.coffee'], {stdio: [null, null, null, 'pipe']})

so = child.stdout.pipe(es.split())
p3 = child.stdio[3].pipe(es.split())

so.on 'data', (data) ->
  console.log('stdout: ' + data)

child.stderr.on 'data', (data) ->
  console.log('stderr: ' + data);

p3.on 'data', (data) ->
  console.log('stdio3: ' + data);

child.on 'close', (code) ->
  console.log('child process exited with code ' + code)

child.stdin.write "a message from your parent", "utf8"

子：

fs = require('fs')

p3 = fs.createWriteStream('/dev/fd/3', {encoding: 'utf8'})

process.stdin.on 'data', (data) ->
    p3.write "hello #{process.pid} - #{data}\n", 'utf8'
    process.stdout.write "world #{process.pid} - #{data}\n", 'utf8'
    p3.end()
    process.exit(0)

process.stdin.on 'end', (data) ->
    console.log "end of stdin"
    p3.end()
    process.exit(0)

process.stdin.setEncoding('utf8')
process.stdin.resume()

该代码适用于OSX 10.9，但无法在Ubuntu框上运行。我试过在Ubuntu 12.04和14.04下运行它。我正在运行Node 10.2x。

Ubuntu下的

/dev/fd/符号链接到/proc/self/fd/所以我相信我的子进程正在打开正确的文件。

在Ubuntu上运行父项的输出如下：

$ coffee parent.coffee 
stderr: 

stderr: events.js:72

stderr:         throw er; // Unhandled 'error' event

stderr:  
stderr:  
stderr:  
stderr:  
stderr:           ^

stderr: Error: UNKNOWN, open '/dev/fd/3'




events.js:72
        throw er; // Unhandled 'error' event
              ^
Error: read ECONNRESET
  at errnoException (net.js:901:11)
  at Pipe.onread (net.js:556:19)

我希望看到（并在OSX盒子上做）：

$ coffee parent.coffee 
stdio3: hello 21101 - a message from your parent
stdout: world 21101 - a message from your parent
stdio3: 
stdout: 
child process exited with code 0

也可以在Ubuntu上使用命令行与子进行通信，因此在生成子进程时父进程可能会出现问题：

$ echo foo | coffee child.coffee 3>&1
hello 3077 - foo

world 3077 - foo

我试图调查节点使用strace进行的内核调用，但是对输出没有多大意义。

Answer 1

我自己想通了。错误发生在孩子身上。在打开已经打开的文件时，Ubuntu linux更加严格：

p3 = fs.createWriteStream('/dev/fd/3', {encoding: 'utf8'})

发生错误。子进程运行时文件描述符3已经打开，因此代码应如下所示：

子：

fs = require('fs')

# parent opens the file descriptor 3 when spawning the child (and closes it when the child returns)
fd3write = (s) ->
    b = new Buffer(s)
    fs.writeSync(3,b,0,b.length)

process.stdin.on 'data', (data) ->
    fd3write "p3 #{process.pid} - #{data}\n"
    process.stdout.write "so #{process.pid} - #{data}\n", 'utf8'
    process.exit(0)

process.stdin.on 'end', (data) ->
    console.log "end of stdin"
    process.exit(0)

process.stdin.setEncoding('utf8')
process.stdin.resume()

我希望这对其他人有帮助。

要使用管道而不是stdin将消息从父级发送给子级，此链接可能有用：child-process-multiple-file-descriptors。

Node.js子进程和管道 - OSX与Ubuntu

父：

子：

1 个答案:

子：