Question

我正在尝试将fBm应用到行星的球体上。要创建我的球体，我将其从立方体转换为此球体。不幸的是，生成的fBm显示为镜像补丁。此外，它仅在2个面上进行（包裹其他面的值）。当呈现为sphere

时，这会导致类似拉伸的外观

噪声函数是Ken Perlin所描述的改进的噪声，我为HLSL改编了这个：

  float fade(float t) { return t * t * t * (t * (t * 6 - 15) + 10); }

  float lerp(float t, float a, float b) { return a + t * (b - a); }

  float grad(int hash, float x, float y, float z) {
  int h = hash & 15;                      // CONVERT LO 4 BITS OF HASH CODE
  float u = h<8 ? x : y,                 // INTO 12 GRADIENT DIRECTIONS.
         v = h<4 ? y : h==12||h==14 ? x : z;
  return ((h&1) == 0 ? u : -u) + ((h&2) == 0 ? v : -v);
  } 
  int p[512] = { 151,...180 }; //0-255 twice

  float noise(float x, float y, float z) {


  int X = (int)floor(x) & 255;                  // FIND UNIT CUBE THAT
  int Y = (int)floor(y) & 255;                  // CONTAINS POINT.
  int Z = (int)floor(z) & 255;
  x -= floor(x);                                // FIND RELATIVE X,Y,Z
  y -= floor(y);                                // OF POINT IN CUBE.
  z -= floor(z);
  float u = fade(x),                                // COMPUTE FADE CURVES
         v = fade(y),                                // FOR EACH OF X,Y,Z.
         w = fade(z);
  int A = p[X  ]+Y, AA = p[A]+Z, AB = p[A+1]+Z,      // HASH COORDINATES OF
      B = p[X+1]+Y, BA = p[B]+Z, BB = p[B+1]+Z;      // THE 8 CUBE CORNERS,

  return lerp(w, lerp(v, lerp(u, grad(p[AA  ], x  , y  , z   ),  // AND ADD
                                 grad(p[BA  ], x-1, y  , z   )), // BLENDED
                         lerp(u, grad(p[AB  ], x  , y-1, z   ),  // RESULTS
                                 grad(p[BB  ], x-1, y-1, z   ))),// FROM  8
                 lerp(v, lerp(u, grad(p[AA+1], x  , y  , z-1 ),  // CORNERS
                                 grad(p[BA+1], x-1, y  , z-1 )), // OF CUBE
                         lerp(u, grad(p[AB+1], x  , y-1, z-1 ),
                                 grad(p[BB+1], x-1, y-1, z-1 ))));
  }

此实现在前一个项目中按预期工作，但是对于此项目，当我使用顶点位置作为输入时，它似乎会创建一个平滑的网格。它是一个单位立方体，所以这些值不是整数，但我无法弄清楚为什么它不能创建典型的Perlin噪声纹理。

非常感谢任何帮助，如果需要，我会提供更多信息。

Answer 1

函数无法访问int的数组，所以我假设其中的值是未定义的。快速修复是使数组静态，但这非常慢。所以现在我需要传入数组。但我遇到了麻烦。

Answer 2

我在Dx11行星渲染项目中使用下面的噪声函数。我也包括了一个fBm功能。我在WebGL着色器编程网站ShaderToy上找到了它（用GLSL编写）。

这是由神秘的inigo quilez撰写的，他是该网站的作者。

尝试一下，我希望它有所帮助。所有的功劳应归功于inigo quilez的工作。将其移植到HLSL是微不足道的。我只在着色器模型5中测试过，但我确信它至少可以在4下工作。

// hash based 3d value noise
// function taken from https://www.shadertoy.com/view/XslGRr
// Created by inigo quilez - iq/2013
// License Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License.

// ported from GLSL to HLSL

cbuffer cbNoiseParameters
{
    float _rOctaves;
    float _rLacunarity;
    float _rFrequency;
    float _rAmplitude;
    float _rGain;
    float _rOffset;
};

float hash( float n )
{
    return frac(sin(n)*43758.5453);
}

float noise( float3 x )
{
    // The noise function returns a value in the range -1.0f -> 1.0f

    float3 p = floor(x);
    float3 f = frac(x);

    f       = f*f*(3.0-2.0*f);
    float n = p.x + p.y*57.0 + 113.0*p.z;

    return lerp(lerp(lerp( hash(n+0.0), hash(n+1.0),f.x),
                   lerp( hash(n+57.0), hash(n+58.0),f.x),f.y),
               lerp(lerp( hash(n+113.0), hash(n+114.0),f.x),
                   lerp( hash(n+170.0), hash(n+171.0),f.x),f.y),f.z);
}

float fBm( float3 vPt )
{
    float octaves       = _rOctaves;    
    float lacunarity    = _rLacunarity;
    float frequency     = _rFrequency;
    float amplitude     = _rAmplitude;  
    float gain          = _rGain;
    float offset        = _rOffset;
    float value         = 0.f;

    for( int i = 0; i < octaves; ++ i )
    {
        value += noise( vPt * frequency ) * amplitude;

        amplitude *= gain;
        frequency *= lacunarity;
    }

    return value;
}

不受欢迎的常规Perlin噪音

2 个答案: