Question

此网站的长期用户未注册。现在我发现了一个问题，虽然我确信解决起来很简单，但我在任何搜索中都看不到任何相关资料！

这个xml示例简化了我的问题：

<root_element>
 <content>
  <content-detail>
    <name>TV Show Name</name>
    <value> Father Ted </value>
  </content-detail>

  <content-detail>
    <name>Airing Status</name>
     <value> Cancelled </value>
  </content-detail>

 </content>
</root_element>

在这个完全虚构的例子中，假设我想编写一个XSL转换，将父亲Ted更新为“父亲Ted - CANCELED”。

我可以更新所有电视节目名称，但是我很难让XSL明白如果播出状态的值被取消，它应该只更新电视节目名称值元素。

请帮助我坚持了几个小时!!!!

Answer 1

这将做你想要的事情

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="value[../name='TV Show Name']">
        <value>
            <xsl:choose>
                <xsl:when test="../../content-detail[name='Airing Status']/value = ' Cancelled '">
                    <xsl:value-of select="."/>- Cancelled
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="."/>
                </xsl:otherwise>
            </xsl:choose>
        </value>
    </xsl:template>    
</xsl:stylesheet>

第一个模板是“身份转换”，它只是将输入复制到输出。

第二个模板仅匹配value为name的{{1}}个元素。它生成一个TV Show Name元素，其文本设置为所需的字符串，具体取决于同一value块中Airing Status的值。

注意：如果<content>值周围的空白有任何变化，您可能需要调整测试。

Answer 2

这是一个面向推送的解决方案，在模板匹配方面更简单一些，并且适用于您的值周围的任意数量的空白：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output omit-xml-declaration="no" indent="yes"/>
<xsl:strip-space elements="*"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template
    match="content[content-detail
             [normalize-space(name) = 'Airing Status']
             [normalize-space(value) = 'Cancelled']
           ]
           /content-detail[normalize-space(name) = 'TV Show Name']/value">
    <value>
      <xsl:value-of select="concat(normalize-space(), ' -- CANCELLED')"/>
    </value>
  </xsl:template>

</xsl:stylesheet>

尝试根据另一个xml元素的值更新一个xml元素的值

2 个答案: