Question

我对Java中的字符串有一个简单的问题。以下简单代码段仅连接两个字符串，然后将它们与==进行比较。

String str1="str";
String str2="ing";
String concat=str1+str2;

System.out.println(concat=="string");

比较表达式concat=="string"显然返回false（我理解equals()和==之间的区别。）

当这两个字符串被声明为final时，

final String str1="str";
final String str2="ing";
String concat=str1+str2;

System.out.println(concat=="string");

比较表达式concat=="string"，在这种情况下返回true。为什么final会有所作为？它是否必须与实习生池做某事或我只是被误导？

Answer 1

当您将String（ immutable ）变量声明为final并使用编译时常量表达式初始化它时，它也会变为编译时常量表达式，其值由编译器使用它来内联。因此，在第二个代码示例中，在内联值之后，编译器将字符串连接转换为：

String concat = "str" + "ing";  // which then becomes `String concat = "string";`

与"string"相比，它会为您提供true，因为字符串文字是实习。

来自JLS §4.12.4 - final Variables：

基本类型或类型String的变量，即final，并使用编译时常量表达式（第15.28节）初始化，称为常量变量。

同样来自JLS §15.28 - Constant Expression:

类型String的编译时常量表达式总是“interned”，以便使用方法String#intern()共享唯一的实例。

在您的第一个代码示例中并非如此，String变量不是final。因此，它们不是编译时常量表达式。连接操作将延迟到运行时，从而导致创建新的String对象。您可以通过比较两个代码的字节代码来验证这一点。

第一个代码示例（非 - final版本）编译为以下字节代码：

  Code:
   0:   ldc     #2; //String str
   2:   astore_1
   3:   ldc     #3; //String ing
   5:   astore_2
   6:   new     #4; //class java/lang/StringBuilder
   9:   dup
   10:  invokespecial   #5; //Method java/lang/StringBuilder."<init>":()V
   13:  aload_1
   14:  invokevirtual   #6; //Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
   17:  aload_2
   18:  invokevirtual   #6; //Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
   21:  invokevirtual   #7; //Method java/lang/StringBuilder.toString:()Ljava/lang/String;
   24:  astore_3
   25:  getstatic       #8; //Field java/lang/System.out:Ljava/io/PrintStream;
   28:  aload_3
   29:  ldc     #9; //String string
   31:  if_acmpne       38
   34:  iconst_1
   35:  goto    39
   38:  iconst_0
   39:  invokevirtual   #10; //Method java/io/PrintStream.println:(Z)V
   42:  return

显然，它将str和ing存储在两个单独的变量中，并使用StringBuilder执行连接操作。

然而，您的第二个代码示例（final版本）如下所示：

  Code:
   0:   ldc     #2; //String string
   2:   astore_3
   3:   getstatic       #3; //Field java/lang/System.out:Ljava/io/PrintStream;
   6:   aload_3
   7:   ldc     #2; //String string
   9:   if_acmpne       16
   12:  iconst_1
   13:  goto    17
   16:  iconst_0
   17:  invokevirtual   #4; //Method java/io/PrintStream.println:(Z)V
   20:  return

因此它直接内联最终变量以在编译时创建String string，该ldc操作在步骤0中加载。然后在步骤ldc中通过7操作加载第二个字符串文字。它不涉及在运行时创建任何新的String对象。 String在编译时已知，并且它们是实例。

Answer 2

根据我的研究，所有final String都是用Java实现的。来自其中一篇博文：

所以，如果你真的需要使用==或！=比较两个String，请确保在进行比较之前调用String.intern（）方法。否则，总是更喜欢String.equals（String）进行字符串比较。

因此，如果您致电String.intern()，则可以使用==运算符比较两个字符串。但是这里String.intern()不是必需的，因为在Java final String内部实习。

您可以为String comparision using == operator方法找到更多信息String.intern()和Javadoc。

另请参阅此Stackoverflow帖子以获取更多信息。

Answer 3

如果你看看这个方法

public void noFinal() {
    String str1 = "str";
    String str2 = "ing";
    String concat = str1 + str2;

    System.out.println(concat == "string");
}

public void withFinal() {
    final String str1 = "str";
    final String str2 = "ing";
    String concat = str1 + str2;

    System.out.println(concat == "string");
}

