Question

我不明白为什么这不起作用。我用$$尝试usind int值，并且它工作得很好，但除非有另一种方式，我希望它与chars一起使用。这是我的.l文件：

%{
#include "y.tab.h"
%}
%option noyywrap
%option yylineno
%%
DEFINE return DEFINETAG;
BEGIN return BEGINTAG;
END return ENDTAG;
[A-Z]+[0-9] {strcpy(yylval.buf,yytext); return AUT;}
[a-z_]+(0|[1-9][0-9]*)? {strcpy(yylval.buf, yytext); return EST;}
(\{[^}*]*\})* {strcpy(yylval.buf, yytext); return CODC;}
[->;] return yytext[0];
[ \t\n] ;
. yyerror("Caracter Inválido");
%%

这是我的.y文件：

%{
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
extern int yylineno;
int r; int c;
%}
%union {char buf[50]; int val;}
%start gda
%token<buf> BEGINTAG ENDTAG DEFINETAG AUT EST CODC
%type<buf> desta daute dest dtraa dautt dtra
%%
gda  : gda desta dtraa devea {char ma[r][c]; printf("%d, %d\n",r,c);}
     |
     ;
desta: DEFINETAG BEGINTAG daute ENDTAG {$$=$3;}
     ;
daute: daute AUT dest {$$=$3;}
     |
     ;
dest : dest EST {r=r+1;$$=$2;}
     | EST {r=r+1;$$=$1;}
     ;
dtraa: DEFINETAG BEGINTAG dautt ENDTAG 
     ;
dautt: dautt AUT dtra 
     |
     ;    
dtra : dtra EST '-''>' EST {c=c+1;}
     | EST '-''>' EST {c=c+1;}
     ;
devea: devea AUT {printf("void %s(){\n",$2);} BEGINTAG deve ENDTAG {printf("}\n");}
     | AUT {printf("void %s(){\n",$1);} BEGINTAG deve ENDTAG {printf("}\n");}
     ;
deve : deve est CODC
     | 
     ;
est  : EST '-''>' EST {printf("if(estado==%s)estado=%s;\n",$1,$4);}
     |
     ;
%%
int main(){
yyparse();
return 0;
}
int yyerror(char *s){fprintf(stderr, "ERRO(%d):%s\n", yylineno,s); return 0;}

这是我的错误列表：

gda2.y: In function ‘yyparse’:
gda2.y:16:12: error: incompatible types when assigning to type ‘char[50]’ from type ‘char *’
gda2.y:18:12: error: incompatible types when assigning to type ‘char[50]’ from type ‘char *’
gda2.y:21:18: error: incompatible types when assigning to type ‘char[50]’ from type ‘char *’
gda2.y:22:18: error: incompatible types when assigning to type ‘char[50]’ from type ‘char *’

Answer 1

在C中，分配给数组是不合法的。例如，你不能这样做：

 char c[50];
 c = "abc";  /* ILLEGAL */

将数组放在union中无法解决问题：

 union {
   char c[50];
   int  i;
 } u;
 u.c = "abc";  /* ILLEGAL */

然而，奇怪的是，即使它们包含数组，您也可以将一个结构分配给另一个结构：

 struct FiftyChars {
   char c[50];
 };

 struct FiftyChars a,b;
 strncpy(a.c, "abc", 49);
 b = a;                /* ¡LEGAL! */

bison和yacc不允许您避免C的规则。因为$$ = $2实际上已翻译成以下内容：

yylval.buf = yystack[top - 2].buf;

无论buf指的是需要允许直接分配。所以它不能是一个数组。但可以是struct，其唯一成员是数组。这意味着您可以将%union声明更改为

%union {struct {char c[50];} buf; int val;}

然后在整个代码中进行适当的更改（例如在buf输入文件中将buf.c更改为flex，在您的$n中更改为$n.c的printf的）。

或者，您可以通过使用strncpy复制字符串并编写

来避免此问题

strncpy($$, $1, 49);

而不是

$$ = $1;

在你的行动中。这应该适用于野牛，虽然我不知道yacc的每个实现是否会将默认操作（$$ = $1）作为联合副本处理（这可能会很好）或作为类型副本（它会抛出一个错误）。

另一方面，您可能在某些时候需要问自己大小50的来源。它绝对清楚它足够大吗？您是否检查以确保令牌永远不会超过49个字符？您的代码是否可能充满潜在的缓冲区溢出？

一旦你开始这样思考，你会发现最好用一个动态分配缓冲区的指针定义你的联合：

%union {char* buf; int val;}

现在将buf在一个语义值的联合中分配给另一个语义值中的buf没有问题，您可以在strdup文件中使用flex初始化buf字段。但是你现在有另一个问题，那就是你需要free所有那些动态分配的名字，或者让你的内存泄漏。

如果你所做的只是构建一个小的一次通过编译器，那么虽然很难看，但内存泄漏是可能的。毕竟，当程序终止时，它的所有内存都将被释放，而您无需做任何事情。这是传统的风格，虽然我怀疑绝大多数阅读这个答案的程序员都会被这个建议所激怒。

不幸的是，修复起来并不容易。语义值从一个堆栈位置传递到另一个堆栈位置，并且没有简单的方法可以知道给定字符串有多少指针，或者不再需要该字符串。如果您使用C ++作为基本语言而不是C，您可以使用std::string，它将处理所有这些问题以及适当大缓冲区的分配，但代价是做了相当多的不必要的字符串复制。或者你可以使用std :: string的共享指针，它会以一定的运行时间成本为你做引用计数。

我的解决方案，有一段时间以来，一直是在词法分析器中维护一个“实习”字符串的字典 - 即唯一字符串，并让词法分析器返回指向（const）唯一的指针串。这具有每个字符串标记的哈希表查找的成本，但它有效地处理垃圾收集问题。在解析结束时，可以简单地删除词法分析器及其相关的唯一字符串哈希表。（当然，如果字符串需要比词法分析器存活更长时间，则需要复制。但在许多情况下，这不是问题。）

为什么不接受char类型

1 个答案: