Question

我有3个节点的Cassandra 2.x群集和这样的db方案：

cqlsh> CREATE KEYSPACE test_ks WITH REPLICATION = {'class': 'SimpleStrategy', 'replication_factor': 3} AND durable_writes = true;
cqlsh> CREATE TABLE IF NOT EXISTS test_ks.test_cf (
   ...   time timeuuid,
   ...   user_id varchar,
   ...   info varchar,
   ...   PRIMARY KEY (time, user_id)
   ... ) WITH compression = {'sstable_compression': 'LZ4Compressor'} AND compaction = {'class': 'LeveledCompactionStrategy'};

让我们添加一些数据（等待插入一段时间）：

cqlsh> INSERT INTO test_ks.test_cf (time, user_id, info) VALUES (now(), 'user1', 'pythonista');
cqlsh> INSERT INTO test_ks.test_cf (time, user_id, info) VALUES (now(), 'user1', 'mr. Haskell');

让我们看看我们的数据：

cqlsh> SELECT dateOf(time), user_id, info FROM test_ks.test_cf;

 dateOf(time)             | user_id | info
--------------------------+---------+-------------
 2014-06-24 16:00:31+0700 |   user1 | mr. Haskell
 2014-06-24 15:59:32+0700 |   user1 |  pythonista

(2 rows)

我在查询test_cf CF时得到了一些奇怪的结果：

cqlsh> SELECT dateOf(time) FROM test_ks.test_cf WHERE user_id='user1' AND token(time) >= token(maxTimeuuid('2014-06-24 16:00:31+0700')) ALLOW FILTERING;

 dateOf(time)
--------------------------
 2014-06-24 15:59:32+0700

(1 rows)

cqlsh> SELECT dateOf(time) FROM test_ks.test_cf WHERE user_id='user1' AND token(time) >= token(maxTimeuuid('2014-06-24 16:00:32+0700')) ALLOW FILTERING;

 dateOf(time)
--------------------------
 2014-06-24 15:59:32+0700

(1 rows)

cqlsh> SELECT dateOf(time) FROM test_ks.test_cf WHERE user_id='user1' AND token(time) >= token(maxTimeuuid('2014-06-24 16:00:33+0700')) ALLOW FILTERING;

 dateOf(time)
--------------------------
 2014-06-24 16:00:31+0700
 2014-06-24 15:59:32+0700

(2 rows)

正如您所看到的，比较结果错误，但timeuuid不得大于maxTimeuuid且必须大于'minTimeuuid'（对于相同的日期时间，当然=））。有人可以向我解释这种奇怪的行为吗？

TIA！

Answer 1

首先，你的主键是向后的 - 如果你想执行这样的查询，你的CREATE TABLE语句应如下所示：

CREATE TABLE IF NOT EXISTS test_ks.test_cf (
  time timeuuid,
  user_id varchar,
  info varchar,
  PRIMARY KEY (user_id, time)
) WITH compression = {'sstable_compression': 'LZ4Compressor'}
  AND compaction = {'class': 'LeveledCompactionStrategy'};

这使得user_id成为分区键，time成为符合您查询模式的群集列。

通过此更改，您不再需要使用TOKEN函数，这是对分区键进行范围查询所必需的，但对于聚类列没有意义（通常不对应于列值的语义顺序））。由于time现在是一个聚类列，您只需要进行常规比较：

SELECT dateOf(time)
FROM test_ks.test_cf
WHERE user_id='user1'
  AND time >= maxTimeuuid('2014-06-24 16:00:31+0700');

您也可以删除ALLOW FILTERING，因为您现在正在执行标准范围切片而非令牌比较，这需要扫描所有行并进行比较。

时间比较的奇怪行为

1 个答案: