Question

基本上，这是关于Pascal（FPC）中的递归数据结构的问题。正如我想在SICP第4章中所示实现一个Scheme解释器，这个问题也可能与Schemers有关。：）

S表达式应表示为标记数据。到目前为止，我已经构建了一个变体记录，它代表了数字和对。希望代码可读且不言自明：

program scheme;

type
   TTag = (ScmFixnum, ScmPair);
   PScmObject = ^TScmObject;
   TScmObject = record
      case ScmObjectTag: TTag of
         ScmFixnum: (ScmObjectFixnum: integer);
         ScmPair: (ScmObjectCar, ScmObjectCdr: PScmObject);
      end;

var
   Test1: TScmObject;
   Test2: TScmObject;
   Test3: TScmObject;

function MakeFixnum(x: integer): TScmObject;
var
   fixnum: TScmObject;
begin
   fixnum.ScmObjectTag := ScmFixnum;
   fixnum.ScmObjectFixnum := x;
   MakeFixnum := fixnum;
end;

function MakePair(car, cdr: PScmObject): TScmObject;
var
   pair: TScmObject;
begin
   pair.ScmObjectTag := ScmPair;
   pair.ScmObjectCar := car;
   pair.ScmObjectCdr := cdr;
   MakePair := pair;
end;

begin
   Test1 := MakeFixnum(7);
   writeln('Test1, Tag: ', Test1.ScmObjectTag,
           ', Content: ', Test1.ScmObjectFixnum);
   Test2 := MakeFixnum(9);
   writeln('Test2, Tag: ', Test2.ScmObjectTag,
           ', Content: ', Test2.ScmObjectFixnum);
   Test3 := MakePair(Test1, Test2);
end.

但是，编译代码会产生如下错误：

$ fpc scheme.pas
(...)
Compiling scheme.pas
scheme.pas(43,34) Error: Incompatible type for arg no. 2: Got "TScmObject", expected "PScmObject"
scheme.pas(45) Fatal: There were 1 errors compiling module, stopping
Fatal: Compilation aborted

很明显函数MakePair中存在错误。但我还不明白我究竟做错了什么。任何帮助表示赞赏。：）

Answer 1

MakePair函数的定义如下：

function MakePair(car, cdr: PScmObject): TScmObject;

请注意，它会收到两个类型为PScmObject的指针。然后你这样称呼它：

MakePair(Test1, Test2);

但Test1和Test2属于TScmObject类型。因此传递的实际参数不兼容，就像编译器所说的那样。

您需要将指针传递给这些记录：

MakePair(@Test1, @Test2);

从长远来看，您需要注意这些记录的生命周期。你需要在堆上分配并且没有垃圾收集我怀疑你会进入一个痛苦的世界，试图跟踪谁拥有记录。也许您可以考虑使用接口引用计数来管理生命周期。

Answer 2

该过程期望指向记录的指针，而不是记录本身。

您可以在调用点使用 @ （at）运算符来创建指针动态到记录，从而满足编译器类型检查：

begin
   Test1 := MakeFixnum(7);
   writeln('Test1, Tag: ', Test1.ScmObjectTag,
           ', Content: ', Test1.ScmObjectFixnum);
   Test2 := MakeFixnum(9);
   writeln('Test2, Tag: ', Test2.ScmObjectTag,
           ', Content: ', Test2.ScmObjectFixnum);
   Test3 := MakePair(@Test1, @Test2);
end.

用FPC编写Scheme解释器：递归数据结构

2 个答案: