Question

我的xml和xslt文件如下所示。问题是，当我应用我的转换文件时，第二个发生第一个跳过。我怎么能在第一次运行时运行。请帮助谢谢。

//BEFORE TRANSFORMATION 

<A>
 <B>
  <Name>ThisOne</Name>
  <Target>abc</Target>
 </B>
</A>

我的XSLT文件

 <?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
    <xsl:output method="xml" indent="yes"/>

 <!--Transformation 1 to replace Target Text-->
  <xsl:template match="A/B/Target/text()">
    <xsl:text>xyz</xsl:text>  
  </xsl:template>

 <!--Transformation 2 to Add a new node after Target-->
  <xsl:template match="A/B/Target">
    <xsl:copy-of select="."/>
    <JOJO></JOJO>
  </xsl:template>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>  
</xsl:stylesheet>

转换后我想看到的是

<A>
 <B>
  <Name>ThisOne</Name>
  <Target>xyz</Target>
  <JOJO/>
 </B>
</A>

Answer 1

更改

<xsl:template match="A/B/Target">
    <xsl:copy-of select="."/>
    <JOJO></JOJO>
  </xsl:template>

到

<xsl:template match="A/B/Target">
    <xsl:copy>
       <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
    <JOJO></JOJO>
  </xsl:template>

Answer 2

您可以使用一个模板重写B节点。用这个替换这两个模板：

<xsl:template match ="A/B">
    <B>
        <Name><xsl:value-of select="Name"/></Name>
        <Target>xyz</Target>
        <JOJO/>
    </B>
</xsl:template>

如何为同一节点运行两个xslt转换

2 个答案: