Question

我需要在子元素中插入一个子元素。我有两个孩子，第一个孩子剪切并粘贴到第二个孩子插入作为第一个孩子。

的xml：

  <fn id="fn1_1">
    <label>1</label>
    <p>The distinguished as &amp;#x2018;bisexuation.&amp;#x2019;</p>
  </fn>

我试过

sub fngroup{
my ($xml_twig_content, $fn_group) = @_;
@text = $fn_group->children;
my $cut;
foreach my $fn (@text){
$cut = $fn->cut if ($fn->name =~ /label/);
if ($fn =~ /p/){
$fn->paste('first_child', $cut);
}
}
}

我无法处理它。如何将标签和标签标签粘贴到p标签上作为first_child。

我需要：

<fn id="fn1_1">
 <p><label>1</label> The distinguished as &amp;#x2018;bisexuation.&amp;#x2019;</p>
 </fn>

Answer 1

您的代码存在以下几个问题：首先应将处理程序应用于fn，而不是fngroup，然后您正在测试$fn =~ /p/而不是$fn->name =~ /p/

所以这会奏效：

#!/usr/bin/perl

use strict;
use warnings;

use XML::Twig;

XML::Twig->new( twig_handlers => { fn => \&fn})
         ->parse( \*DATA)
         ->print;

sub fn {
    my ($xml_twig_content, $fn) = @_;
    my @text = $fn->children;
    my $cut;
    foreach my $fn (@text){
        $cut = $fn->cut if ($fn->name =~ /label/);
        if ($fn->name =~ /p/){
            $cut->paste(first_child => $fn);
        }
    }
}

__DATA__
<foo>
  <fngroup>
    <fn id="fn1_1">
      <label>1</label>
      <p>The distinguished as &amp;#x2018;bisexuation.&amp;#x2019;</p>
    </fn>
  </fngroup>
</foo>

但是，这是不必要的复杂。为什么不简单地使用处理程序：

sub fn {
    my ($twig, $fn) = @_;
    $fn->first_child( 'label')->move( first_child => $fn->first_child( 'p'));
}

如何插入子xml树枝

1 个答案: