Question

我正在研究Happy数学表达式和变量解析器。问题是我不知道如何保存变量的值并在以后使用它。有什么想法吗？

这是我识别表达式和变量赋值的方式：

genExp   : exp                    { $1 }
         | variable '=' exp            { //here I want to save the value of the variable; something like this: insert variables $1 $3, where 'variables' is a Data.Map }

表达式可以包含变量。例如：

a = 2 + 1
a + 2 (now the parser must print 5)

当解析器解析行'a = 2 + 1'时，我需要保存变量'a'的值，当解析器解析行'a +时，我需要获取变量'a'的值2'

Answer 1

您要做的是在表达式的评估期间跟踪变量的值，而不是在解析期间。我们假设您将表达式解析为以下类型：

data Expr = Literal Int | Variable Var | Assign Var Expr | Add Expr Expr | ...
newtype Var = Var String deriving (Ord, Eq, Show)

然后，您可以使用所有变量的当前值简单地在评估函数周围传递一个Map：

import qualified Data.Map as M
import Control.Monad.State

data Expr = Literal Int | Variable Var | Assign Var Expr | Add Expr Expr
newtype Var = Var String deriving (Ord, Eq, Show)

-- Each Expr corresponds to a single line in your language, so
-- a = 2+1
-- a + 2
-- corresponds to
-- [Assign (Var "a") (Add (Literal 2) (Literal 1)),
--  Add (Variable (Var "a")) (Literal 2)]
eval :: [Expr] -> Int
eval es = last $ evalState (mapM eval' es) M.empty -- M.empty :: M.Map Var Int
  where
    eval' (Literal n)  = return n
    eval' (Variable v) = do
      vs <- get
      case M.lookup v vs of
        Just x -> return x
        _      -> error $ "variable " ++ show v ++ " is undefined!"
    eval' (Assign v ex) = do
      x <- eval' ex
      modify (M.insert v x)
      return x
    eval' (Add a b) = do
      x <- eval' a
      y <- eval' b
      return (x+y)

当然，在解析表达式时，没有什么可以阻止您评估表达式，从而无需像这样的抽象语法树。一般的想法是一样的;在整个解析过程中，您需要与您保持一些状态，以跟踪所有变量的当前值。

Haskell - 快乐，数学表达式和变量解析器

1 个答案: