Question

首先，我是Perl和Mojo的新手，所以我会尽力做到这一点......：D

问题在于我需要并行工作，因此该服务需要每秒处理多个调用。此服务将允许其他服务通过REST进行连接以下载和处理文件。我正在对这个想法进行一些测试而没有成功。

我一直在测试 Mojo :: IOLoop ，但我认为我误解了一些关于这个的概念，因为使用循环和定时器的每个实现都是完全错误的......

实际上我的工作流程就在这里：

（1）获取REST呼叫

（2）验证通过mongodb提供的网址

（3）下载与该mongo对象相关联的文件。

所以实际上这是有效的，但我无法看到如何实现这一点以便并行工作......

#!/usr/bin/env_perl
use Mojolicious::Lite;
use MongoDB;

my $mongo     = MongoDB::MongoClient->new(host => 'xxxx.mongohq.com',port => 'xxxxx',     username => 'xxxxx', password => 'xxxxx', db_name => 'xxxxx');
my $database   = $mongo->get_database( 'xxxxx' );
my $collection = $database->get_collection( 'xxxxx' );

any [qw/ get post /] => '/:action/:objid' => sub {

  my $self = shift;

  #Parsing objectid...
  my $objectid  = $self->param('objid');
  my $id = MongoDB::OID->new(value => $objectid);

  my $all = $collection->find({_id => $id});
  my $dts = $all->next;

  download($dts->{parsedoc}->{url},"final_name.xml");

};

app->start;

sub download {
  say "Starting new download..";  
  my $ua = Mojo::UserAgent->new(max_redirects => 5);
  my $tx = $ua->get($_[0]);
  $tx->res->content->asset->move_to($_[1]);
  say "Download ends."; 
}

在这里实施IOLoop的最佳方法是什么？我一直在使用一些mojo计时器示例，但也许我需要重新排序我的应用流程？提前谢谢。

Answer 1

正如我在评论中提到的，Mojo :: IOLoop不涉及并行性，而是涉及事件循环。这意味着可能需要很长时间的操作可以开始，然后仅在完成后继续而不阻塞其他过程。在您的示例中，对Mongo的调用和下载都是这些类型的长时间运行的进程，人们可能希望将其置于事件循环中。 Mojolicious :: UserAgent在与回调一起使用时是非阻塞的（操作完成后调用的操作）。要对Mongo执行相同的操作，您需要确保您的Mongo库可以以非阻塞方式使用。

我已经嘲笑了一个忽略Mongo部分（读者练习）并以非阻塞方式使用UserAgent的小例子。

#!/usr/bin/env perl
use Mojolicious::Lite;

helper download => sub {
  my ($c, $url, $target) = @_;
  my $ua = $c->app->ua->max_redirects(5);

  say "Starting new download ($url) ..."; 
  $ua->get( $url, sub {
    my ($ua, $tx) = @_;
    say "Finished download ($url) ...";
    $tx->res->content->asset->move_to($target);

    say "File saved ($url --> $target)";
    $c->render( text => "File saved ($url --> $target)" );
  });
};

any [qw/ get post /] => '/:action/:objid' => sub {
  my $self = shift;
  $self->render_later; # prevent auto-render

  #Parsing objectid
  my $objectid  = $self->param('objid');
  #verify url here ...

  # example url
  my $url = 'http://www.google.com';

  $self->download($url,"final_name.xml");
};

app->start;

Mojolicious REST + IOLoop并发服务

1 个答案: