Question

我试图在xQuery中创建一个搜索并返回图形中两个节点之间路径的算法，但只要它只返回一个节点，我就没有运气了。邻接节点。 首先，我应该明确图表是一个有向图，每个节点可以有零个，一个或多个来源，在XML中，一个节点只有它的起源但不是它的链接。跟随节点

这是一些节点及其XML

的示例

<node>
  <id> 123-456-789</id>
  <name> something </name>
  <Links>
     <Link>
        <origin></origin>
     </Link>
  <Links>

 <node>
  <id> 245-678-901</id>
  <name> node 2</name>
  <Links>
     <Link>
        <origin> 123-456-789 </origin>
     </Link>
  <Links>

  <node>
  <id> xxx-xxx-xxx</id>
  <name> node 3</name>
  <Links>
     <Link>
        <origin> 123-456-789 </origin>
     </Link>
  <Links>

  <node>
  <id> 234-546-768</id>
  <name> node 4</name>
  <Links>
     <Link>
        <origin> 245-678-901</origin>
     </Link>
  <Links>

从那个XML我想得到从节点1到节点4的路径（node1-＆gt; node2-＆gt; node4）但无论我尝试做什么，只会给我node1-node2和node3但不是node4 另一件事是我想选择一个不直接的路径，我的意思是，如果我想要node5和node7之间的路径，但node5和node7都指向node6

我已尝试将此python代码改编为xquery

def BFS(graph,start,end,q):

temp_path = [start]

q.enqueue(temp_path)

while q.IsEmpty() == False:
    tmp_path = q.dequeue()
    last_node = tmp_path[len(tmp_path)-1]
    print tmp_path
    if last_node == end:
        print "VALID_PATH : ",tmp_path
    for link_node in graph[last_node]:
        if link_node not in tmp_path:
            new_path = []
            new_path = tmp_path + [link_node]
            q.enqueue(new_path)

（代码不是我的，它属于它this activestate page的合法编码员）

这是我试图做的事情：

declare function local:BFS($graph as element()* , $ini_node as element(Node)*, $end_node as element(Node)*) as element()*
{
    let $seq := $ini_node
    let $queue := ($seq)
    for $item in $queue
        return
            if ( count($queue) > 0) then
                let $seq := remove($queue, count($queue))
                let $last := $seq[last()] return if (deep-equal($last, $end_node)) then $seq
                else
                    for $node in $graph[contains(.,$graph/id[contains(.,$last/Links/Link/origin/text())])] (: what i've tried was to get the graph nodes which id is equal to the origins of the last node :)
                        return if(not(functx:is-node-in-sequence-deep-equal($node,$seq))) then
                            let $new_path:= ()
                            let $new_path:= insert-before($seq, count($seq)+1, $node)
                            let $queue := insert-before($queue,1, $new_path) return $queue
                        else ()

            else
                ()


};

Answer 1

XQuery和Python之间的根本区别在于XQuery是functional programming language。这意味着之后不能修改绑定到变量的值。例如，在函数local:BFS(...)中，您无法更改循环内$queue的值，您只需创建一个隐藏外部变量的新变量$queue。

为了使其工作，您可以将外部循环编写为recursive function，而不是将当前队列作为参数。然后，循环的每次迭代都是使用更新版本的队列调用函数：

declare function local:BFS($graph, $queue, $steps, $end) {
  if(empty($queue)) then error(xs:QName('local:NOTFOUND'), 'No path found.')
  else (
    let $curr := $queue[1], $rest-queue := $queue[position() > 1]
    return (
      if($curr eq $end) then local:result($steps, $end)
      else (
        let $successors :=
          $graph//node[Links/Link/origin = $curr and not($steps/@to = id)]/id/string()
        let $new-steps  :=
          for $succ in $successors
          return <edge from="{$curr}" to="{$succ}" />
        return local:BFS(
          $graph,
          ($rest-queue, $successors),
          ($steps, $new-steps),
          $end
        )
      )
    )
  )
};

可以通过向起始节点提供第一条边来调用它：

declare function local:BFS($graph, $start, $end) {
  local:BFS($graph, $start, <edge to="{$start}" />, $end)
};

所有使用的边都存储在$steps中。为了在找到目的地后重建路径，我们可以向后遍历它们直到找到初始边缘：

declare function local:result($steps, $dest) {
  let $pred := $steps[@to = $dest]/@from/string()
  return if(exists($pred)) then (local:result($steps, $pred), $dest)
  else $dest
};

如果您担心性能，XQuery序列可能不是用作队列的最佳数据结构。关于用于查找的XML片段也可以这样说。因此，如果您可以访问XQuery 3.0处理器，则可以查看我在https://github.com/LeoWoerteler/xq-modules处编写的一些（至少是渐近的）更有效的数据结构。我甚至以Dijkstra's algorithm为例。

在XQuery中搜索两个图节点之间的路径

1 个答案: