Question

为什么SQLHelper.vb中的ExecuteDataTable没有共享功能。有一个：ExecuteReader，ExecuteDataset和ExecuteScaler。

这不是问题，因为我会写自己的。我只是在徘徊为什么会这样。我通常会使用DataReader，但我正在编写数据逻辑层，而DataTable需要比连接更长（DataReader不能超过连接）。

Answer 1

ExecuteDataset()已经满足您的需求。从某种意义上说，数据集只是DataTables的集合。

我通常会使用DataReader，但我正在编写数据逻辑层，而DataTable需要比连接更长（DataReader不能超过连接）。

在这种情况下，我可以建议您构建一个在Iterator块中使用DataReader的ExecuteEnumerable()方法，而不是构建一个ExecuteDatatable（）方法。代码看起来像这样：

Public Shared Iterator Function ExecuteEnumerable(Of T)( ... ) As IEnumerable(Of T)
   Using cn As New SqlConnection( ... ), _
         cmd As New SqlCommand( ... )

       'As needed
       'cmd.Parameters.Add( ... ).Value = ...

       Using rdr As SqlDataReader = cmd.ExecuteReader()
           While rdr.Read()
               Yield transform(rdr)
           End While
       End Using
    End Using
End Function

你会注意到我跳过了一些事情。我不熟悉现有的SqlHelper.vb文件，因为您希望匹配现有的样式，我在代码中留下了空间以供您调整。但是，我想提出两个重要的部分：

请注意cmd.Parameters.Add（）调用。实用程序sql帮助类的一个常见失败是它们无法充分提供查询参数。通常结果都是非常不安全的代码。如果您现在没有办法为现有方法传递参数数据，则需要创建一个。这是优先事项1.
transform(rdr)调用将使用Func(IDataRecord, T)委托，该委托必须作为函数的参数提供。要使ExecuteEnumerable（）迭代器概念起作用，必须在每次迭代时获取SqlDataReader对象中当前值的副本。您可以在此处设置某种通用数据传输对象，就像在DataTable中使用DataRow类型一样。但是，我宁愿使用委托将代码直接复制到强类型的业务对象中，而不是花费cpu和内存时间来创建某种类型的通用数据传输对象。缺点是需要通过每次调用方法发送有关如何为特定对象执行此操作的说明。但是，大多数情况下，这很容易与业务对象上的共享工厂方法一起使用。

Answer 2

我们可以创建像DataSet一样的

' Execute a SqlCommand (that returns a resultset) against the specified SqlConnection 
' using the provided parameters.
' e.g.:  
' Dim dt As DataTable = ExecuteDataTable(conn, CommandType.StoredProcedure, "GetOrders", new SqlParameter("@prodid", 24))
' Parameters:
' -connection - a valid SqlConnection
' -commandType - the CommandType (stored procedure, text, etc.)
' -commandText - the stored procedure name or T-SQL command
' -commandParameters - an array of SqlParamters used to execute the command
' Returns: A dataset containing the resultset generated by the command
Public Overloads Shared Function ExecuteDataTable(ByVal connection As SqlConnection, _
                                                ByVal commandType As CommandType, _
                                                ByVal commandText As String, _
                                                ByVal ParamArray commandParameters() As SqlParameter) As DataTable
    If (connection Is Nothing) Then Throw New ArgumentNullException("connection")
    ' Create a command and prepare it for execution
    Dim cmd As New SqlCommand
    Dim dt As New DataTable
    Dim dataAdatpter As SqlDataAdapter
    Dim mustCloseConnection As Boolean = False

    PrepareCommand(cmd, connection, CType(Nothing, SqlTransaction), commandType, commandText, commandParameters, mustCloseConnection)

    Try
        ' Create the DataAdapter & DataSet
        dataAdatpter = New SqlDataAdapter(cmd)

        ' Fill the DataSet using default values for DataTable names, etc
        dataAdatpter.Fill(dt)

        ' Detach the SqlParameters from the command object, so they can be used again
        cmd.Parameters.Clear()
    Finally
        If (Not dataAdatpter Is Nothing) Then dataAdatpter.Dispose()
    End Try
    If (mustCloseConnection) Then connection.Close()

    ' Return the dataset
    Return dt
End Function ' ExecuteDataTable

SQLHelper.vb缺少ExecuteDataTable

2 个答案: