Question

FastMM报告此行是内存泄漏的来源：

StrClassName := MidStr (curLine, length(START_OF_CLASSNAME)+1, length(curline)+1)

Copy和MidStr有什么用？这只是一个Delphi 2007编译器的bug，还是以后的版本也有这个问题？以下是FastMM报告副本的link，以及image我的应用程序如何显示这些类型的报告。请参阅，为了显示VirtualTreeView中的节点，我需要一种新的数据类型。我称之为TMemoryLeak。当我解析报告时，我给我的TMemoryLeak一个类名，callstack，它的大小等。但是当应用程序关闭并且FastMM启动时，上面的复制行似乎泄漏了内存。我释放了callstack的大小，整个对象，但ClassName字段是一个字符串，总是会释放内存。

更新（来自评论）

这是声明和构造函数以及解构器。至于生命周期 - 一旦对象用于显示节点树，就会调用对象的解构器，之后它们就会被淘汰，并且被释放（我希望）。

TMemoryLeak = class(TObject)
    private
      fID              :integer;
      fSize            :integer;
      fTotalSize       :integer;
      fCallStack       :TStringList;
      fClassName       :string;
      fRepeatedInstance:integer;


    public
      property ID               :integer      read fID                write fID;
      property TotalSize        :Integer      read fTotalSize         write fTotalSize;
      property Size             :integer      read fSize              write fSize;
      property CallStack        :TStringList  read fCallStack         write fCallStack;
      property ClassName        :string       read fClassName         write fClassName;
      property RepeatedInstance :integer      read fRepeatedInstance  write fRepeatedInstance;
      class function Equal(xA: TMemoryLeak; xB: TMemoryLeak): Boolean;
      procedure clear;
      constructor create;
      destructor destroy; override;
  end;

  TMemoryLeakList=class(TObjectList)
    private
      fSortType         :TMlSortType;
      fSortDirection    :TMLSortDirection;
      fTotalLeakSize    :integer;
      fClassName        :string;
      fRepeatedInstance :Integer;
      fID               :Integer;
      function  GetItem(Index: Integer): TMemoryLeak;
      procedure SetItem(Index: Integer; const Value: TMemoryLeak);

    public
      property Items[Index: Integer]:TMemoryLeak      read GetItem             write SetItem; default;
      property TotalLeakSize        :integer          read fTotalLeakSize      write fTotalLeakSize;
      property SortType             :TMLSortType      read fSortType           write fSortType;
      property SortDirection        :TMLSortDirection read fSortDirection      write fSortDirection;
      property ClassName            :string           read fClassName          write fClassName;
      property RepeatedInstance     :integer          read fRepeatedInstance   write fRepeatedInstance;
      property ID                   :Integer          read fID                 write fID;

      function Add(AObject: TMemoryLeak): Integer;
      procedure Clear();
      procedure Sort;

      constructor create;
      destructor destroy; override;
  end;


constructor TMemoryLeak.create;
  begin
    inherited;
    fCallStack := TStringList.create;
    fRepeatedInstance:=0;
  end;
  destructor TMemoryLeak.destroy;
  begin
    clear;
  end;
  procedure TMemoryLeak.clear;
  begin
    fCallStack.Clear;
  end;
  class function TMemoryLeak.Equal(xA, xB: TMemoryLeak): Boolean;
  var i:Integer;
  begin
    Result:=False;

    if xA.ClassName = xb.ClassName then
    begin
      if xA.size = xb.size then
      begin
        if xA.CallStack.Count = xB.CallStack.Count then
        begin
          for i := 0 to xa.CallStack.Count - 1 do
          begin
            if CompareStr(xA.CallStack[i], xB.CallStack[i]) <> 0 then
            begin
             break;
            end;
          end;
          if i = xa.CallStack.Count then
            Result:=True;
        end
      end
    end

  end;

  { TMemoryLeakList }

  constructor TMemoryLeakList.create;
  begin
    inherited;
    fSortType         :=stID;
    fSortDirection    :=sdAsc;
    fClassName        :='';
    fRepeatedInstance :=0;
  end;
  destructor TMemoryLeakList.destroy;
  begin
    Clear;
  end;
  procedure TMemoryLeakList.Clear;
  var i : Integer;
  begin
      for i := 0 to Count - 1 do
        Items[i].clear;
  end;

Answer 1

有意义的解释是你有内存泄漏。

我认为您对FastMM泄漏报告的工作原理有误解。您似乎从泄漏报告中推断Copy，MidStr等是造成泄漏的原因。事实并非如此。分配内存但未随后解除分配时会报告泄漏。在像Copy和MidStr这样的函数的情况下，他们的工作是创建自然涉及内存分配的新字符串。报告泄漏是因为为了保存字符串缓冲区而创建的内存未被释放。当其余代码无法解除分配该内存时，分配函数Copy或MidStr不是错误。

Delphi 2007是一款成熟的产品，已知字符串的内存管理是正确的。也许你做一些手动内存复制，绕过字符串的引用计数。您是否通过调用nil将一些变量/字段设置为FillChar？您是否使用FreeMem而不是Dispose处理了记录？前者不会减少字符串引用计数。这样的事情可能是泄漏的原因。

查看您发布的代码的摘录，这是一个问题：

destructor TMemoryLeakList.destroy;
begin
  Clear;
end;

您无法调用继承的析构函数。这意味着列表的成员不会被销毁。这解释了为什么你的字符串没有被销毁。

实际上，您不需要为列表类提供析构函数。只需删除它，让继承的TObjectList析构函数完成工作。由于OwnsObjects默认为True，因此列表中的任何成员一旦从列表中删除，并且列表本身被销毁，就会被销毁。

如果您的Clear方法实际清除了列表，那么就会发生这种情况。但是您的Clear不是真正的Clear。预期容器中的真实Clear将删除所有成员。您应该删除Clear并依赖继承的版本。

在TMemoryLeak中，您也无法调用继承的析构函数。并且也无法销毁该类拥有的字符串列表实例。

总结一下，我会像这样编写这些构造函数和析构函数：

constructor TMemoryLeak.Create;
begin
  inherited;
  fCallStack := TStringList.Create;
end;

destructor TMemoryLeak.Destroy;
begin
  fCallStack.Free;
  inherited;
end;

constructor TMemoryLeakList.Create;
begin
  inherited;//by default OwnsObjects is set to True, list manages member lifetime
  fSortType :=stID;
  fSortDirection :=sdAsc;
end;

然后移除destructor，并移除Clear方法。继承自TObjectList的版本就足够了。

在评论中说明：

一旦使用对象显示节点树，就会调用对象的析构函数。在那之后它们已经过时了，并且被解除分配（我希望）。

我认为很有可能这没有帮助。由于您在OwnsObjects模式下创建了对象列表，因此您根本不应该破坏列表的成员。您已经要求列表本身执行此操作。你不能两个都这样做。而“我希望”的评论并没有让我充满信心，这段代码是正确的。

由于我们无法看到您的所有代码，因此我很难确定这是它的全部问题。

底线是您的代码有泄漏。相信FastMM！

这怎么是内存泄漏？

1 个答案: