Question

我有这个XML代码段

<MediaTypes>
  <DVD>true</DVD>
  <HDDVD>false</HDDVD>
  <BluRay>true</BluRay>
</MediaTypes>

我想创建一个看起来像这样的输出

DVD / Blu-ray

或者像这样

DVD

或者像这样

DVD / HD-DVD / Blu-ray

取决于真/假状态

但我是XSLT游戏中的初学者。： - /

这是完整XML的片段

<?xml version="1.0" encoding="Windows-1252"?>
<Collection xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
  <DVD>
    <ProfileTimestamp>2012-06-07T05:20:51Z</ProfileTimestamp>
    <ID>0044005507027.5</ID>
    <MediaTypes>
      <DVD>true</DVD>
      <HDDVD>false</HDDVD>
      <BluRay>false</BluRay>
    </MediaTypes>
    <UPC>0-044005-507027</UPC>
    <CollectionNumber>448</CollectionNumber>
    <CollectionType IsPartOfOwnedCollection="true">Owned</CollectionType>
    <Title>The Big Lebowski</Title>
    <DistTrait />
    <OriginalTitle />
    <CountryOfOrigin>United States</CountryOfOrigin>
    ...
  </DVD>
  <DVD>
     ...
  </DVD>
</Collection>

我尝试按照下面给出的建议（关于循环），但它似乎不起作用。

这是我到目前为止（完整）的XSL：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template name="MediaTypes" match="MediaTypes">
        Test
        <xsl:for-each select="*[.='true']">            
            <xsl:value-of select="name()"/>
            <xsl:if test="position()!=last()">
                <xsl:text>/</xsl:text>
            </xsl:if>
        </xsl:for-each>        
    </xsl:template>

    <xsl:template match="/">
        <html>
            <head>
                <title>DVD Profiler Double Dips</title>
            </head>
            <body>
                <div>
                    <h1>DVD Profiler Double Dips</h1>
                </div>
                <table border="1" cellpadding="3" cellspacing="0">
                    <tr>
                        <th>Title</th>
                        <th>Edition</th>
                        <th>Production Year</th>
                        <th>DVD /</th>
                        <th>Purchase Date</th>
                        <th>Collection Type</th>
                        <th>Original Title</th>
                        <th>Sort Title</th>
                    </tr>
                    <xsl:for-each select="/Collection/DVD">
                        <tr>
                            <td>
                                <xsl:value-of select="Title"/>
                            </td>
                            <td>
                                <xsl:if test="DistTrait != ''">
                                    <xsl:value-of select="DistTrait"/>
                                </xsl:if>
                                <xsl:if test="DistTrait = ''">
                                    &#160;
                                </xsl:if>
                            </td>
                            <td>
                                <xsl:if test="ProductionYear != ''">
                                    <xsl:value-of select="ProductionYear"/>
                                </xsl:if>
                                <xsl:if test="ProductionYear = ''">
                                    &#160;
                                </xsl:if>
                            </td>
                            <td>
                                <xsl:call-template name="MediaTypes" />
                            </td>
                        </tr>
                    </xsl:for-each>
                </table>
            </body>
        </html>
    </xsl:template>
</xsl:stylesheet>

但是

<xsl:call-template name="MediaTypes" />

站着，只有“测试”出来

耶！

你们真棒。是的

<xsl:apply-templates select="MediaTypes"/>

是我的首选武器。

我的最终模板如下所示：

<xsl:template name="MediaTypes" match="MediaTypes">
    <xsl:for-each select="*[.='true']">
        <xsl:value-of select="name()"/>
        <xsl:if test="position()!=last()">
            <xsl:text> / </xsl:text>
        </xsl:if>
    </xsl:for-each>
    <xsl:if test="CustomMediaType != ''">
        <xsl:if test="*[.='true']">
            <xsl:text> / </xsl:text>
        </xsl:if>
        <xsl:value-of select="CustomMediaType"/>
    </xsl:if>
</xsl:template>

开始了解内容如何运作

感谢您的帮助！

Answer 1

这个问题相当简单 - 真正的问题是你只显示了一个XML文档的片段。 XSLT非常依赖于上下文。

这是一个匹配任何<MediaTypes>元素并输出所需字符串的模板;希望你知道如何将它合并到你自己的样式表中：

<xsl:template match="MediaTypes">
    <xsl:for-each select="*[.='true']">
        <xsl:value-of select="name()"/>
        <xsl:if test="position()!=last()">
            <xsl:text>/</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

Answer 2

我建议你稍微更改一下xml

这是一个例子

<?xml version="1.0" ?>
<?xml-stylesheet type="text/xsl" ?>
<MediaTypes>
    <Media name="DVD">true</Media>
    <Media name="HDDVD">false</Media>
    <Media name="BluRay">true</Media>
</MediaTypes>

这样你可以编写像//MediaTypes/Media这样的XPATH表达式然而，@ michael.hor257k写了一个很好的解决方案，将这个xml模式插入到看起来像这样的

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:template match="//MediaTypes">
        <xsl:for-each select="*[.='true']">
            <xsl:value-of select="@name"/>
            <xsl:if test="position()!=last()">
                <xsl:text>/</xsl:text>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

这将呈现DVD/BluRay

在这里测试http://xslttest.appspot.com/

如何使用XSLT构建字符串？

2 个答案: