Question

我需要获取一个来自同一XML文件中两个不同节点的值。例如，我的xml：

 <asset>
      <curr_wanted>EUR</curr_wanted>
      <curr>USD</curr>
      <value>50</value>
    </asset>

    <exchangeRates>
      <USD>
        <USD>1</USD>
        <EUR>0.73</EUR>
      </USD>
    </exchangeRates>

我希望以欧元兑换50美元。

我试过了：

<xsl:value-of select="(Asset/value * /exchangeRates[node() = curr]/curr_wanted)"/>

但它没有用。我还必须使用XSLT 1.0。我怎样才能以欧元获得这个价值？

Answer 1

我没有对它进行过多测试，但是对于像

这样的输入

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <asset>
      <curr_wanted>EUR</curr_wanted>
      <curr>USD</curr>
      <value>50</value>
    </asset>
    <asset>
      <curr_wanted>EUR</curr_wanted>
      <curr>USD</curr>
      <value>25</value>
    </asset>    
    <exchangeRates>
      <USD>
        <USD>1</USD>
        <EUR>0.73</EUR>
      </USD>
    </exchangeRates>
</root>

像下面这样的东西可以工作

for $asset in /root/asset, $rate in /root/exchangeRates 
    return $asset/value*$rate/*[name() = $asset/curr]/*[name() = $asset/curr_wanted]

但它只能在xpath 2.0中运行，它还取决于整个输入xml（如果可能存在更多资产元素，更多的exchangeRates元素等）。

编辑：在xslt 1.0中，您可以使用xsl：variable存储一些信息，并防止它们在xpath评估期间更改上下文。在以下模板中查找示例

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
    <xsl:output method="text" />

    <!-- Store "exchangeRates" in a global variable-->
    <xsl:variable name="rates" select="/root/exchangeRates" />  

    <xsl:template match="/root">
        <xsl:apply-templates select="asset" />
    </xsl:template>

    <xsl:template match="asset">
        <!-- Store necessary values into local variables -->
        <xsl:variable name="currentValue" select="value" />
        <xsl:variable name="currentCurrency" select="curr" />
        <xsl:variable name="wantedCurrency" select="curr_wanted" />
        <xsl:variable name="rate" select="$rates/*[name() = $currentCurrency]/*[name() = $wantedCurrency]" />

        <!-- Some text to visualize results -->
        <xsl:value-of select="$currentValue" />
        <xsl:text> </xsl:text>
        <xsl:value-of select="$currentCurrency" />
        <xsl:text> = </xsl:text>

        <!-- using variable to prevent context changes during xpath evaluation -->
        <xsl:value-of select="$currentValue * $rate" />

        <!-- Some text to visualize results -->
        <xsl:text> </xsl:text>
        <xsl:value-of select="$wantedCurrency" />

        <xsl:text>&#10;</xsl:text>
    </xsl:template>

</xsl:stylesheet>

为上面的输入xml生成以下输出。

50 USD = 36.5 EUR
25 USD = 18.25 EUR

使用XSLT将节点值相乘

1 个答案: