在Perl中解析数​​组中的文件和存储分隔部分

Question

我需要使用外部数据，一个纯文本文件，其中包含要在Perl中处理的数据（我正在学习这种语言）。

{NAME}
orga:21:12348:oragnisation
serv:22:12348:service
{NAME-END}
{DATA}
palm:data:fluid:147
rose:data:fluid:149
{DATA-END}
{OTHER}
palm:data:fluid:147
rose:data:fluid:149
germ:data:fluid:189
{OTHER-END}

如何读取此文件并将每个部分存储在数组中（部分已知并在{xxxx}和{xxxx-END}之间分隔。部分中的每个数据都转换为列表并存储在数组中。 我希望有这样的东西，例如：

@name = ( ("orga","21","12348","organisation"), ("serv","22","12348","service") )

Answer 1

尝试创建根据其他变量的值命名的变量是一个坏主意。最好的方法是构建数组哈希，而不是像@name那样单独命名的数组。

像这个程序的东西会做你需要的。我使用Data::Dump来显示程序构建的数据结构。

use strict;
use warnings;

use Data::Dump;

open my $fh, '<', 'data.txt' or die $!;

my %data;
my $sect;
while (<$fh>) {
  chomp;
  if (/^\{(\w+)\}$/) {
    $sect = $1;
  }
  elsif (/^\{($sect-END)\}$/) {
    undef $sect
  }
  elsif (defined $sect) {
    push @{ $data{$sect} }, [split /:/];
  }
}

dd \%data;

<强>输出

{
  DATA  => [
             ["palm", "data", "fluid", 147],
             ["rose", "data", "fluid", 149],
           ],
  NAME  => [
             ["orga", 21, 12348, "oragnisation"],
             ["serv", 22, 12348, "service"],
           ],
  OTHER => [
             ["palm", "data", "fluid", 147],
             ["rose", "data", "fluid", 149],
             ["germ", "data", "fluid", 189],
           ],
}

Answer 2

这样的事情怎么样：

my %list;
while(<DATA>) {
    chomp;
    if (/^\{(.*?)\}/ .. /^\{${1}-END\}/) {
        push @{$list{$1}}, $_ unless /^\{/;
    }
}
say Dumper\%list;

<强>输出：

$VAR1 = {
          'OTHER' => [
                     'palm:data:fluid:147',
                     'rose:data:fluid:149',
                     'germ:data:fluid:189'
                   ],
          'NAME' => [
                    'orga:21:12348:oragnisation',
                    'serv:22:12348:service'
                  ],
          'DATA' => [
                    'palm:data:fluid:147',
                    'rose:data:fluid:149'
                  ]
        };