Question

这是对我的问题的描述：我有两个文本文件（此处为$variants和$annotation）。我想检查$variants中第2列的值是否位于$annotation中第2列和第3列的值之间。如果是这样，那么$annotation中第1列的值应添加到$variants中的新列。

这是我的示例输入文件的样子

$annotation表示制表符分隔的文本文件

这些值可能重叠，无法完美排序，因为我正在使用循环基因组

C0    C1    C2   
gene1 0     100
gene2 500   1000
gene3 980   1200
gene4 1500  5

$variants表示制表符分隔的文本文件

C0    C1
...   5 
...   10
...   100
...   540
...   990

输出应如下所示（$variants添加了另外两列）

C0    C1   C2    C3
...   5    gene1 gene4
...   10   gene1
...   100  gene1
...   540  gene2
...   990  gene2 gene3

这就是我的剧本目前的样子

my %hash1=();
while(<$annotation>){
    my @column = split(/\t/);  #split on tabs
    my $keyfield = $column[1] && $column[2]; # I need to remember values from two columns   here. How do I do that?
    }   

while(<$variants>){
    my @column=split(/\t/);  # split on tabs
    my $keyfield = $column[1];
    if ($hash1{$keyfield} >= # so the value in column[1] should be between the values from   column[1] & [2] in $annotation
        push # if true then add values from column[0] in $annotation to new column in $variants
    }

所以我最大的问题是如何使用哈希值记住文件中的两个值，以及如何将一个文件中的值放到另一个文件中的列中。有人可以帮我这个吗？

Answer 1

根本不需要散列。此示例期望注释被排序而不是重叠，只有在打印变体的所有值时，它才有效。

#!/usr/bin/perl
use warnings;
use strict;

open my $VAR, '<', 'variants' or die $!;
<$VAR>; # skip header
my ($str, $pos) = split ' ', <$VAR>;

open my $ANN, '<', 'annotation' or die $!;
<$ANN>; # skip header

while (<$ANN>) {
    my ($gene, $from, $to) = split;
    while ($from <= $pos and $pos <= $to) {
        print "$str $pos $gene\n";
        ($str, $pos) = split ' ', <$VAR> or last;
    }
}

Answer 2

如果输入文件不大且位置不是太高，您可以使用数组来表示所有位置：

#!/usr/bin/perl
use warnings;
use strict;

sub skip_header {
    my $FH = shift;
    <$FH>;
}


open my $ANN, '<', 'annotation' or die $!;

my $max = 0;
while (<$ANN>) {
    $_ > $max and $max = $_ for (split)[1, 2];
}
seek $ANN, 0, 0; # Rewind the file back.

my $circular;
my @genes;
while (<$ANN>) {
    my ($gene, $from, $to) = split;
    if ($from <= $to) {
        $genes[$_] .= "$gene " for $from .. $to;
    } else {
        $circular = 1;
        $genes[$_] .= "$gene " for 0 .. $to, $from .. $max + 1;
    }
}

chop @genes;

open my $VAR, '<', 'variants' or die $!;
skip_header($VAR);
while (<$VAR>) {
    next if /^\s*#/;
    chomp;
    my ($str, $pos) = split;
    $pos = $#genes if $circular and $pos > $#genes;
    print "$_ ", $genes[$pos] // q(), "\n";
}

如果值位于两个值之间，则将另一个值添加到相应的行

2 个答案: