Question

我是xml-twig的新手，如何拆分父标记？

文件：

<xml>
   <p class="indent">text text incluce <div>text</div> ateas</p>
   <p class="text">text text incluce <div>text</div> ateas</p>
</xml>

我需要输出为：

<xml>
   <p class="indent">text text incluce</p>
   <div>text</div>
   <p class="indent">ateas</p>
   <p class="text">text text incluce</p>
    <div>text</div>
   <p class="text">ateas</p>
</xml>

如何拆分标签？

use strict;
use XML::Twig;

open(my $output , '>', "split.xml") || die "can't open the Output $!\n";

my $xml_twig_content = XML::Twig->new(
        'p' => \&split, )

$xml_twig_content->parsefile("sample.xml");
$xml_twig_content->print($output);

sub split{
        my ($xml_twig_content, $p) = @_;

}

如何拆分标签？...

Answer 1

可能有几种方法可以做到这一点。以下代码使用wrap_in，在所有文本节点周围添加新，然后erase删除原始。 atts用于将原始的属性复制到新属性。

#!/usr/bin/perl
use warnings;
use strict;

use XML::Twig;

open(my $output , '>', "split.xml") || die "can't open the Output $!\n";

my $xml = XML::Twig->new( twig_handlers => { p => \&split_tag } );

$xml->parsefile("1.xml");
$xml->print($output);

sub split_tag {
    my ($twig, $p) = @_;
    $_->wrap_in('p', $p->atts) for $p->children('#TEXT');
    $p->erase;
}

顺便说一句，请发布一个可运行的代码。您的示例代码错过了重要部分（例如twig_handlers或分号）。

对于附加约束，您可以按如下方式弯曲脚本：

sub split_tag {
    my ($twig, $p) = @_;
  CHILD:
    for my $ch ($p->children(sub {'div' ne shift->name})) {
        my $wrap = $ch->wrap_in('p', $p->atts);
        my $prev = $wrap->prev_sibling or next CHILD;
        $prev->merge($wrap) if 'p' eq $prev->name;
    }
    $p->erase;
}

Answer 2

很大程度上取决于完整XML数据的性质。例如，如果您期望嵌套的元素，则解决方案要复杂得多，并且需要更好地定义行为。

然而，该程序似乎可以满足您的需求，并可以处理您的样本数据。与您自己的代码一样，split子例程处理遇到的每个元素。如果元素包含的是文本，则保持不变，否则子元素将被分离并用于在数组@split中创建替换节点的列表。通过创建父元素的克隆并将文本粘贴为其内容来转换此列表中的文本节点。修改完所有文本节点后，对replace_with的调用会替换原始元素的新元素列表。

请注意，print_to_file方法无需单独打开输出文件。

use strict;
use warnings;

use XML::Twig;

my $twig = XML::Twig->new(
  twig_handlers => { p => \&split },
);

$twig ->parsefile('sample.xml');
$twig->print_to_file('split.xml', pretty_print => 'indented');

sub split{
  my ($twig, $p) = @_;
  return if $p->contains_only_text;

  my @split = $p->cut_children;
  for my $child (grep $_->is_pcdata, @split) {
    my $text = $child;
    $child = $p->copy;
    $text->paste(last_child => $child);
  }

  $p->replace_with(@split);
}

<强>输出

<xml>
  <p class="indent">text text incluce </p>
  <div>text</div>
  <p class="indent"> ateas</p>
  <p class="text">text text incluce </p>
  <div>text</div>
  <p class="text"> ateas</p>
</xml>

如何在xml twig中拆分父标签？

2 个答案: