Question

我正在使用XML存储一个小的联系人列表并尝试编写一个XSL模板，将其转换为CSV文件。我遇到的问题是输出中有空格。

输出：

Friend, John, Smith, Home,
        123 test,
       Sebastopol,
       California,
       12345,
     Home 1-800-123-4567, Personal john.smith@gmail.com

我缩进/间隔了源XML文件和关联的XSL模板，以便于阅读和开发，但所有额外的空白区域都会自动进入输出。 XML本身在节点内没有额外的空格，只是在它们之外用于格式化，XSLT也是如此。

为了使CSV文件有效，每个条目都需要在它自己的行上，而不是分解。除了从XML和XSLT剥离所有额外的空白区域（使它们只是一长串代码）之外，还有另一种方法可以摆脱输出中的空格吗？

编辑：这是一个小型XML示例：

<PHONEBOOK>
    <LISTING>
        <FIRST>John</FIRST>
        <LAST>Smith</LAST>
        <ADDRESS TYPE="Home">
            <STREET>123 test</STREET>
            <CITY>Sebastopol</CITY>
            <STATE>California</STATE>
            <ZIP>12345</ZIP>
        </ADDRESS>
        <PHONE>1-800-123-4567</PHONE>
        <EMAIL>john.smith@gmail.com</EMAIL>
        <RELATION>Friend</RELATION>
    </LISTING>
</PHONEBOOK>

这是XSLT：

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" />

 <xsl:template match="/">
   <xsl:for-each select="//LISTING">
    <xsl:value-of select="RELATION" /><xsl:text>, </xsl:text>
    <xsl:value-of select="FIRST" /><xsl:text>, </xsl:text>
    <xsl:value-of select="LAST" /><xsl:text>, </xsl:text>

    <xsl:if test="ADDRESS">
     <xsl:for-each select="ADDRESS">
       <xsl:choose>
        <xsl:when test="@TYPE">
         <xsl:value-of select="@TYPE" />,
        </xsl:when>
            <xsl:otherwise>
            <xsl:text>Home </xsl:text>
            </xsl:otherwise>
       </xsl:choose>
       <xsl:value-of select="STREET" />,
       <xsl:value-of select="CITY" />,
       <xsl:value-of select="STATE" />,
       <xsl:value-of select="ZIP" />,
     </xsl:for-each>
    </xsl:if>

    <xsl:for-each select="PHONE">
      <xsl:choose>
       <xsl:when test="@TYPE">
        <xsl:value-of select="@TYPE" />  
       </xsl:when>
       <xsl:otherwise><xsl:text>Home </xsl:text></xsl:otherwise>
      </xsl:choose>
     <xsl:value-of select="."  /><xsl:text  >, </xsl:text>
    </xsl:for-each>

    <xsl:if test="EMAIL">
     <xsl:for-each select="EMAIL">
      <xsl:choose>
       <xsl:when test="@TYPE">
        <xsl:value-of select="@TYPE" /><xsl:text  > </xsl:text> 
       </xsl:when>
       <xsl:otherwise><xsl:text  >Personal </xsl:text></xsl:otherwise>
      </xsl:choose>
      <xsl:value-of select="."  /><xsl:text  >, </xsl:text>
     </xsl:for-each>
    </xsl:if>
    <xsl:text>&#10;&#13;</xsl:text>
   </xsl:for-each>
 </xsl:template>

</xsl:stylesheet>

Answer 1

在XSLT中，默认情况下会保留空白区域，因为它很可能是相关数据。

防止输出中不需要的空白区域的最佳方法不是首先创建它。不要这样做：

<xsl:template match="foo">
  foo
</xsl:template>

因为从处理器的角度来看是"\n··foo\n"。而是

<xsl:template match="foo">
  <xsl:text>foo</xsl:text>
</xsl:template>

只要在XML元素之间出现，样式表中的空格就会被忽略。简单地说：永远不要在XSLT代码中的任何地方使用“裸”文本，始终将其包含在元素中。

另外，使用非特定的：

<xsl:apply-templates />

是有问题的，因为文本节点的默认XSLT规则说“将它们复制到输出”。这也适用于“仅限空白”的节点。例如：

<xml>
  <data> value </data>
</xml>

包含三个文本节点：

"\n··"（在<xml>之后）
"·value·"
“\n"（</xml>之前）

为了避免＃1和＃3潜入输出（这是不需要的空格的最常见原因），您可以通过声明一个空模板来覆盖文本节点的默认规则：

<xsl:template match="text()" />

现在所有文本节点都已静音，并且必须明确创建文本输出：

<xsl:value-of select="data" />

要从值中删除空格，可以使用normalize-space() XSLT函数：

<xsl:value-of select="normalize-space(data)" />

但要小心，因为该函数规范化了字符串中的任何空格，例如"·value··1·"将成为"value·1"。

此外，您可以使用<xsl:strip-space>和<xsl:preserve-space>元素，但通常这不是必需的（就个人而言，我更喜欢如上所示的显式空白处理）。

Answer 2

默认情况下，XSLT模板设置为<xsl:preserve-space>，这将在输出中保留空格。您可以添加<xsl:strip-space elements="*">来告诉它删除空格的位置。

您可能还需要包含normalize-space指令，如下所示：

<xsl:template match="text()"><xsl:value-of select="normalize-space(.)"/></xsl:template>

这是example for preserve/strip space from W3 Schools。

Answer 3

至于删除标签但保留单独的行，我尝试了以下XSLT 1.0方法，它运行得相当好。您对1.0或2.0版本的使用在很大程度上取决于您使用的平台。看起来.NET技术仍然依赖于XSLT 1.0，所以你只能使用非常混乱的模板（见下文）。如果您正在使用Java或其他东西，请参阅最底层列出的更清晰的XSLT 2.0方法。

这些示例旨在由您扩展以满足您的特定需求。我在这里使用选项卡作为示例，但这应该是通用的，可以扩展。

XML：

<?xml version="1.0" encoding="UTF-8"?>
<text>
        adslfjksdaf

                dsalkfjdsaflkj

            lkasdfjlsdkfaj
</text>

...和XSLT 1.0模板（如果使用.NET则需要）：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet  
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">   
 <xsl:template name="search-and-replace">
   <xsl:param name="input"/>
   <xsl:param name="search-string"/>
   <xsl:param name="replace-string"/>
   <xsl:choose>
    <xsl:when test="$search-string and 
                    contains($input,$search-string)">
       <xsl:value-of
           select="substring-before($input,$search-string)"/>
       <xsl:value-of select="$replace-string"/>
       <xsl:call-template name="search-and-replace">
         <xsl:with-param name="input"
               select="substring-after($input,$search-string)"/>
         <xsl:with-param name="search-string"
               select="$search-string"/>
         <xsl:with-param name="replace-string"
               select="$replace-string"/>
       </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$input"/>
    </xsl:otherwise>
   </xsl:choose>
  </xsl:template>                
  <xsl:template match="text">
   <xsl:call-template name="search-and-replace">
     <xsl:with-param name="input" select="text()" />
     <xsl:with-param name="search-string" select="'&#x9;'" />
     <xsl:with-param name="replace-string" select="''" />
   </xsl:call-template>    
  </xsl:template>
</xsl:stylesheet>

XSLT 2.0使用replace函数实现这一点：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:xs="http://www.w3.org/2001/XMLSchema"
      exclude-result-prefixes="xs"
      version="2.0">
 <xsl:template match="text">
  <xsl:value-of select="replace(text(), '&#x9;', '')" />
 </xsl:template>
</xsl:stylesheet>

Answer 4

其他人已经指出了一般问题。样式表的具体问题是您忘记了<xsl:text>逗号：

   <xsl:choose>
    <xsl:when test="@TYPE">
     <xsl:value-of select="@TYPE" />,
    </xsl:when>
    <xsl:otherwise>Home </xsl:otherwise>
   </xsl:choose>
   <xsl:value-of select="STREET" />,
   <xsl:value-of select="CITY" />,
   <xsl:value-of select="STATE" />,
   <xsl:value-of select="ZIP" />,

这会使每个逗号后面的空格显着，因此它最终会出现在输出中。如果您在<xsl:text>中包装每个逗号，问题就会消失。

另外，摆脱disable-output-escaping。它没有在这里做任何事情，因为你没有输出XML。

Answer 5

将一个模板添加到xslt

中

$(window).scroll(function() {

        var scroll = $(window).scrollTop();

  if (scroll >= 850) {

        if (scroll <= 650) {
          $j('.innerimage').attr('src', 'images/side_1.png');
        }


          $j('.innerimage').attr('src', 'images/side_2.png');
   }
});

Answer 6

我的上一个回答是错误的，所有逗号必须通过标签'text'

输出

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/PHONEBOOK">
        <xsl:for-each select="LISTING">
            <xsl:value-of select="RELATION" /><xsl:text>, </xsl:text>
            <xsl:value-of select="FIRST" /><xsl:text>, </xsl:text>
            <xsl:value-of select="LAST" /><xsl:text>, </xsl:text>

                <xsl:for-each select="ADDRESS">
                    <xsl:choose>
                        <xsl:when test="@TYPE">
                            <xsl:value-of select="@TYPE" /><xsl:text>,</xsl:text>
                        </xsl:when>
                        <xsl:otherwise><xsl:text>Home </xsl:text></xsl:otherwise>
                    </xsl:choose>
                <xsl:value-of select="STREET/text()" /><xsl:text>,</xsl:text>
                    <xsl:value-of select="CITY/text()" /><xsl:text>,</xsl:text>
                    <xsl:value-of select="STATE/text()" /><xsl:text>,</xsl:text>
                    <xsl:value-of select="ZIP/text()" /><xsl:text>,</xsl:text>
                </xsl:for-each>

            <xsl:for-each select="PHONE">
                <xsl:choose>
                    <xsl:when test="@TYPE">
                        <xsl:value-of select="@TYPE" />  
                    </xsl:when>
                    <xsl:otherwise><xsl:text>Home </xsl:text></xsl:otherwise>
                </xsl:choose>
                <xsl:value-of select="."  /><xsl:text  >, </xsl:text>
            </xsl:for-each>

            <xsl:if test="EMAIL">
                <xsl:for-each select="EMAIL">
                    <xsl:choose>
                        <xsl:when test="@TYPE">
                            <xsl:value-of select="@TYPE" /><xsl:text  > </xsl:text> 
                        </xsl:when>
                        <xsl:otherwise><xsl:text  >Personal </xsl:text></xsl:otherwise>
                    </xsl:choose>
                    <xsl:value-of select="."  /><xsl:text  >, </xsl:text>
                </xsl:for-each>
            </xsl:if>
            <xsl:text>&#10;&#13;</xsl:text>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="text()|@*">
        <xsl:text>-</xsl:text>
    </xsl:template>

</xsl:stylesheet>

Answer 7

通过删除以下行修改我们用于格式化原始xml文件的代码将删除在导出的Excel中添加的额外空白空格。

使用缩进属性系统进行格式化时会添加这些额外的空白空格。

与格式化xml相关的注释行，如下面的行并尝试。

xmlWriter.Formatting = System.Xml.Formatting.Indented;

Answer 8

此答案可能无法直接回答问题。但是一般的方法可以解决这个问题。创建模板规则：

<xsl:template name="strip-space">
    <xsl:param name="data"/>
    <xsl:value-of select="normalize-space($data)"/>
</xsl:template>

现在调用它以删除多余的空格：

<xsl:template match="my-element">
    <xsl:call-template name="strip-space">
        <xsl:with-param name="data">
            <xsl:apply-templates/>
        </xsl:with-param>
    </xsl:call-template>
</xsl:template>

例如，考虑以下XML片段：

<?xml version="1.0" encoding="UTF-8"?>
<test>
    <my-element>
        <e1>some text</e1> <e2>some other text</e2> <e3>some other text</e3>
    </my-element>
</test>

如果有人喜欢将其转换为以下文字：

{test{my-element{e1some text} {e2some other text} {e3some other text}}}

现在是样式表：

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" />

    <xsl:template match="/">
        <xsl:apply-templates mode="t1"/>
        <xsl:text>&#xa;</xsl:text>
        <xsl:apply-templates mode="t2"/>
    </xsl:template>

    <xsl:template match="*" mode="t1">
        <xsl:text>{</xsl:text>
        <xsl:value-of select="local-name()"/>
        <xsl:call-template name="strip-space">
            <xsl:with-param name="data">
                <xsl:apply-templates mode="t1"/>
            </xsl:with-param>
        </xsl:call-template>
        <xsl:text>}</xsl:text>
    </xsl:template>

    <xsl:template match="*" mode="t2">
        <xsl:text>{</xsl:text>
        <xsl:value-of select="local-name()"/>
        <xsl:value-of select="."/>
        <xsl:text>}</xsl:text>
    </xsl:template>

    <xsl:template name="strip-space">
        <xsl:param name="data"/>
        <xsl:value-of select="normalize-space($data)"/>
    </xsl:template>

</xsl:stylesheet>

应用样式表后，它会产生：

{test{my-element{e1some text} {e2some other text} {e3some other text}}}

{test

        some text some other text some other text

}

输出描述了@mode="t1"（<xsl:value-of select="."/>方法）与@mode="t2"（xsl:call-template方法）的不同。希望这对某人有帮助。

XSLT - 从模板中删除空格

8 个答案: