Question

我搜索过类似的问题，但无法提出任何建议。我有以下xml我需要修改它

  <XDB>
     <ROOT>
           <KEY><ID>12345</ID><DATE>5/10/2011</DATE></KEY>
           <PERSONAL><ID>1</ID><INFO><LASTNAME>Smith</LASTNAME>...</INFO></PERSONAL>
           <CONTACT><ID>1</ID><EMAIL>asmith@yahoo.com</EMAIL>...</CONTACT>
     </ROOT>
    <ROOT>
           <KEY><ID>98765</ID><DATE>5/10/2013</DATE></KEY>
           <CONTACT><ID>2</ID><EMAIL>psmithton@yahoo.com</EMAIL>...</CONTACT>
     </ROOT>

...

  </XDB>

它需要看起来像这样：

 <XDB>
     <ROOT>
       <KEY><ID>12345</ID><DATE>5/10/2011</DATE>
           <PERSONAL><ID>1</ID><INFO><LASTNAME>Smith</LASTNAME>...</INFO></PERSONAL>
           <CONTACT><ID>1</ID><EMAIL>asmith@yahoo.com</EMAIL>...</CONTACT>
        </KEY>

     </ROOT>
    <ROOT>
       <KEY><ID>98765</ID><DATE>5/10/2013</DATE>
           <CONTACT><ID>2</ID><EMAIL>psmithton@yahoo.com</EMAIL>...</CONTACT>
       </KEY>
     </ROOT>

...

  </XDB>

我需要让2个兄弟姐妹成为第一个“关键”兄弟姐妹的孩子。基本上，我需要删除关闭＆lt; / KEY＆GT;然后把它放在收盘前＆lt; / ROOT取代。我很感激你的帮助。感谢。

Answer 1

基于Identity transform的xslt可以完成这项工作

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <!-- Copy everything you find... -->
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*" />
        </xsl:copy>
    </xsl:template>

    <!-- ... but if you find first element inside ROOT ... -->
    <xsl:template match="ROOT/node()[1]">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*" />
            <!-- ... copy its sibling into it ... -->
            <xsl:copy-of select="following-sibling::*" />
        </xsl:copy>
    </xsl:template>

    <!-- ignore other elements inside ROOT element since they are copied in template matching first element -->
    <xsl:template match="ROOT/node()[position() &gt; 1]" />

</xsl:stylesheet>

xslt：移动第一个兄弟姐妹

1 个答案: