Question

我使用此脚本从我的SQL Server数据库获取备份

DECLARE @name VARCHAR(50) -- database name 
DECLARE @path VARCHAR(256) -- path for backup files 
DECLARE @fileName VARCHAR(256) -- filename for backup 
DECLARE @fileDate VARCHAR(20) -- used for file name

--Path to backups
SET @path = 'E:\DataBase Backups\' 

SELECT @fileDate = CONVERT(VARCHAR(20),GETDATE(),112)

DECLARE db_cursor CURSOR FOR 
SELECT name 
FROM master.dbo.sysdatabases 
WHERE name NOT IN ('master','model','msdb','tempdb','ReportServer','ReportServerTempDB') 

OPEN db_cursor  
FETCH NEXT FROM db_cursor INTO @name  

WHILE @@FETCH_STATUS = 0  
BEGIN  
       --Remove if you dont want a date stamp 
       SET @fileName = @path + @name + '_' + @fileDate + '.BAK' 

      -- SET @fileName = @path + @name + '.BAK' 
       BACKUP DATABASE @name TO DISK = @fileName with noinit

       FETCH NEXT FROM db_cursor INTO @name  
END  

CLOSE db_cursor  
DEALLOCATE db_cursor

此代码每天生成新的备份文件，但我需要在今天备份或在进行今天的备份后替换旧备份，所有旧备份都将被删除！请你帮助我好吗？

Answer 1

您可以使用未记录的扩展存储过程xp_delete_file来删除备份文件。 Microsoft已在内部添加了一些安全措施，以允许它仅删除数据库和事务日志备份文件。所以它不能用于删除任何其他文件类型;甚至不是文本文件。

您需要声明一些额外的变量。

DECLARE @DeleteDate datetime = DATEADD(wk, -1, GETDATE())
DECLARE @FileExtension nvarchar(3) = N'BAK'
DECLARE @DeletePath nvarchar(512)

然后将此代码添加到游标循环中。

SET @DeletePath = @path + @name
EXEC master.sys.xp_delete_file 0,@DeletePath,@FileExtension,@DeleteDate,1;

@DeleteDate用于告诉存储过程要删除哪些文件早于特定日期。只需使用DATEADD函数设置截止日期。

@DeletePath将是您的@path + @name，因此它将输出类似'E：\ DataBase Backups \ MyDatabaseName'的内容。

@FileExtention用于告知要删除的文件类型;例如BAK'或'TRN'。

我一直在使用相同的代码清除自定义TSQL备份作业中的旧备份文件，效果很好。

用新的替换以前的数据库备份

1 个答案: