Question

有没有办法在为移动设备构建的AS3 / Air应用中动态添加textinput字段？

我有一个表单，用户需要输入一些信息（名称，地址，DOB等），并且有一个部分供用户输入联系号码。我希望能够添加无限量的联系号码。要做到这一点，我有一个＆＃39;添加号码＆＃39;按钮。用户单击此按钮，屏幕会在列表底部添加1个新的textinput。

感谢任何指导或代码示例。

Answer 1

我很无聊所以我做了一个小小的演示。看看下面的链接。

演示： http://ronnieswietek.com/_random/phone_nums.swf

来源： http://ronnieswietek.com/_random/phone_nums.fla

下面的代码可能有点臃肿，但这是出于演示目的

import flash.events.MouseEvent;
import fl.controls.TextInput;
import flash.display.Sprite;

var lastY:Number = origPhoneField.y;
var fieldHolder:Sprite = new Sprite();
fieldHolder.x = origPhoneField.x;
fieldHolder.y = origPhoneField.y + 35;
addChild(fieldHolder);

function addPhoneField(e:MouseEvent):void
{
    //-- clicking the plus icon will add a new custom text input
    //-- its only custom because I added a minus button to it
    var newInput:CustomTextInput = new CustomTextInput();
    newInput.y = (fieldHolder.numChildren > 0) ? fieldHolder.height + 5 : 0;
    fieldHolder.addChild(newInput);
    newInput.minusBtn.addEventListener(MouseEvent.CLICK, removePhoneField);
}
addBtn.addEventListener(MouseEvent.CLICK, addPhoneField);

function removePhoneField(e:MouseEvent):void
{
    //-- clicking the minus will remove the movie clip and reposition the other fields vertically
    fieldHolder.removeChild(e.target.parent);
    for (var i:int = 0; i < fieldHolder.numChildren; i++)
    {
        var target = fieldHolder.getChildAt(i);
        target.y = (i * 35);
    }
}

function showNumbers(e:MouseEvent):void
{
    //-- for demo purposes, this will output all the values
    outputWin.text += origPhoneField.text + "\n";
    for (var i:int = 0; i < fieldHolder.numChildren; i++)
    {
        var target = fieldHolder.getChildAt(i);
        outputWin.text += target.theField.text + "\n";
    }
    outputWin.text += "================\n";
}
showNums.addEventListener(MouseEvent.CLICK, showNumbers);

如何在AS3 AIR应用程序中动态添加textinput

1 个答案: