Question

与原始问题Is it possible to get the index of class property?相关联，由Remy Lebeau和RRUZ回答

program Demo;

{$APPTYPE CONSOLE}

uses
  System.SysUtils, Winapi.Windows,
  System.Rtti, System.TypInfo;

type
  TMyClass = class
  private
    function GetInteger(const Index: Integer): Integer;
    procedure SetInteger(const Index, Value: Integer);
  public
    property P1: Integer Index 1 read GetInteger write SetInteger;
    property P2: Integer Index 2 read GetInteger write SetInteger;
    property P3: Integer Index 3 read GetInteger write SetInteger;
  end;

{ TMyClass }

function TMyClass.GetInteger(const Index: Integer): Integer;
begin
  Result := Index;
end;

procedure TMyClass.SetInteger(const Index, Value: Integer);
begin
  //
end;

{------------------------------------------------------------------------------}
function GetPropertyIndex(const AClass: TClass; APropertyName: string): Integer;
var
  Ctx: TRttiContext;
begin
  Ctx := TRttiContext.Create;
  Result := (Ctx.GetType(AClass).GetProperty(APropertyName) as TRttiInstanceProperty).Index;
end;

{------------------------------------------------------------------------------}
var
  C: Cardinal;
  I: Integer;
  N: Integer;
begin
  try
    C := GetTickCount;
    for N := 1 to 1000000 do
      I := GetPropertyIndex(TMyClass, 'P2');
    WriteLn(GetTickCount - C, ' ms - The index of the property P2 is ', I);

    ReadLn;
  except
    on E: Exception do Writeln(E.ClassName, ': ', E.Message);
  end;
end.

在我的电脑上，此测试需要约5秒钟。但是当我在调用TRttiContext之前使用GetPropertyIndex()时 - 例如

...
begin
  try
    TRttiContext.Create.Free;

    C := GetTickCount;
    for N := 1 to 1000000 do
      I := GetPropertyIndex(TMyClass, 'P2');
...

同样的测试只需要约1秒。为什么？

编辑我在测试secon示例时发现的问题是

...
var
  Ctx: TRttiContext;
  C: Cardinal;
  I: Integer;
  N: Integer;
begin
  try
    C := GetTickCount;
    for N := 1 to 1000000 do
    begin
      Ctx := TRttiContext.Create;
      I := (Ctx.GetType(TMyClass).GetProperty('P2') as TRttiInstanceProperty).Index;
    end;  
    WriteLn(GetTickCount - C, ' ms - The index of the property P2 is ', I);

    ReadLn;
  except
    on E: Exception do Writeln(E.ClassName, ': ', E.Message);
  end;
end.

但问题的原因在第二次测试中更为明显。

Answer 1

使用引用计数池缓存RTTI数据。代码加速的原因是因为TRttiContext.Create.Free语句创建了一个临时TRttiContext，它保留了应用程序生命周期的范围，维护对该池的活动引用。在TRttiContext内创建的后续GetPropertyIndex()实例正在重新使用现有池，而不是每次都浪费时间重新创建新池。当DPR代码到达end.语句时，临时TRttiContext超出范围并释放其对池的引用。

删除TRttiContext.Create.Free语句后，临时TRttiContext消失，并为TRttiContext使用的每个GetPropertyIndex()创建并销毁新池，浪费时间一遍又一遍地创建相同的缓存。

您可以通过在“项目选项”中启用“调试DCU”然后单步执行调试器中的TRttiContext代码，轻松查看此操作。

为什么提前创建TRttiContext使我的RTTI测试运行得更快？

1 个答案: