Question

我正在尝试在批处理脚本中将~替换为%HOME%。这就是我到目前为止所做的：

@echo off
setlocal enabledelayedexpansion
set str=%*
set replacement=%HOME%
set str=%str:~=!replacement!%
echo %str%

这不像我预期的那样有效，大概是因为我需要以某种方式逃避波浪号~。

当我使用^转义时，str保持不变。如果没有转义，str就是字符串str:~=<my_home_path>。

如何将"~/work/my_folder"更改为"C:/Users/login/work/my_folder"？

Answer 1

如果~始终是第一个字符，您可以使用如下：

@echo off &setlocal enabledelayedexpansion
set "str=|~/work/my_folder"
set "replacement=C:/Users/login"
set str=%str:|~=!replacement!%
echo %str%

Answer 2

或者更复杂一点：

@echo off &setlocal enabledelayedexpansion
set "str=~/work/my_folder -param one ~ two:~"
set "replacement=C:/Users/login"
call :strlen str len
set /a len-=1
for /l %%i in (0,1,%len%) do if "!str:~%%i,1!"=="~" (set "new=!new!%replacement%") else set "new=!new!!str:~%%i,1!"
echo %new%
goto :eof

:strlen
:: list string length up to 8189 (and reports 8189 for any string longer than 8189)
:: function from http://ss64.org/viewtopic.php?pid=6478#p6478
(   setlocal enabledelayedexpansion & set /a "}=0"
    if "%~1" neq "" if defined %~1 (
        for %%# in (4096 2048 1024 512 256 128 64 32 16) do (
            if "!%~1:~%%#,1!" neq "" set "%~1=!%~1:~%%#!" & set /a "}+=%%#"
        )
        set "%~1=!%~1!0FEDCBA9876543211" & set /a "}+=0x!%~1:~32,1!!%~1:~16,1!"
    )
)
endlocal & set /a "%~2=%}%" & exit /b
endlocal

输出：

C:/Users/login/work/my_folder -param one C:/Users/login two:C:/Users/login

这不适用于感叹号。

Answer 3

我认为除了几个小问题之外你已经非常接近了。

首先，Windows %home%中可能没有环境变量 - 至少在我的系统上没有。我认为你要找的变量是%userprofile%。 ss64.com有一个很好的列表和Windows environment variables的描述。

另一个问题是你以错误的顺序推迟扩张。尝试将倒数第二行更改为set str=!str:~=%userprofile%!，以便内部变量在外部变量之前扩展。将正斜杠向后翻译可能也不是一个坏主意。

@echo off
setlocal enabledelayedexpansion
set str=%*
set "str=!str: ~= %userprofile%!"
set "str=!str:*~=%userprofile%!"
set "str=%str:\=/%"
echo %str%

示例输出：

C:\Users\me\Desktop>test ~/.bash_profile
C:/Users/me/.bash_profile

C:\Users\me\Desktop>test arg1 arg2 ~/.bash_profile
arg1 arg2 C:/Users/me/.bash_profile

Answer 4

    @ECHO OFF
    CLS
    SET OldStr=~\work\my_folder
    SET NewStr=
    SET Replacement=C:\Users\login\work\my_folder
    CALL :ReplaceHome "%OldStr%"
    ECHO %NewStr%
    EXIT /b %ERRORLEVEL%

    :ReplaceHome
    IF "%~1"=="" EXIT /B %ERRORLEVEL%
    SET TempStr=%~1
    IF "%TempStr:~0,1%"=="~" SET TempStr=%Replacement%%TempStr:~1%
    SET NewStr=%NewStr%%TempStr:~0,1%
    CALL :ReplaceHome "%TempStr:~1%"
    EXIT /B %ERRORLEVEL%

cmd字符串替换特殊字符

4 个答案: