Question

如何使用给定avs_term_rearranged(AVs, T, AVsR)和AVs的标准符合方式T进行书写，AVsR是AVs的排列，其中元素排列在其变量的顺序与T中从左到右的顺序相同。

AVs是A = V形式的元素列表，其中A是指定变量名称的原子，如'X'，V是对应的变量。此类列表由read_term/2,3生成，并带有读取选项variable_names/1（7.10.3）。此外，未定义元素的精确顺序。

| ?- read_term(T,[variable_names(AVs)]).
A+B+A+_+C.

AVs = ['A'=A,'B'=B,'C'=C]
T = A+B+A+_+C

T这个术语包含AVs的所有变量以及更多变量。

请注意，在符合标准的程序中，不能依赖变量的术语顺序（7.2.1）：

7.2.1变量

如果X和Y是不相同的变量，那么X    term_precedes Y应依赖于实现，除了在创建排序列表期间（7.1.6.5，   8.10.3.1 j）排序应保持不变。

注意 - 如果X和Y都是匿名变量，则它们不是相同的术语   （见6.1.2 a）。

以from 8.4.3.4：

为例

sort([f(U),U,U,f(V),f(U),V],L).
   Succeeds, unifying L with [U,V,f(U),f(V)] or
   [V,U,f(V),f(U)].
   [The solution is implementation dependent.]

因此，sort/2有两种可行的方式，而且甚至不能依赖于成功：

sort([f(U),U,U,f(V),f(U),V],L), sort(L, K), L == K.

举个例子：

?- avs_term_rearranged(['A'=A,'B'=B,'C'=C], A+C+F+B, AVsR).
   AVsR = ['A'=A,'C'=C,'B'=B].

Answer 1

avs_term_rearranged(AVs, T, AVsR) :-
    term_variables(T, Vs),
    copy_term(Vs+AVs, Vs1+AVs1),
    bind_names(AVs1),
    build_vn_list(Vs, Vs1, AVsR).

bind_names([]).
bind_names([N=V|AVs]) :-
    N = V,
    bind_names(AVs).

build_vn_list([], [], []).
build_vn_list([V|Vs],[N|Ns],NVs) :-
    ( atom(N) ->
      NVs = [N=V|NVs1]
    ; var(N) ->
      NVs = NVs1
    ),
    build_vn_list(Vs, Ns, NVs1).

Answer 2

在term_variables/2上使用T获取包含所需顺序变量的列表Xs。然后使用AVs的元素构建一个列表，但按顺序。

avs_term_rearranged(AVs, T, AVRs) :-
    term_variables(T, Xs),
    pick_in_order(AVs, Xs, AVRs).

pick_in_order([], [], []).
pick_in_order(AVs, [X|Xs], AVRs) :-
    ( pick(AVs, X, AV, AVs1) ->
        AVRs = [AV|AVRs1],
        pick_in_order(AVs1, Xs, AVRs1)
    ;
        pick_in_order(AVs, Xs, AVRs)
    ).

pick([AV|AVs], X, AX, DAVs) :-
    (_=V) = AV,
    ( V==X ->
        AX = AV,
        DAVs = AVs
    ;
        DAVs = [AV|DAVs1],
        pick(AVs, X, AX, DAVs1)
    ).

注意：

这是二次的，因为pick/4是线性的
term_variables/2并非绝对必要，您可以直接遍历T

Answer 3

我以前的回答有二次运行时复杂性。如果这是一个问题，这是一个线性的替代方案。这有点棘手的原因是未绑定的变量不能用作散列等的密钥。

和以前一样，我们基本上重新排列列表AVs，使其元素与列表Xs中的变量具有相同的顺序（从term_variables/2获得）。这里的新想法是首先计算所需排列（APs）的（基础）描述，然后使用此描述构造AV的排列。

avs_term_rearranged(AVs, T, AVRs) :-
    term_variables(T, Xs),
    copy_term(AVs-Xs, APs-Ps),
    ints(Ps, 0, N),
    functor(Array, a, N),
    distribute(AVs, APs, Array),
    gather(1, N, Array, AVRs).

ints([], N, N).
ints([I|Is], I0, N) :- I is I0+1, ints(Is, I, N).

distribute([], [], _).
distribute([AV|AVs], [_=P|APs], Array) :-
    nonvar(P),
    arg(P, Array, AV),
    distribute(AVs, APs, Array).

gather(I, N, Array, AVRs) :-
    ( I > N ->
        AVRs = []
    ;
        arg(I, Array, AV),
        I1 is I+1,
        ( var(AV) -> AVRs=AVRs1 ; AVRs = [AV|AVRs1] ),
        gather(I1, N, Array, AVRs1)
    ).

Answer 4

此版本非常短，使用 member/2 （来自Prolog序言）进行搜索。它具有非常低的辅助记忆消耗。仅创建列表AVsR。没有暂时的创建堆项（在当前实现上）。它有二次方但是，AVs长度的开销。

avs_term_rearranged(AVs, T, AVsR) :-
   term_variables(T, Vs),
   rearrange(Vs, AVs, AVsR).

rearrange([], _, []).
rearrange([V|Vs], AVs, AVsR0) :-
   ( member(AV, AVs),
     AV = (_=Var), V == Var ->
      AVsR0 = [AV|AVsR]
   ;  AVsR0 = AVsR
   ),
   rearrange(Vs, AVs, AVsR).

另一个方面是member(AV, AVs)目标本质上是非确定性的，即使只有相对浅的非确定性涉及，而@ jschimpf的（第一个）版本确实创造了一个选择仅指向if-then-else实现的(;)/2。两个版本都没有留下任何选择点。

这是一个更忠实地模拟@ jschimpf的想法的版本。这个，但是，现在创建留在堆上的辅助术语。

rearrange_js([], _, []).
rearrange_js([V|Vs], AVs0, AVsR0) :-
   ( select(AV, AVs0, AVs),
     AV = (_=Var), V == Var ->
      AVsR0 = [AV|AVsR]
   ;  AVsR0 = AVsR,
      AVs0 = AVs
   ),
   rearrange_js(Vs, AVs, AVsR).

重新排列variable_names

4 个答案: