Question

我最近才开始学习Clojure，所以如果这有点基本的话，请道歉：

有人可以向我解释一下之间的区别：

=> (def a (lazy-cat
            [0]
            (map inc a)
   ))

=> (take 5 a)
(0 1 2 3 4)

和

=> (def b (lazy-cat
            [0]
            (map #(inc (nth b %)) (range))
   ))

=> (take 5 b)

IndexOutOfBoundsException   clojure.lang.RT.nthFrom (RT.java:773)

我期望第二个例子以相同的方式运行，使用b的第一个元素计算第二个，然后第二个计算第三个元素。我的理解是，clojure甚至不会尝试计算b的第三个元素，直到它已经为第二个元素赋值并将其打印在屏幕上。

我很感激有人可以解释一下幕后实际发生的事情。

谢谢：）

Answer 1

此行为的原因是map函数实现最简单(map f colls)的情况。看到差异：

user=> (def b (lazy-cat [0] (map (fn [i _] (inc (nth b i))) (range) (range))))
#'user/b
user=> (take 5 b)
(0 1 2 3 4)

这有点令人困惑，但让我解释一下发生了什么。那么，为什么map的第二个参数会改变行为：

https://github.com/clojure/clojure/blob/master/src/clj/clojure/core.clj#L2469

(defn map
  ...
  ([f coll]
   (lazy-seq
    (when-let [s (seq coll)]
      (if (chunked-seq? s)
        (let [c (chunk-first s)
              size (int (count c))
              b (chunk-buffer size)]
          (dotimes [i size]
              (chunk-append b (f (.nth c i))))
              (chunk-cons (chunk b) (map f (chunk-rest s))))
        (cons (f (first s)) (map f (rest s)))))))
  ([f c1 c2]
   (lazy-seq
    (let [s1 (seq c1) s2 (seq c2)]
      (when (and s1 s2)
        (cons (f (first s1) (first s2))
              (map f (rest s1) (rest s2)))))))
...

答案：chunked-seq的优化原因。

user=> (chunked-seq? (seq (range)))
true

因此，价值将被“预先计算”：

user=> (def b (lazy-cat [0] (map print (range))))
#'user/b
user=> (take 5 b)
(0123456789101112131415161718192021222324252627282930310 nil nil nil nil)

当然，在你的情况下，这个“预先计算”失败了IndexOutOfBoundsException。

Answer 2

查看take的来源：

(defn take
  "Returns a lazy sequence of the first n items in coll, or all items if
  there are fewer than n."
  {:added "1.0"
   :static true}
  [n coll]
  (lazy-seq
   (when (pos? n) 
     (when-let [s (seq coll)]
      (cons (first s) (take (dec n) (rest s)))))))

现在对第一种情况进行说明。没有机会解决数组越界。

对于第二个示例，您正在对尚未扩展为n个元素的序列调用nth。 b将尝试将0与依赖于不存在的元素的序列连接起来。

Clojure无限懒惰的序列，超出范围

2 个答案: