Question

我正在用VB.NET开发一篇文章。在我的主要表单中，我正在创建一个用作对话框的新表单。我想知道是否有办法在新对话框结束时保存每个用户的大小设置（可能在他们机器上的文件中，通过XML或其他东西？）

Answer 1

您可以将其保存到设置文件中，并在'onclosing'事件中更新它。

进行设置转到项目属性 - ＆gt;设置 - ＆gt;然后进行类似system.drawing.size的“dialogsize”设置。

然后在对话框中执行此操作：

Public Sub New()
    InitializeComponent()
End Sub

Public Sub New(ByVal userSize As Size)
    InitializeComponent()
    Me.Size = userSize
End Sub

Protected Overrides Sub OnClosing(ByVal e As System.ComponentModel.CancelEventArgs)
    MyBase.OnClosing(e)
    My.Settings.DialogSize = Me.Size
    My.Settings.Save()
End Sub

执行以下操作以检查并使用设置：

    Dim dlg As MyDialogWindow
    If My.Settings.DialogSize.IsEmpty Then
        dlg = New MyDialogWindow()
    Else
        dlg = New MyDialogWindow(My.Settings.DialogSize)
    End If
    dlg.ShowDialog()

Answer 2

虽然this is for C#，但它也有助于VB.Net。

Answer 3

您还可以为应用程序添加新设置（大小）并将其设置为system.drawing.size

然后，确保将当前大小保存到关闭时的设置。

    Private Sub myForm_FormClosing(ByVal sender As System.Object,
                          ByVal e As System.Windows.Forms.FormClosingEventArgs) _
                             Handles MyBase.FormClosing

    My.Settings.size = Me.Size
    My.Settings.Save()

End Sub

并在加载时应用您在设置中保存的大小

    Private Sub myForm_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) _
    Handles MyBase.Load
    ' if  this is the first  time to load the form 
    ' dont set the size ( the form will load  with the size  in the designe)
    If Not My.Settings.size.IsEmpty Then
        Me.Size = My.Settings.size
    End If
End Sub

Answer 4

这是一个I found online的解决方案，对我来说似乎很不错。

前面提到的某些解决方案无法按预期工作。取决于关闭时我的表单的位置，当我再次加载表单时，表单不会重新定位到该确切位置。

此解决方案似乎也可以通过考虑其他一些因素来解决问题：

您需要在项目属性->设置下设置这两个设置：WindowLocation和WindowSize如下：

然后创建以下功能：

Private Sub LoadWindowPosition()

    'Get window location/position from settings
    Dim ptLocation As System.Drawing.Point = My.Settings.WindowLocation

    'Exit if it has not been set (X = Y = -1)
    If (ptLocation.X = -1) And (ptLocation.Y = -1) Then
        Return
    End If

    'Verify the window position is visible on at least one of our screens
    Dim bLocationVisible As Boolean = False

    For Each S As Screen In Screen.AllScreens
        If S.Bounds.Contains(ptLocation) Then
            bLocationVisible = True
            Exit For
        End If
    Next

    'Exit if window location is not visible on any screen 
    If Not bLocationVisible Then
        Return
    End If

    'Set Window Size, Location
    Me.StartPosition = FormStartPosition.Manual
    Me.Location = ptLocation
    Me.Size = My.Settings.WindowSize
End Sub

接下来，您需要将代码添加到表单的加载和关闭事件中，如下所示：

Private Sub frmMain_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    LoadWindowPosition()
End Sub

Private Sub frmMain_Closing(sender As Object, e As CancelEventArgs) Handles Me.Closing
    My.Settings.WindowLocation = Me.Location
    My.Settings.WindowSize = Me.Size
End Sub

我希望能有所帮助。

Answer 5

您也可以使用VB.NET IDE本身提供的UI来执行此操作。在窗体的属性窗格中，查看名为“（应用程序设置）”的项目，然后在“属性绑定”下。您可以将表单的每个属性（包括大小和位置）绑定到该应用程序的设置值。

Answer 6

事实证明，我找到了使用System.IO.IsolatedStorage

执行此操作的方法

保存Windows窗体大小

6 个答案: