Question

我正在尝试编写一个Perl函数，该函数接收两个Lists / Arrays并计算它们的交叉积（笛卡尔积）。我目前有代码工作，它采用两个输入列表并计算交叉产品，但我在打印嵌套列表时遇到问题。

我正在寻找关于打印嵌套List的最佳方式的建议。以下是我当前的尝试：

for(@C) { 
    for(@$_) { 
        print $_; 
    } 
    print " ";
}

# prints
# 1A 1B 1C 1D 1E 1F 1G 1H 1I 
# 2A 2B 2C 2D 2E 2F 2G 2H 2I 
# 3A 3B 3C 3D 3E 3F 3G 3H 3I 
# 4A 4B 4C 4D 4E 4F 4G 4H 4I 
# etc ...

但这对我来说不够 Perly 。所以我用map进行了另一次尝试：

print map { 
    map { $_ } @$_; 
} @C;

# prints
# 1A1B1C1D1E1F1G1H1I
# 2A2B2C2D2E2F2G2H2I
# 3A3B3C3D3E3F3G3H3I
# 4A4B4C4D4E4F4G4H4I
# etc ...

但是这些项目都被压在了一起。无论如何使用map格式化此方法？有没有更好的方法来实现这一目标？

全功能代码：

use strict;
use warnings; 

# globals
my @digits  = (1,2,3,4,5,6,7,8,9);
my @letters = ("A","B","C","D","E","F","G","H","I");
my @rows = @digits;
my @cols = @letters;
my @squares = cross(\@rows, \@cols);

sub cross {
    my @C = [];

    foreach (reverse @_) {
        my @A = @$_;

        @C = map { my $n = $_; map { [ $n, @$_ ] } @C } @A;
    }

    # works
    #for(@C) { 
    #   for(@$_) { 
    #       print $_; 
    #   } 
    #   print " ";
    #}

    print map { 
        map { $_ } @$_; 
    } @C;

    return @C;
}

Answer 1

没有任何内容表明map无法返回格式化字符串：

print map { " $_" };

或者为了更精确的控制，请使用join：

print join ' ', map { ... };

Answer 2

print map { join '', @$_, ' ' } @C;

Answer 3

默认情况下，数组会根据您的需要插入到字符串中。所以：

#! /usr/bin/env perl
use common::sense;

my @a = ([qw/1A 1B 1C 1D 1E 1F 1G 1H 1I/],
         [qw/2A 2B 2C 2D 2E 2F 2G 2H 2I/],
         [qw/3A 3B 3C 3D 3E 3F 3G 3H 3I/],
         [qw/4A 4B 4C 4D 4E 4F 4G 4H 4I/],
         ['etc', '...']);

say "# prints";
say "# @$_" for @a;

输出：

# prints
# 1A 1B 1C 1D 1E 1F 1G 1H 1I
# 2A 2B 2C 2D 2E 2F 2G 2H 2I
# 3A 3B 3C 3D 3E 3F 3G 3H 3I
# 4A 4B 4C 4D 4E 4F 4G 4H 4I
# etc ...

可替换地，

local $" = ', ';
say "# @$_" for @a;

输出：

# 1A, 1B, 1C, 1D, 1E, 1F, 1G, 1H, 1I
# 2A, 2B, 2C, 2D, 2E, 2F, 2G, 2H, 2I
# 3A, 3B, 3C, 3D, 3E, 3F, 3G, 3H, 3I
# 4A, 4B, 4C, 4D, 4E, 4F, 4G, 4H, 4I
# etc, ...

使用格式打印嵌套列表

3 个答案: