Question

如何以编程方式单击下载按钮后下载文件，因此无需知道下载文件的URL。

文件下载后出现提示并询问您是否要保存文件，按“是”后，另一个提示会询问您要保存文件的位置。因此，首先下载文件，可能在某个地方的缓冲区中，在初始下载后，会出现提示。

因此，单击按钮后，如何捕获下载流并将其另存为某个文件，而不显示弹出提示？

（点击按钮的任何方法都没问题，以下情况应该没问题。）

procedure TForm1.Button1Click(Sender: TObject);
var
  x: integer;
  ovLinks: OleVariant;
begin
  WebBrowser1.Navigate('The web page');
  //wait for page to down load
  ovLinks := WebBrowser1.OleObject.Document.all.tags('A');
  if ovLinks.Length > 0 then
  begin
    for x := 0 to ovLinks.Length-1 do
      begin
        if Pos('id of button', ovLinks.Item(x).id) > 0 then
        //or if Pos('href of button', ovLinks.Item(x).href) > 0 then
        begin
          ovLinks.Item(x).click;
          Break;
        end;
      end;
  end;
end;

此问题的原因是：无法始终找到文件的网址。例如：在此web site，我无法以编程方式找到网址，但在按下导出按钮后，使用IE，文件被下载到“Temporary Internet Files”文件夹中。在IE'Temporary Internet Files'文件夹中，它有一个列'Internet地址'，显示网址。但是在Chrome中没有这样的数据。但是，在此web site，我可以以编程方式找到该网址，但是当我下载文件时，按“此处”，该文件不会出现在IE“Temporary Internet Files”文件夹中。对于其他网站，可以在文件夹中找到网址并通过编程方式找到它，但在其他网站上无法找到网址。

Answer 1

将IDownloadManager界面及其Download方法实施到您的网络浏览器控件，您可以简单地控制您需要的内容。每当您要下载文件时，都会调用Download方法（仅当弹出另存为对话框时）。

的 1。嵌入式Web浏览器

您可以使用已经实现此接口的Embedded Web Browser控件，该控件会触发与OnFileDownload中同一命名事件不同的TWebBrowser。例如，请参阅this thread了解如何使用它。

的 2。自己动手

另一个选择是你可以自己将它实现到TWebBrowser。在下面的例子中，我使用插入类只是为了显示原理，但是将它作为一个组件包装起来非常容易（这就是为什么我发布了OnBeforeFileDownload）。

的 2.1。 OnBeforeFileDownload事件

此插入类中TWebBrowser的唯一扩展名是OnBeforeFileDownload事件，该事件将在下载文件时触发（在保存为弹出对话框之前，而不是OnFileDownload } event，而不是在下载文档本身时）。如果您不为其编写事件处理程序，则Web浏览器控件将像以前一样运行（显示另存为对话框）。如果编写事件处理程序并将False返回到其Allowed声明的参数，则将取消文件保存。如果将True返回到Allowed参数（默认情况下），将显示另存为对话框。请注意，如果通过将Allowed设置为False来取消下载，则需要自己下载文件（因为我在此示例中使用Indy同步）。为此，有FileSource常量参数，其中包含下载的文件URL。以下是事件参数概述：

发件人（TObject） - 事件发件人
FileSource（WideString） - 源文件URL
Allowed（布尔） - 声明的布尔参数，决定是否允许文件下载（默认值为True）

的 2.2。 IDownloadManager实施

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  StdCtrls, OleServer, OleCtrls, Dialogs, ActiveX, MSHTML, UrlMon, SHDocVw,
  IdHTTP;

const
  IID_IDownloadManager: TGUID = '{988934A4-064B-11D3-BB80-00104B35E7F9}';
  SID_SDownloadManager: TGUID = '{988934A4-064B-11D3-BB80-00104B35E7F9}';

type
  IDownloadManager = interface(IUnknown)
    ['{988934A4-064B-11D3-BB80-00104B35E7F9}']
    function Download(pmk: IMoniker; pbc: IBindCtx; dwBindVerb: DWORD;
      grfBINDF: DWORD; pBindInfo: PBindInfo; pszHeaders: PWideChar;
      pszRedir: PWideChar; uiCP: UINT): HRESULT; stdcall;
  end;
  TBeforeFileDownloadEvent = procedure(Sender: TObject; const FileSource: WideString;
    var Allowed: Boolean) of object;
  TWebBrowser = class(SHDocVw.TWebBrowser, IServiceProvider, IDownloadManager)
  private
    FFileSource: WideString;
    FOnBeforeFileDownload: TBeforeFileDownloadEvent;
    function QueryService(const rsid, iid: TGUID; out Obj): HRESULT; stdcall;
    function Download(pmk: IMoniker; pbc: IBindCtx; dwBindVerb: DWORD;
      grfBINDF: DWORD; pBindInfo: PBindInfo; pszHeaders: PWideChar;
      pszRedir: PWideChar; uiCP: UINT): HRESULT; stdcall;
  protected
    procedure InvokeEvent(ADispID: TDispID; var AParams: TDispParams); override;
  published
    property OnBeforeFileDownload: TBeforeFileDownloadEvent read FOnBeforeFileDownload write FOnBeforeFileDownload;
  end;

type
  TForm1 = class(TForm)
    Button1: TButton;
    WebBrowser1: TWebBrowser;
    FileSourceLabel: TLabel;
    FileSourceEdit: TEdit;
    ShowDialogCheckBox: TCheckBox;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    procedure BeforeFileDownload(Sender: TObject; const FileSource: WideString;
      var Allowed: Boolean);
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TWebBrowser }

function TWebBrowser.Download(pmk: IMoniker; pbc: IBindCtx; dwBindVerb,
  grfBINDF: DWORD; pBindInfo: PBindInfo; pszHeaders, pszRedir: PWideChar;
  uiCP: UINT): HRESULT;
var
  Allowed: Boolean;
begin
  Result := E_NOTIMPL;
  if Assigned(FOnBeforeFileDownload) then
  begin
    Allowed := True;
    if pszRedir <> '' then
      FFileSource := pszRedir;
    FOnBeforeFileDownload(Self, FFileSource, Allowed);
    if not Allowed then
      Result := S_OK;
  end;
end;

procedure TWebBrowser.InvokeEvent(ADispID: TDispID; var AParams: TDispParams);
begin
  inherited;
  // DispID 250 is the BeforeNavigate2 dispinterface and to the FFileSource here
  // is stored the URL parameter (for cases, when the IDownloadManager::Download
  // won't redirect the URL and pass empty string to the pszRedir)
  if ADispID = 250 then
    FFileSource := OleVariant(AParams.rgvarg^[5]);
end;

function TWebBrowser.QueryService(const rsid, iid: TGUID; out Obj): HRESULT;
begin
  Result := E_NOINTERFACE;
  Pointer(Obj) := nil;
  if Assigned(FOnBeforeFileDownload) and IsEqualCLSID(rsid, SID_SDownloadManager) and
    IsEqualIID(iid, IID_IDownloadManager) then
  begin
    if Succeeded(QueryInterface(IID_IDownloadManager, Obj)) and
      Assigned(Pointer(Obj))
    then
      Result := S_OK;
  end;
end;

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
var
  HTMLWindow: IHTMLWindow2;
  HTMLDocument: IHTMLDocument2;
begin
  WebBrowser1.Navigate('http://financials.morningstar.com/income-statement/is.html?t=AAPL&ops=clear');
  while WebBrowser1.ReadyState <> READYSTATE_COMPLETE do
    Application.ProcessMessages;

  HTMLDocument := WebBrowser1.Document as IHTMLDocument2;
  if not Assigned(HTMLDocument) then
    Exit;
  HTMLWindow := HTMLDocument.parentWindow;
  if Assigned(HTMLWindow) then
  try
    HTMLWindow.execScript('SRT_stocFund.Export()', 'JavaScript');
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ReportMemoryLeaksOnShutdown := True;
  WebBrowser1.OnBeforeFileDownload := BeforeFileDownload;
end;

procedure TForm1.BeforeFileDownload(Sender: TObject; const FileSource: WideString;
  var Allowed: Boolean);
var
  IdHTTP: TIdHTTP;
  FileTarget: string;
  FileStream: TMemoryStream;
begin
  FileSourceEdit.Text := FileSource;
  Allowed := ShowDialogCheckBox.Checked;
  if not Allowed then
  try
    IdHTTP := TIdHTTP.Create(nil);
    try
      FileStream := TMemoryStream.Create;
      try
        IdHTTP.HandleRedirects := True;
        IdHTTP.Get(FileSource, FileStream);
        FileTarget := IdHTTP.URL.Document;
        if FileTarget = '' then
          FileTarget := 'File';
        FileTarget := ExtractFilePath(ParamStr(0)) + FileTarget;
        FileStream.SaveToFile(FileTarget);
      finally
        FileStream.Free;
      end;
    finally
      IdHTTP.Free;
    end;
    ShowMessage('Downloading finished! File has been saved as:' + sLineBreak +
      FileTarget);
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
end;

end.

的 2.3。 IDownloadManager项目

您可以将上述代码（使用Delphi 2009编写）下载为完整的项目from here。

Answer 2

我不知道这是否会让你到达你需要去的地方，但它看起来很有希望。使用我在这里的TWebBrowser（从“Microsoft Internet Controls版本1.1”导出），您可以使用OnBeforeNavigate2事件来监视Web浏览器处理的所有URL。你从那里遇到的问题是确定你需要做什么，捕获URL，然后自己处理它。这是我在你所呈现的first web site上使用控件的五分钟的简短示例。

procedure TForm1.WebBrowser1BeforeNavigate2(Sender: TObject;
     pDisp: IDispatch; var URL, Flags, TargetFrameName, PostData,
     Headers: OleVariant; var Cancel: WordBool);
  begin
    Edit1.Text := String(URL);
    if Pos('CSV', Edit1.Text) > 0 then
      Cancel := true;
  end;

正如你所看到的，有很多参与者，你必须locate the documentation来看看这些意思。但在我的简短示例中，我所做的是将导航的URL放到Edit1.Text（如果你真的想看看发生了什么，可能更好的TMemo）。举个例子，没有什么可以表明它是一个直接下载的文件，但是使用上面的代码，我可以取消浏览器做它的事情（显示下载提示等），然后在Edit1框中输入URL到在行动。如果要进一步挖掘，我相信你可以查看有问题的标题，并确定网站是否打算向你发送一个你应该下载的文件，因为URL本身并没有说“CSV”文件“（将http://financials.morningstar.com/ajax/ReportProcess4CSV.html?t=AAPL&region=usa&culture=us_EN&reportType=is&period=12&dataType=A&order=asc&columnYear=5&rounding=3&view=raw&productCode=USA&r=809199&denominatorView=raw&number=3放入网络浏览器将下载相关的CSV文件。）

希望这对你来说是一个好的开始。

如何防止嵌入式浏览器提示保存下载文件的位置？

2 个答案: