Question

我对这种语言有点新意，所以我有几个疑问。我正在处理xml以在pdf表单上显示一些数据。但是有一些字符串有“|”所以我可以拆分数据以便正确显示。以下是输入数据的示例：

<root>
  <reference>
    <NroLinRef>12</NroLinRef>
    <CodRef>I20</CodRef>
    <RazonRef>Data1|Data2|Data3|Data4|Data5|Data6|Data7</RazonRef>
  </reference>
</root>

在输出中我需要这样的东西，所以我可以按行顺序显示单元格，这样数据必须清晰可读。

<root>
  <Reference>
    <NroLinRef>12</NroLinRef>
    <CodRef>I20</CodRef>
    <Data1>Data1</Data1>
    <Data2>Data2</Data2>
    <Data3>Data3</Data3>
    <Data4>Data4</Data4>
    <Data5>Data5</Data5>
    <Data6>Data6</Data6>
    <Data7>Data7</Data7>
  </Reference>
</root>

为此，我一直在使用来自其他问题的其他代码，但无法找到如何更新或自定义名称。

我得到的输出实际上是这样的：

<root>
  <Reference>
    <NroLinRef>12</NroLinRef>
    <CodRef>I20</CodRef>
    <Data>Data1</Data>
    <Data>Data2</Data>
    <Data>Data3</Data>
    <Data>Data4</Data>
    <Data>Data5</Data>
    <Data>Data6</Data>
    <Data>Data7</Data>
  </Reference>
</root>

这是我正在使用的XSL

    <xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
        <xsl:template match="@*|node()">
            <xsl:copy>
                <xsl:apply-templates select="@*|node()"/>
            </xsl:copy>
        </xsl:template>
        <xsl:template match="Referencia/RazonRef" name="tokenize">
           <xsl:param name="text" select="."/>
            <xsl:param name="separator" select="'|'"/>
            <xsl:choose>
                <xsl:when test="not(contains($text, $separator))">
                    <Data>
                        <xsl:value-of select="normalize-space($text)"/>
                    </Data>
                </xsl:when>         
                <xsl:otherwise>
                    <Data>
                        <xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
                    </Data>
                    <xsl:call-template name="tokenize">
                        <xsl:with-param name="text" select="substring-after($text, $separator)"/>
                    </xsl:call-template>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:template>
    </xsl:stylesheet>

如何获得我想要的输出？

Answer 1

可以通过应用以下样式表来实现预期结果：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="RazonRef" name="tokenize">
    <xsl:param name="text" select="."/>
    <xsl:param name="separator" select="'|'"/>
    <xsl:param name="i" select="1"/>
    <xsl:element name="Data{$i}">
        <xsl:value-of select="substring-before(concat($text, $separator), $separator)"/>
    </xsl:element>
    <xsl:if test="contains($text, $separator)">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="substring-after($text, $separator)"/>
            <xsl:with-param name="i" select="$i + 1"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

用“|”拆分字符串字符列

1 个答案: