Question

我想为给定的input生成一个真值表。如果我给输入2输出将是

10 01 11 00

如果输入为3，则输出为

111 000 110 101 011 100 001 010

我有一个代码段

#!/usr/bin/perl

#print "a|b|c\n";

for $a (1, 0){
    for $b (1, 0){
      for  $c (1,0) {
        for $d ( 1,0) 
        {        
          print "$a $b $c $d";
          #print $x = ($a & $b & $c);
          print "\n";
        }
     }
   }
}

print "\n";

上面的代码是4。

我不知道如何在不编写多个for循环的情况下执行此操作。这里的值为2我需要写两个for循环等等。

任何机构都可以告诉我如何为几个输入值调整此代码。

任何帮助都将非常感谢

Answer 1

<强>递归

这是一个使用递归的简单解决方案：

#!/usr/bin/perl -w                                                              
my $variables=$ARGV[0]||0;
show_combinations($variables);                                                           

sub show_combinations { my($n,@prefix)=@_;                                      
  if($n > 0) {                                                                  
    show_combinations( $n-1, @prefix, 0);                                       
    show_combinations( $n-1, @prefix, 1);                                       
  } else {                                                                      
    print "@prefix\n";                                                          
  }                                                                             
}

以下是一些示例案例：

> script.pl 1
0
1
> script.pl 2
0 0
0 1
1 0
1 1
> script.pl 3
0 0 0
0 0 1
0 1 0
0 1 1
1 0 0
1 0 1
1 1 0
1 1 1

Answer 2

我不是Perl专家，所以你可能需要清理它，但如果被迫使用Perl，我可能会做这样的事情：

#!/usr/bin/perl

my ($n) = @ARGV;

printf("%0*b\n", $n, $_) for 0 .. (1 << $n) - 1;

Answer 3

我不知道Perl，所以这可能不起作用：

- 从0循环到（2 ^ n）-1，其中n是你案例中的位数;

- 将每个数字转换为其n位二进制表示;

Answer 4

这是使用模块Math::Cartesian::Product的简单的一行Perl代码。

use Math::Cartesian::Product;

cartesian {print "@_\n"} ([0..1]) x $ARGV[0];

输出

    
./sample.pl 2

0 0
0 1
1 0
1 1

./sample.pl 3

0 0 0
0 0 1
0 1 0
0 1 1
1 0 0
1 0 1
1 1 0
1 1 1

Answer 5

以下是使用Math::BigInt对我之前的解决方案的概括。这是一个迭代解决方案：

#!/usr/bin/perl

use strict;
use warnings;

use Math::BigInt try => 'GMP';

my $n_bits = $ARGV[0] || 0;

my $it = make_it($n_bits);

while ( defined(my $bits = $it->()) ) {
    print "$bits\n";
}

sub make_it {
    my ($n_bits) = @_;

    my $limit = Math::BigInt->new('2');
    $limit->blsft($n_bits - 1);

    my $next = Math::BigInt->new('-1');

    return sub {
        $next->binc;
        return unless $next->bcmp($limit) < 0;
        my $bits = $next->as_bin;
        $bits =~ s/^0b//;
        if ( (my $x = length $bits) < $n_bits ) {
            $bits = '0' x ($n_bits - $x) . $bits;
        }
        return $bits;
    }
}

您可以使用%b的{{1}}格式说明符：

printf

这仅适用于小于32的use strict; use warnings; my ($count) = @ARGV; my $fmt = "%0${count}b"; my $n = 2**$count - 1; for my $c (0 .. $n) { my @bits = split //, sprintf $fmt, $c; print "@bits\n"; }值。

输出：

C:\Temp> y 3
0 0 0
0 0 1
0 1 0
0 1 1
1 0 0
1 0 1
1 1 0
1 1 1

Answer 6

我很惊讶没有人在这里提到glob作为解决方案：

perl -e 'print join "\n", glob("{0,1}" x shift || 1 )' -- 3

打印：

glob非常便于计算字符串排列。

以上是以更清洁，非单行的形式：

use strict;
use warnings;

my $symbol_count = shift || 1;

my @permutations = glob( '{0,1}' x $symbol_count );

print join "\n", @permutations;

给定输入的真值表生成

6 个答案: