Question

我第一次使用DBpedia。我想下载人员数据集中的所有人以及commonName，nationality，birthDate和knownFor的属性（我最终会使用某种脚本语言将其粘贴到excel电子表格中）。

这是我第一次尝试执行此工作的查询，但它不起作用。我尝试将其与我在互联网上看到的其他代码拼凑在一起。有谁知道如何解决这一问题？感谢

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/> 

SELECT ?person ?commonName ?nationality ?knownFor ? birthDate
WHERE {
    ?person a type:Person .
    ?person prop:commonName ?commonNameFilter(lang(?commonName) = 'en') .
    ?person prop:nationality ?nationality(lang(?nationality) = 'en') .
    ?person prop:knownFor ?knownFor(lang(?knownFor) = 'en') .
    ?person prop:birthDate ?birthDate .
}

编辑：新版本的代码：返回公共字符（非英语复制品）。仍然缺少其他属性。

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/ontology/>

SELECT DISTINCT * WHERE {
    ?person a dbpedia-owl:Person ;  
              dbpedia-owl:commonName ?commonName . FILTER(lang(?commonName) = 'en')
}
LIMIT 30

Answer 1

首先，您的查询有很多语法问题：

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/> 
            ^ you probably want to use the dbpedia-owl properties which are 
            # in <http://dbpedia.org/ontology/>
SELECT ?person ?commonName ?nationality ?knownFor ? birthDate
                                                   ^ space between ? and varname
WHERE {
    ?person a type:Person .
    ?person prop:commonName ?commonNameFilter(lang(?commonName) = 'en') .
                                       ^ This needs to be "?commonName . FILTER(..."
                                       # and the same thing applies to your other 
                                       # filters
    ?person prop:nationality ?nationality(lang(?nationality) = 'en') .
    ?person prop:knownFor ?knownFor(lang(?knownFor) = 'en') .
    ?person prop:birthDate ?birthDate .
}

以增量方式构建其中一些查询会更容易，因为这样您就可以找到实际所拥有的某些资源属性，然后您可以进一步扩展查询。公共端点的数量为predefined namespaces，使用这些端点可以让其他人更轻松地读取您的查询。所以，你可以先问人：

SELECT * WHERE {
    ?person a dbpedia-owl:Person .
}
LIMIT 10

SPARQL results

看到它正常工作，您可以查看一些返回的实例并看到它们具有dbpedia-owl:commonName属性，然后扩展查询：

SELECT * WHERE {
    ?person a dbpedia-owl:Person ;  
              dbpedia-owl:commonName ?commonName .
}
LIMIT 10

SPARQL results

使用dbpedia-owl:birthDate属性扩展它很容易。我没有在我看过的实例上看到nationality谓词，所以我不确定你的国籍查询是什么。虽然我看到了knownFor属性的一些用法，但我没有在很多情况下看到它，所以如果你把它作为必需的属性，你就会排除很多人。但是，从长远来看，这种增量方法可能会帮助你。

查找属性

虽然可浏览本体提供了一种很好的方法来查找类，但我不确定是否有这么好的方法来查找属性。但是，你可以用蛮力的方式做点什么。例如，要查找实际用于Person的所有属性，您可以运行如下查询。（注意：此查询需要一段时间才能执行，因此如果您使用它，则应该下载结果。）

select distinct ?p where {
  [] a dbpedia-owl:Person ;
     ?p [] .
}

SPARQL results

我会注意到dbpedia-owl:nationality 出现在该列表中。

要获取所有内容的所有属性，您可以download the ontology，并运行如下查询：

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix owl: <http://www.w3.org/2002/07/owl#>
select * where { 
  { ?p a owl:ObjectProperty }
  UNION 
  { ?p a owl:DatatypeProperty }
}

我使用Jena的ARQ在本地运行：

$ arq --query properties.sparql --data dbpedia_3.8.owl
----------------------------------------------------------------------------
| p                                                                        |
============================================================================
| <http://dbpedia.org/ontology/regionServed>                               |
| <http://dbpedia.org/ontology/coachedTeam>                                |
| <http://dbpedia.org/ontology/legalForm>                                  |
| <http://dbpedia.org/ontology/goldenCalfAward>                            |
| <http://dbpedia.org/ontology/composer>                                   |
| <http://dbpedia.org/ontology/owningOrganisation>                         |
| <http://dbpedia.org/ontology/branchFrom>                                 |
| <http://dbpedia.org/ontology/iso6393Code>                                |
...
| <http://dbpedia.org/ontology/classification>                             |
| <http://dbpedia.org/ontology/bgafdId>                                    |
| <http://dbpedia.org/ontology/currencyCode>                               |
| <http://dbpedia.org/ontology/onChromosome>                               |
| <http://dbpedia.org/ontology/course>                                     |
| <http://dbpedia.org/ontology/frequentlyUpdated>                          |
| <http://dbpedia.org/ontology/distance>                                   |
| <http://dbpedia.org/ontology/volume>                                     |
| <http://dbpedia.org/ontology/description>                                |
----------------------------------------------------------------------------

这不会提供rdfs:domain和rdfs:range，但你也可以要求提供这些，或仅针对rdfs:range dbpedia-owl:Person的那些属性（但请注意，这不会全部可以使用Person的属性，因为范围可能或多或少具体）：

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix owl: <http://www.w3.org/2002/07/owl#>
prefix dbpedia-owl: <http://dbpedia.org/ontology/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>

select ?p ?range where { 
  { ?p a owl:ObjectProperty }
  UNION 
  { ?p a owl:DatatypeProperty }

  ?p rdfs:domain dbpedia-owl:Person ; rdfs:range ?range .
}


$ arq --query properties.sparql --data dbpedia_3.8.owl | head
--------------------------------------------------------------------------------------------------------
| p                                           | range                                                  |
========================================================================================================
| dbpedia-owl:restingPlacePosition            | <http://www.w3.org/2003/01/geo/wgs84_pos#SpatialThing> |
| dbpedia-owl:opponent                        | dbpedia-owl:Person                                     |
| dbpedia-owl:employer                        | dbpedia-owl:Organisation                               |
| dbpedia-owl:hometown                        | dbpedia-owl:Settlement                                 |
| dbpedia-owl:militaryBranch                  | dbpedia-owl:MilitaryUnit                               |
| dbpedia-owl:school                          | dbpedia-owl:EducationalInstitution                     |
| dbpedia-owl:ethnicity                       | dbpedia-owl:EthnicGroup                                |
...
| dbpedia-owl:sex                             | xsd:string                                             |
| dbpedia-owl:hipSize                         | xsd:double                                             |
| dbpedia-owl:individualisedPnd               | xsd:nonNegativeInteger                                 |
| dbpedia-owl:weddingParentsDate              | xsd:date                                               |
| dbpedia-owl:birthName                       | xsd:string                                             |
| dbpedia-owl:networth                        | xsd:double                                             |
| dbpedia-owl:birthYear                       | xsd:gYear                                              |
| dbpedia-owl:bustSize                        | xsd:double                                             |
| dbpedia-owl:description                     | xsd:string                                             |
--------------------------------------------------------------------------------------------------------

Answer 2

我还不太擅长SPARQL，但我确实在这里看到了一些语法问题。我重写了查询，看起来像这样：

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/>
SELECT ?person, ?commonName, ?nationality, ?knownFor, ?birthDate
WHERE {
    ?person a type:Person .
    ?person prop:commonName ?commonName .
    FILTER (lang(?commonName) = 'en') .
    ?person prop:nationality ?nationality .
    FILTER (lang(?nationality) = 'en') .
    ?person prop:knownFor ?knownFor .
    FILTER (lang(?knownFor) = 'en') .
    ?person prop:birthDate ?birthDate .
}

现在它至少运行查询而没有错误。但我没有看到结果。不知道为什么

使用DBPedia加载所有People以及一些数据

2 个答案:

查找属性