并使用javap -c ClassWithTheseMethods反编译您将看到的版本

  public void noFinal();
    Code:
       0: ldc           #15                 // String str
       2: astore_1      
       3: ldc           #17                 // String ing
       5: astore_2      
       6: new           #19                 // class java/lang/StringBuilder
       9: dup           
      10: aload_1       
      11: invokestatic  #21                 // Method java/lang/String.valueOf:(Ljava/lang/Object;)Ljava/lang/String;
      14: invokespecial #27                 // Method java/lang/StringBuilder."<init>":(Ljava/lang/String;)V
      17: aload_2       
      18: invokevirtual #30                 // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/StringBuilder;
      21: invokevirtual #34                 // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      ...

和

  public void withFinal();
    Code:
       0: ldc           #15                 // String str
       2: astore_1      
       3: ldc           #17                 // String ing
       5: astore_2      
       6: ldc           #44                 // String string
       8: astore_3      
       ...

因此，如果字符串不是最终编译器，则必须使用StringBuilder来连接str1和str2所以

String concat=str1+str2;

将编译为

String concat = new StringBuilder(str1).append(str2).toString();

表示将在运行时创建concat，因此不会来自String池。

此外，如果字符串是最终的，那么编译器可以假设它们永远不会改变，而不是使用StringBuilder它可以安全地连接它的值，所以

String concat = str1 + str2;

可以更改为

String concat = "str" + "ing";

并连接成

String concat = "string";

表示concate将成为sting文字，将在字符串池中实现，然后在if语句中与该池中的相同字符串文字进行比较。

Answer 4

堆栈和字符串conts池概念 enter image description here

Answer 5

让我们看一下final示例

的一些字节代码

Compiled from "Main.java"
public class Main {
  public Main();
    Code:
       0: aload_0
       1: invokespecial #1                  // Method java/lang/Object."<init>":()V
       4: return

  public static void main(java.lang.String[]) throws java.lang.Exception;
    Code:
       0: ldc           #2                  // String string
       2: astore_3
       3: getstatic     #3                  // Field java/lang/System.out:Ljava/io/PrintStream;
       6: aload_3
       7: ldc           #2                  // String string
       9: if_acmpne     16
      12: iconst_1
      13: goto          17
      16: iconst_0
      17: invokevirtual #4                  // Method java/io/PrintStream.println:(Z)V
      20: return
}

在0:和2:，String "string"被推入堆栈（来自常量池）并直接存储到本地变量concat 。您可以推断编译器在编译时创建（连接）String "string"本身。

非final字节代码

Compiled from "Main2.java"
public class Main2 {
  public Main2();
    Code:
       0: aload_0
       1: invokespecial #1                  // Method java/lang/Object."<init>":()V
       4: return

  public static void main(java.lang.String[]) throws java.lang.Exception;
    Code:
       0: ldc           #2                  // String str
       2: astore_1
       3: ldc           #3                  // String ing
       5: astore_2
       6: new           #4                  // class java/lang/StringBuilder
       9: dup
      10: invokespecial #5                  // Method java/lang/StringBuilder."<init>":()V
      13: aload_1
      14: invokevirtual #6                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/Stri
ngBuilder;
      17: aload_2
      18: invokevirtual #6                  // Method java/lang/StringBuilder.append:(Ljava/lang/String;)Ljava/lang/Stri
ngBuilder;
      21: invokevirtual #7                  // Method java/lang/StringBuilder.toString:()Ljava/lang/String;
      24: astore_3
      25: getstatic     #8                  // Field java/lang/System.out:Ljava/io/PrintStream;
      28: aload_3
      29: ldc           #9                  // String string
      31: if_acmpne     38
      34: iconst_1
      35: goto          39
      38: iconst_0
      39: invokevirtual #10                 // Method java/io/PrintStream.println:(Z)V
      42: return
}

这里有两个String常量，"str"和"ing"，需要在运行时与StringBuilder连接。

Answer 6

但是，当您使用Java的字符串文字表示法创建时，它会自动调用intern（）方法将该对象放入字符串池中，前提是它已不存在于池中。

为什么最终会有所作为？

编译器知道最终变量永远不会改变，当我们添加这些最终变量时输出转到字符串池因为str1 + str2表达式输出也永远不会改变，所以最后编译器调用inter输出上述两个最终变量后的方法。如果是非final变量编译器，请不要调用intern方法。

将字符串与==进行比较，这些字符串在Java中声明为final

6 个答案: