Question

我已根据“OpenGL编程指南”第8版中的演示实现了OIT。（红皮书）。现在我需要添加MSAA.Just使MSAA可以提高透明度，因为分层像素被解析x次等于样本级别的数量。我已经阅读了this文章，了解如何使用DirectX，他们说像素着色器应该按照每个样本而不是每个像素运行。如何在OpenGL中完成。

我不会在这里推出整个实现，而是片段着色器块，其中分层像素的最终分辨率出现：

vec4 final_color = vec4(0,0,0,0);
for (i = 0; i < fragment_count; i++)
{
    /// Retrieving the next fragment from the stack:
    vec4 modulator = unpackUnorm4x8(fragment_list[i].y) ;
    /// Perform alpha blending:
    final_color =   mix(final_color, modulator, modulator.a);
}

color = final_color ;

更新

我已经尝试了这里提出的解决方案，但它仍然不起作用。这是列表构建和解析过程的完整片段着色器：

列出构建通行证：

#version 420 core
layout (early_fragment_tests) in;
layout (binding = 0, r32ui) uniform uimage2D head_pointer_image;
layout (binding = 1, rgba32ui) uniform writeonly uimageBuffer list_buffer;
layout (binding = 0, offset = 0) uniform atomic_uint list_counter;
layout (location = 0) out vec4 color;//dummy output

in vec3 frag_position;
in vec3 frag_normal;
in vec4 surface_color;
in int gl_SampleMaskIn[];
uniform vec3 light_position = vec3(40.0, 20.0, 100.0);

void main(void)
{
    uint index;
    uint old_head;
    uvec4 item;
    vec4 frag_color;
    index = atomicCounterIncrement(list_counter);
    old_head = imageAtomicExchange(head_pointer_image, ivec2(gl_FragCoord.xy), uint(index));

    vec4 modulator =surface_color;
    item.x = old_head;
    item.y = packUnorm4x8(modulator);
    item.z = floatBitsToUint(gl_FragCoord.z);
    item.w = int(gl_SampleMaskIn[0]);
    imageStore(list_buffer, int(index), item);
    frag_color = modulator;
    color = frag_color;
}

列出决心：

#version 420 core
// The per-pixel image containing the head pointers
layout (binding = 0, r32ui) uniform uimage2D head_pointer_image;
// Buffer containing linked lists of fragments
layout (binding = 1, rgba32ui) uniform uimageBuffer list_buffer;
// This is the output color
layout (location = 0) out vec4 color;
// This is the maximum number of overlapping fragments allowed
#define MAX_FRAGMENTS 40

// Temporary array used for sorting fragments
uvec4 fragment_list[MAX_FRAGMENTS];

void main(void)
{
    uint current_index;
    uint fragment_count = 0;
    current_index = imageLoad(head_pointer_image, ivec2(gl_FragCoord).xy).x;

    while (current_index != 0 && fragment_count < MAX_FRAGMENTS )
    {   
        uvec4 fragment = imageLoad(list_buffer, int(current_index));
        int coverage = int(fragment.w);
        //if((coverage &(1 << gl_SampleID))!=0) {

            fragment_list[fragment_count] = fragment;
            current_index = fragment.x;

        //}

        fragment_count++;
    }

    uint i, j;

    if (fragment_count > 1)
    {
        for (i = 0; i < fragment_count - 1; i++)
        {
            for (j = i + 1; j < fragment_count; j++)
            {
                uvec4 fragment1 = fragment_list[i];
                uvec4 fragment2 = fragment_list[j];

                float depth1 = uintBitsToFloat(fragment1.z);
                float depth2 = uintBitsToFloat(fragment2.z);

                if (depth1 < depth2)
                {
                    fragment_list[i] = fragment2;
                    fragment_list[j] = fragment1;
                }
            }
        }
    }

    vec4 final_color = vec4(0,0,0,0);

    for (i = 0; i < fragment_count; i++)
    {  
        vec4 modulator = unpackUnorm4x8(fragment_list[i].y);
        final_color =  mix(final_color, modulator, modulator.a);      
    }

    color = final_color;
}

Answer 1

在不知道代码实际如何工作的情况下，您可以像链接DX11演示那样完成相同的操作，因为OpenGL提供了所需的相同功能。

因此，在第一个仅存储所有渲染片段的着色器中，您还存储每个片段的样本覆盖蒙版（当然还有颜色和深度）。这是作为片段着色器输入变量int gl_SampleMaskIn[]给出的，对于标识为32*i+j的每个样本，如果片段覆盖该样本，则设置j的位glSampleMaskIn[i]（因为您可能赢了）使用＆gt; 32xMSAA，通常只需使用glSampleMaskIn[0]，只需要存储一个int作为覆盖掩码。）

...
fragment.color = inColor;
fragment.depth = gl_FragCoord.z;
fragment.coverage = gl_SampleMaskIn[0];
...

然后为每个样本运行最终的排序和渲染着色器，而不是仅为每个片段运行。这是通过使用输入变量int gl_SampleID隐式实现的，它给出了当前样本的ID。所以我们在这个着色器中做的（除非非MSAA版本）是排序步骤只是考虑样本，只是在最终（待排序）片段列表中添加片段（如果当前样本实际被覆盖）通过这个片段：

有什么感觉（请注意，从您的小片段和DX链接中推断出伪代码）：

while(fragment.next != 0xFFFFFFFF)
{
    fragment_list[count++] = vec2(fragment.depth, fragment.color);
    fragment = fragments[fragment.next];
}

现在是

while(fragment.next != 0xFFFFFFFF)
{
    if(fragment.coverage & (1 << gl_SampleID))
        fragment_list[count++] = vec2(fragment.depth, fragment.color);
    fragment = fragments[fragment.next];
}

或类似的东西。

编辑：对于更新的代码，您必须仅在fragment_count块内增加if(covered)，因为我们不想将片段添加到列表中样品没有覆盖。增加它总是会导致您在边缘看到的伪像，即MSAA（以及覆盖范围）发挥作用的区域。

另一方面，列表指针必须在每次循环迭代中转发（current_index = fragment.x），而不仅仅是样本被覆盖，否则它会导致无限循环，就像你的情况一样。所以你的代码应该是这样的：

while (current_index != 0 && fragment_count < MAX_FRAGMENTS )
{
    uvec4 fragment = imageLoad(list_buffer, int(current_index));
    uint coverage = fragment.w;
    if((coverage &(1 << gl_SampleID))!=0)
        fragment_list[fragment_count++] = fragment;
    current_index = fragment.x;
}

Answer 2

关于gl_SampleID内置变量的7.1中的OpenGL 4.3 Spec状态：

在片段着色器中静态使用此变量会导致整个着色器按样本进行评估。

（在ARB_sample_shading中已经出现这种情况，gl_SamplePosition或使用sample限定符声明的自定义变量也是如此）

因此它非常自动，因为你可能还需要SampleID。

通过MSAA订购独立透明度

2 个答案: