Question

我是xml twig的新手..我需要从xpath复制到xpath，我该怎么办？我尝试了一些方法，但它无法正常工作，所以请任何一个帮助..如何将标签从xpath复制到xml文件中的xpath ...我怎么能得到这个选项xml :: twig ...

我的意见：

<xml>
<front>
 <sample>
<a>link <bo>ale</bo></a>
</sample>
</front>
<body>
<p>some text</p>
</body>
</xml>

我需要xpath复制标签......

from : //front/sample/ 
to : //body/

我需要输出为：

<xml>
    <front>
     <sample>

    </sample>
    </front>
    <body>
    <a>link <bo>ale</bo></a>
    <p>some text</p>
    </body>
    </xml>

我试试：

use XML::Twig:

 my $Tag_move = XML::Twig->new(
                               twig_handlers =>{
                                        'xml' => \&Tag_Alt,
                               },
                               pretty_print => 'indented',
);
$Tag_move->parsefile(input.xml);
$Tag_move->print;

sub Tag_Alt{
        my ($Tag_move, $tagm) = @_;
             my @c = $tagm->findnodes('//front/sample/');   
             my $chi = $tagm->copy_children(@c);
             $chi->paste('first_child', $tagm->findnodes('//body/'));
}

Answer 1

您似乎遇到了标量与数组的问题。也许是在以前的生活中使用jQuery的结果？ ; - ）

在任何情况下，如果你写这个你的子将工作：

sub Tag_Alt{
  my ($Tag_move, $tagm) = @_;
  my @c = $tagm->findnodes('//front/sample/');   
  my @children= map { $_->cut_children } @c;
  foreach my $child (@children) {
    $child->paste('first_child', ($tagm->findnodes('//body/'))[0]); 
  }     
}

我会用不同的方式写这个：

#!/usr/bin/perl

use strict;
use warnings;

use XML::Twig;

my @samples;

my $Tag_move = XML::Twig->new(
    twig_handlers =>{ # cut and store the everything within sample
                      sample => sub { push @samples, $_->cut_children; },
                      # paste the samples within the body
                      body   => sub { foreach my $sample (@samples) 
                                        { $sample->paste( first_child => $_); }
                                    },
                    },
    pretty_print => 'indented',
    empty_tags => 'expand',   # otherwise the empty sample is output as <sample/>
);
$Tag_move->parsefile( "input.xml")
        ->print;

顺便说一句，帮自己一个忙，并使用strict和warnings。这将抓住你犯的很多错误。您将收到错误，而不是允许以静默方式创建未知变量。

如何通过xpath在xml twig中复制子项或标记？

1 个答案: