Question

我正在尝试在DBGrid中将Yes / No替换为True / False。下面的代码几乎可以工作：

procedure TDatamodule1.DBGridDrawColumnCell(Sender: TObject;
  const Rect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);

  var
    sText : String;

begin
  if (UpperCase(Column.Field.FieldName) = UpperCase('Approved')) or
     (UpperCase(Column.Field.FieldName) = UpperCase('Obsolete')) then
    begin
      if Column.Field.Value = True then
        sText := 'Yes'
      Else
        If Column.Field.Value = False Then
          sText := 'No'
        Else
          sText := '';
      (Sender as TDBGrid).Canvas.FillRect(Rect);
      (Sender as TDBGrid).Canvas.TextRect(Rect, Rect.Left+3, Rect.Top+2, sText);
    end;
end;

这似乎一直有效，直到我开始使用键盘光标键在网格中移动。具有焦点的单元格始终同时具有True和Yes或False，而No绘制在彼此之上。如何防止在具有焦点的单元格上绘制默认的True / False标签？网格的所有其他单元格都很完美。

编辑：我没有提到网格设置为Readonly，我注意到问题在于选择和聚焦。提前谢谢。

Answer 1

一个简单的解决方案是设置布尔字段DisplayValues：

MyField.DisplayValues := 'Yes;No';

Answer 2

实现此目的的一种方法是为这些字段设置OnGetText事件处理程序。如果您有静态字段，则可以在设计时设置这些字段。使用动态字段，您可以在FormCreate事件中执行此操作。

procedure TMyForm.MyFieldGetText(Sender: TField; var Text: string; DisplayText: Boolean);
begin
  if Sender.AsBoolean then
    Text := 'Yes'
  else
    Text := 'No';
end;

Answer 3

我会说你在错误的抽象层面上工作。使用两个计算列（下例中的AFlag和OFlag）并为clientdataset定义OnCalcFields事件。以下代码附加到名为“qCpap”的数据集中。

procedure TView.qCpapCalcFields(DataSet: TDataSet);
begin
 if qCpapApproved.AsBoolean 
  then qCpapAFlag.AsString:= 'Yes'
  else qCpapAFlag.AsString:= 'No';

 if qCpapObsolete.AsBoolean 
  then qCpapOFlag.AsString:= 'Yes'
  else qCpapOFlag.AsString:= 'No';
end;

顺便说一句，在字符串常量上使用'uppercase'函数是没有意义的：你也可以自己写大写字符串。

Answer 4

我通过大量的反复试验解决了我的问题。首先，在DBGrid组件中，我将dgEditing设置为false，因为它是不必要的（我的网格是只读的）。这可以防止用户将单元格置于聚焦模式。其次，我将DefaultDrawing设置为False。我更新了我的DBGridDrawColumnCell过程，如下所示：

procedure TDatamodule1.DBGridDrawColumnCell(Sender: TObject;
  const Rect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);

  var
    sText : String;

begin
  if gdselected in state then { set proper colors if cell is selected }
    Begin
      (Sender as TDBGrid).Canvas.Font.Color := 
        TStyleManager.ActiveStyle.GetSystemColor(clwindowtext);
      (Sender as TDBGrid).Canvas.Brush.Color := 
        TStyleManager.ActiveStyle.GetSystemColor(clhighlight);
    End;

  if (UpperCase(Column.Field.FieldName) = 'APPROVED') or
     (UpperCase(Column.Field.FieldName) = 'OBSOLETE')) then
    begin
      if Column.Field.Value = True then
        sText := 'Yes'
      Else
        If Column.Field.Value = False Then
          sText := 'No'
        Else
          sText := '';
      (Sender as TDBGrid).Canvas.FillRect(Rect);
      (Sender as TDBGrid).Canvas.TextRect(Rect, Rect.Left+3, Rect.Top+2, sText);
    end
  Else
    Begin { I added this to draw all other columns as defaultdrawing is off }
      (Sender as TDBGrid).defaultdrawcolumncell(Rect, DataCol, Column, State);
    End;
end;

如何让DBGrid绘制是/否而不是真/假

4 个答案: