Question

我无法弄清楚如何在静态或甚至动态链接的dll中检测内存泄漏。我只想检测dll中的泄漏，我不想在dll和应用程序之间共享内存管理器。此外，dll 与运行时包

链接

我的示例dll看起来像这样：

library dll;
uses
  fastmm4,
  System.SysUtils,
  System.Classes;
{$R *.res}
procedure MyInit; stdcall;
Begin
  TObject.Create;
End;
exports MyInit;
begin
end.

application dpr：

program app;

uses
  //fastmm4,
  Vcl.Forms,
  main in 'main.pas' {Form1};

{$R *.res}

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

注意：如果我取消注释fastmm4，那么我可以检测到应用程序（TStringList.Create）导致的memleak，而不是dll中的泄漏。

在应用程序主单元中：

unit main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    LDLLHandle: HModule;
    LShowProc: TProcedure;
  end;

var
  Form1: TForm1;

{$ifdef static}
procedure MyInit; stdcall; external 'dll.dll';
{$endif}

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  TStringList.Create;
  {$ifdef static}
  MyInit;
  {$else}
  LDLLHandle := LoadLibrary('dll.dll');
  if LDLLHandle <> 0 then
  begin
    try
      LShowProc := GetProcAddress(LDLLHandle, 'MyInit');
      if Assigned(LShowProc) then
        LShowProc;
    finally
      FreeLibrary(LDLLHandle);
    end;
  end;
  {$endif}
end;

end.

我希望FastMM在调用FreeLibrary时生成报告，或者在程序退出时生成报告，如果dll是静态加载的，但没有任何反应。

在FastMM4Options.inc我另外只设置 FullDebugMode 和 ClearLogFileOnStartup ， FastMM_FullDebugMode.dll 位于输出目录中。

我创建了repository on github。我错过了什么？

Answer 1

您的DLL未报告泄漏的原因源于FastMM关闭中的此代码：

  CheckBlocksOnShutdown(
  {$ifdef EnableMemoryLeakReporting}
        True
    {$ifdef RequireIDEPresenceForLeakReporting}
        and DelphiIsRunning
    {$endif}
    {$ifdef RequireDebuggerPresenceForLeakReporting}
        and ((DebugHook <> 0)
        {$ifdef PatchBCBTerminate}
        or (Assigned(pCppDebugHook) and (pCppDebugHook^ <> 0))
        {$endif PatchBCBTerminate}
        )
    {$endif}
    {$ifdef ManualLeakReportingControl}
        and ReportMemoryLeaksOnShutdown
    {$endif}
  {$else}
        False
  {$endif}
  );

在您的选项中，RequireDebuggerPresenceForLeakReporting已定义。更重要的是，在DLL中，DebugHook等于0，大概是因为您正在调试应用程序而不是DLL。这意味着您通过CheckBlocksOnShutdown致电False。并且False禁用泄漏报告。

您可以通过取消定义RequireDebuggerPresenceForLeakReporting来解决此问题。

Answer 2

我只是使用Delphi2010上的快速内存管理器4.97版本测试它 - win7

FastMM4是.dpr（project和dll）'use'子句中的第一个单元
'ShareMM'选项已启用
'AttemptToUseSharedMM'选项已启用
启用'EnableMemoryLeakReporting'选项

在exe

还有一个测试演示'动态加载DLL' 此演示没有ShareMem。我必须设置选项'ShareMM'和'AttemptToUseSharedMM'并添加FastMM_FullDebugMode.dll以获得FastMM的泄漏报告。

如何配置FastMM以检测dll中的内存泄漏

2 个答案: