Question

请帮助我了解如何获取自定义类实例来访问时间轴上定义的变量。

我没有使用文档类，因为这个程序将是一个具有多个阶段的内存实验，因此使用时间轴最适合我。（FWIW，我也没有使用xml;只是尽量保持这个简单。）现在我刚刚制作了一个简单的单帧fla，我正在尝试进行词汇测试。我创建了一个名为VocabQ的自定义类，后者又包含4个名为VocabButton的自定义类的实例。现在，单击其中一个按钮只会跟踪按钮标签。但我希望它还更新在时间轴上声明的String变量CurrentResponse的值。如果我只是尝试从VocabButton类引用CurrentResponse，我会收到错误“1120：访问未定义的属性......”。

我根据我在互联网上发现的讨论尝试了各种方法，但还没有取得成功，只是变得更加困惑。请帮忙！（非常感谢简单的解决方案，如果存在的话！）请参阅下面的代码。谢谢，〜杰森

时间轴中的代码：

import VocabQ;
import flash.display.*;
stop();

var CurrentResponse:String="NA";

var VocabQuestion = new VocabQ("VocabWord",["answerA","answerB","answerC","answerD"]);
addChild(VocabQuestion);

VocabQ.as代码：

package
{
    import flash.display.*;
    import flash.events.*;
    import flash.net.*;
    import flash.text.*;
    import VocabButton;

    public class VocabQ extends MovieClip{
        private var _VocabWordText:String;
        private var _VocabWord:TextField;
        private var _ResponseOptions:Array;

        public function VocabQ(VocabWordText:String,ResponseOptions:Array){         
        _VocabWordText=VocabWordText;
        _ResponseOptions=ResponseOptions;
        build();
        }

        private function build():void{          
            _VocabWord = new TextField();
            _VocabWord.text=_VocabWordText;
            _VocabWord.x=25;
            _VocabWord.y=25;
            _VocabWord.textColor = 0x000000;
            addChild(_VocabWord);

            for (var i:int; i < _ResponseOptions.length; i++){
                var _VocabButton:VocabButton = new VocabButton(_ResponseOptions[i]);
                _VocabButton.x = 25 + (_VocabWord.width) + 10 + ((_VocabButton.width + 2) * i);
                _VocabButton.y = 25;
                addChild(_VocabButton);
                }
            }       
    }
}

VocabButton.as代码：

package 
{
    import flash.display.*;
    import flash.text.*;
    import flash.events.*;

    public class VocabButton extends MovieClip{
        private var _btnLabel:TextField;

        public function VocabButton(labl:String){

            _btnLabel = new TextField();       
            _btnLabel.textColor = 0x000000;
            _btnLabel.text = labl;
            _btnLabel.border=true;
            _btnLabel.borderColor=0x000000;
            _btnLabel.background=true;
            _btnLabel.backgroundColor= 0xDAF4F0;
            _btnLabel.mouseEnabled = false;
            _btnLabel.selectable=false;
            _btnLabel.width=100;
            _btnLabel.height=18;        
            buttonMode=true;
            useHandCursor=true;
            addEventListener(MouseEvent.CLICK,onClick,false,0,true);

            addChild(_btnLabel);
        }

        private function onClick(evt:MouseEvent):void{
        trace(_btnLabel.text);  
        //CurrentResponse=_btnLabel.text;  //causes error 1120: Access of undefined property...
        }
    }
}

Answer 1

这应该有效：

private function onClick(evt:MouseEvent):void {
    trace(_btnLabel.text);  
    evt.currentTarget.root.CurrentResponse=_btnLabel.text;
}

请参阅此处的讨论：http://www.actionscript.org/forums/showthread.php3?t=161188

就个人而言，我宁愿添加点击监听器，而不是试图像这样访问时间线到时间线上的VocabQuestion并允许Event to Bubble Up，或者，如果您的班级中有多个按钮，则扩展EventDispatcher并创建一些同样可以自定义的事件在你的时间轴上处理，但是对于一个简单的测试，访问root属性应该足够好了。

AS3如何获取自定义类实例以访问时间轴上的变量？

1 个答案: